批处理之家's Archiver

Batcher 发表于 2009-2-14 03:32

批处理删除指定天数日期之前的文件(2023-10-08)

【方案1】以文件的最后修改时间为准 BAT + PowerShell[code]@echo off
REM ------------------------------------------------------------------------------
REM 如果显示的待删除文件列表正确无误
REM 把 Select-Object FullName 修改成 Remove-Item -Force 再次执行即可真正删除文件
REM Win7/Win8/Win10等系统自带PowerShell
REM ------------------------------------------------------------------------------

REM 指定待删除文件的存放路径
set "SrcDir=C:\Test\BatHome"
REM 指定天数
set "DaysAgo=10"

powershell -c "Get-ChildItem -Path '%SrcDir%' -Recurse -ErrorAction:SilentlyContinue | Where-Object -FilterScript {(((get-date) - ($_.LastWriteTime)).days -gt %DaysAgo% -and $_.PsISContainer -ne $True)} | Select-Object FullName"

pause[/code]【方案2】以文件的创建时间为准 BAT + PowerShell[code]@echo off
REM ------------------------------------------------------------------------------
REM 如果显示的待删除文件列表正确无误
REM 把 Select-Object FullName 修改成 Remove-Item -Force 再次执行即可真正删除文件
REM Win7/Win8/Win10等系统自带PowerShell
REM ------------------------------------------------------------------------------

REM 指定待删除文件的存放路径
set "SrcDir=C:\Test\BatHome"
REM 指定天数
set "DaysAgo=10"

powershell -c "Get-ChildItem -Path '%SrcDir%' -Recurse -ErrorAction:SilentlyContinue | Where-Object -FilterScript {(((get-date) - ($_.CreationTime)).days -gt %DaysAgo% -and $_.PsISContainer -ne $True)} | Select-Object FullName"

pause[/code]【方案3-1】以文件的修改日期为准 forfiles[code]@echo off
REM ------------------------------------------------------------------------------
REM 演示:删除指定路径下指定天数之前(以文件的最后修改日期为准)的文件。
REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
REM Win7/Win8/Win10等系统自带forfiles命令
REM ------------------------------------------------------------------------------

REM 指定待删除文件的存放路径
set "SrcDir=C:\Test\BatHome"
REM 指定天数
set "DaysAgo=1"

forfiles /p %SrcDir% /s /m *.* /d -%DaysAgo% /c "cmd /c echo del /f /q /a @path"
pause[/code]【方案3-2】forfiles 删除指定日期之前的txt文件,且排除指定文件名的某个文件:[code]@echo off
REM ------------------------------------------------------------------------------
REM 演示:删除指定路径下指定天数之前(以文件的最后修改日期为准)的文件。
REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
REM Win7/Win8/Win10等系统自带forfiles命令
REM ------------------------------------------------------------------------------

REM 指定待删除文件的存放路径
set "SrcDir=C:\Test\BatHome"
REM 指定天数
set "DaysAgo=3"
REM 指定排除的文件名
set "ExcludeFile=BatHome.txt"

for /f "delims=" %%i in ('forfiles /p %SrcDir% /s /m *.txt /d -%DaysAgo% /c "cmd /c echo @path"') do (
    if "%%~nxi" neq "%ExcludeFile%" (
        echo del /f /q "%%i"
    )
)

pause[/code]【方案4】以文件的最后修改时间为准 BAT + REG + VBS[code]@echo off
REM ------------------------------------------------------------------------------
REM 演示:删除指定路径下指定天数之前(以文件的最后修改日期为准)的文件。
REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
REM 本例调用了临时VBS代码进行日期计算
REM 本例为兼容不同的日期格式,调用reg命令(XP系统自带)统一设置日期格式,
REM 处理完毕之后再把日期格式恢复成原来的状态。
REM ------------------------------------------------------------------------------

REM 指定待删除文件的存放路径
set "SrcDir=C:\Test\BatHome"
REM 指定天数
set "DaysAgo=1"

for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
    set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
    set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
for /r "%SrcDir%" %%a in (*.*) do (
    if "%%~ta" leq "%DstDate%" (
        if exist "%%a" (
            echo del /f /q "%%a"
        )
    )
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause[/code]【方案5】以文件的最后修改时间为准 BAT + REG + Ritchie Lawrence 日期函数[code]@echo off
REM ------------------------------------------------------------------------------
REM 演示:删除指定路径下指定天数之前(以文件的最后修改日期为准)的文件。
REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
REM 本例调用了 Ritchie Lawrence 的日期函数进行日期计算
REM 日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html
REM 本例为兼容不同的日期格式,调用reg命令(XP系统自带)统一设置日期格式,
REM 处理完毕之后再把日期格式恢复成原来的状态。
REM ------------------------------------------------------------------------------

REM 指定待删除文件的存放路径
set "SrcDir=C:\Test\BatHome"
REM 指定天数
set "DaysAgo=1"

for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
    set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%
for /r "%SrcDir%" %%a in (*.*) do (
    if "%%~ta" leq "%DstDate%" (
        if exist "%%a" (
            echo del /f /q "%%a"
        )
    )
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF[/code]【方案6】以文件的最后修改时间为准 BAT + VBS[code]@echo off
REM ------------------------------------------------------------------------------
REM 演示:删除指定路径下指定天数之前(以文件的最后修改日期为准)的文件。
REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
REM 本例调用了临时VBS代码进行日期计算,并统一设置系统日期格式,处理完毕
REM 之后再把日期格式恢复成原来的状态。摆脱了对reg命令(XP系统自带)的依赖。
REM ------------------------------------------------------------------------------

REM 指定待删除文件的存放路径
set "SrcDir=C:\Test\BatHome"
REM 指定天数
set "DaysAgo=1"

>"%temp%\BackupDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\BackupDate.vbs" echo WScript.Echo WshShell.RegRead ("HKEY_CURRENT_USER\Control Panel\International\sShortDate")
for /f %%a in ('cscript /nologo "%temp%\BackupDate.vbs"') do (
    set "RegDateOld=%%a"
)
>"%temp%\UnifyDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\UnifyDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "yyyy-M-d", "REG_SZ"
cscript /nologo "%temp%\UnifyDate.vbs"
>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
    set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
for /r "%SrcDir%" %%a in (*.*) do (
    if "%%~ta" leq "%DstDate%" (
        if exist "%%a" (
            echo del /f /q "%%a"
        )
    )
)
>"%temp%\RecoverDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\RecoverDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "%RegDateOld%", "REG_SZ"
cscript /nologo "%temp%\RecoverDate.vbs"
pause[/code]【方案7】以文件的创建时间为准 BAT + REG + Ritchie Lawrence 日期函数[code]@echo off
REM ------------------------------------------------------------------------------
REM 演示:删除指定路径下指定天数之前(以文件的创建日期为准)的文件。
REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
REM 本例调用了 Ritchie Lawrence 的日期函数进行日期计算
REM 日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html
REM 本例为兼容不同的日期格式,调用reg命令(XP系统自带)统一设置日期格式,
REM 处理完毕之后再把日期格式恢复成原来的状态。
REM ------------------------------------------------------------------------------

REM 指定待删除文件的存放路径
set "SrcDir=C:\Test\BatHome"
REM 指定天数
set "DaysAgo=1"

for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
    set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%

for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (
    call :CompareTime "%%a"
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

:CompareTime
for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (
    if "%%h" leq "%DstDate%" (
        if exist %1 (
            echo del /a /f /q %1
        )
    )
    goto :eof
)[/code]【方案8】以文件名中包含的日期字符串为准 字符串截取[code]@echo off
REM ------------------------------------------------------------------------------
REM 演示:删除指定路径下指定天数之前(以文件名中包含的日期字符串为准)的文件。
REM 如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
REM 本例假设文件名中包含的日期字符串(比如:bak-2009-12-25.log)
REM ------------------------------------------------------------------------------

REM 指定待删除文件的存放路径
set "SrcDir=C:\Test\BatHome"
REM 指定天数
set "DaysAgo=1"

>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%

setlocal enabledelayedexpansion
for /r "%SrcDir%" %%a in (*.*) do (
    set "FileDate=%%~na"
    set "FileDate=!FileDate:~4,10!"
    if "!FileDate!" leq "%DstDate%" (
        if exist "%%a" (
            echo del /f /q "%%a"
        )
    )
)
endlocal
pause
[/code]

thth 发表于 2009-6-3 09:11

回复 1楼 的帖子

看了楼主贴很有收获,先谢谢了!
不过,我在试了方案一发现在日期比较的时候好像有问题,我就把去掉@echo off 显示出来的打出来:
if "09-06-01 08:56" LEQ "2009-05-29" (if-----
后面我省略了,
正常情况应该是前面比后面的日期大,可是由于格式不对,造成后面的总是大,所以把该要的和不要都删除了。
我不知道是那个地方的问题。我是在2000测试的。

Batcher 发表于 2009-6-3 09:27

回复 2楼 的帖子

方案一的描述中已经说明了需要reg命令的支持,但是Win2000系统中是没有这个命令的。请选择方案三。

thth 发表于 2009-6-3 10:45

回复 3楼 的帖子

我用的2000下是没有reg这个命令,但是我从别的机子上考了一个这个命令,运行时reg的语句没有显示出错,我在2000下4个方案都不能成功运行,从显示出来看还是日期格式不对。
不过我在xp下运行只有方案二不能运行,其他都可以很好的运行。
xp下有代码能用就好了,不求甚解了。
谢谢楼主的回答。

Batcher 发表于 2009-6-3 10:51

回复 4楼 的帖子

你在2000中:开始,运行,cmd,echo %date%,结果贴出来看看。
我帮你写一个2000中可以运行的。

另外,能否把方案三的@echo off删除,把它在2000中运行的完整过程贴出来看看?

jamesst 发表于 2009-6-12 10:03

需求

楼主,如果我想删除指定文件夹下、指定天数日期之前、指定文件名(有规则的)的文件,怎么实现呢?
急~~在线等,拜托了。

Batcher 发表于 2009-6-12 10:09

回复 6楼 的帖子

我没有未卜先知的能力,无法猜出你的文件名规则是什么。不知道该如何帮你。
抱歉。

jamesst 发表于 2009-6-12 10:38

专门定制?呵呵,谢谢楼主了!!
文件名字举例:今天生成的就是“2009-06-12”,昨天的是“2009-06-11”,没有扩展名,以此类推。
注意该目录下还有很多其它文件不能删哦

jamesst 发表于 2009-6-12 11:43

在线等。。。。。。。。。。。

Batcher 发表于 2009-6-12 13:13

回复 8楼 的帖子

[code]@echo off
::如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
rem 指定待删除文件的存放路径
set SrcDir=C:\Test
rem 指定天数
set DaysAgo=7
rem 假设日期格式为:2009-06-12 星期五
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%

for /f "delims=/" %%a in ('dir /b /a-d "%SrcDir%"') do (
  if "%%a" leq "%DstDate%" (
    echo del /a /f /q "%SrcDir%\%%a"
  )
)
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF[/code]

jamesst 发表于 2009-6-12 14:11

详见附件。
这个bat还多删除了两个其它文件,请判断,辛苦啦。

原始目录内容如下:
驱动器 E 中的卷没有标签。
卷的序列号是 13A4-CA45

E:\123123 的目录

2009-06-12  14:12    <DIR>          .
2009-06-12  14:12    <DIR>          ..
2009-06-12  14:12                 0 1.txt
2009-05-20  11:47            20,609 2009-05-24
2009-05-20  11:47            20,609 2009-05-25
2009-05-20  11:47            20,609 2009-05-26
2009-05-20  11:47            20,609 2009-05-27
2009-05-20  11:47            20,609 2009-05-28
2009-05-20  11:47            20,609 2009-05-29
2009-05-20  11:47            20,609 2009-05-30
2009-05-20  11:47            20,609 2009-05-31
2009-05-20  11:47            20,609 2009-06-01
2009-05-20  11:47            20,609 2009-06-02
2009-05-20  11:47            20,609 2009-06-03
2009-05-20  11:47            20,609 2009-06-04
2009-05-20  11:47            20,609 2009-06-05
2009-05-20  11:47            20,609 2009-06-06
2009-05-20  11:47            20,609 2009-06-07
2009-05-20  11:47            20,609 2009-06-08
2009-05-20  11:47            20,609 2009-06-09
2009-05-20  11:47            20,609 2009-06-10
2009-05-20  11:47            20,609 2009-06-11
2009-05-20  11:47            20,609 2009-06-12
2004-07-21  07:48        18,331,779 Oracle 9i中文版实用培训教程.pdf
2005-07-13  23:32        19,664,908 Oracle备份与恢复培训教程.pdf
2008-10-14  11:24           480,909 S60_Platform_FAQ_v1_12_en.pdf
2004-10-02  09:49            44,032 UnMakeSIS.exe
2008-03-24  13:03         8,838,445 wolf学习笔记.pdf
2002-03-05  06:01         7,714,572 XML编程从入门到精通.pdf
2008-10-14  10:54           127,544 x_S60.sis
2008-09-10  13:19        36,601,098 [买股票,找这样的公司就对了].pdf
2005-01-13  10:02           651,487 《管理就这么简单》.pdf
2008-10-04  19:03         2,430,968 公司OA考勤管理系统.rar
2009-02-04  00:45           207,872 生意架构__2003.xls
2008-10-13  13:05         8,594,865 非C程序员C++入门自学教程.PDF
              33 个文件    104,100,659 字节

jamesst 发表于 2009-6-12 14:13

补充,我修改的bat内容如下:
@echo off
::如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
rem 指定待删除文件的存放路径
set SrcDir=E:\123123
rem 指定天数
set DaysAgo=15
rem 假设日期格式为:2009-06-12 星期五
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%

for /f "delims=/" %%a in ('dir /b /a-d "%SrcDir%"') do (
  if "%%a" leq "%DstDate%" (
    echo del /a /f /q "%SrcDir%\%%a"
  )
)
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

Batcher 发表于 2009-6-12 15:16

回复 12楼 的帖子

[code]@echo off
::如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
rem 指定待删除文件的存放路径
set SrcDir=E:\123123
rem 指定天数
set DaysAgo=15
rem 假设日期格式为:2009-06-12 星期五
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%

for /f "delims=/" %%a in ('dir /b /a-d "%SrcDir%\????-??-??"') do (
  if "%%a" leq "%DstDate%" (
    echo del /a /f /q "%SrcDir%\%%a"
  )
)
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF[/code]

jamesst 发表于 2009-6-12 17:18

完全ok了,楼主的功力不是一般的强啊,拜服~~~~~~

qq43142691 发表于 2009-6-14 02:25

[quote]原帖由 [i]Batcher[/i] 于 2009-6-12 13:13 发表 [url=http://bbs.bathome.net/redirect.php?goto=findpost&pid=31366&ptid=3334][img]http://bbs.bathome.net/images/common/back.gif[/img][/url]
@echo off
::如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
rem 指定待删除文件的存放路径
set SrcDir=C:\Test
rem 指定天数
set DaysAgo=7
rem 假设日期格式为:2009-06-12 星期五
call :Date ... [/quote]

如果我猜的没错的话...这个是 cn-dos 联盟里面的吧...

Batcher 发表于 2009-6-14 12:22

回复 15楼 的帖子

非常可惜的是,你猜错了。
顶楼说的很清楚,日期函数是 Ritchie Lawrence 写的。

xiongmao 发表于 2009-7-11 16:00

请教楼主,我的系统2000 SERVER ,日期格式为星期六 2009-07-11 ,怎么实现 利用方案三,出现日期判断不正确的现象“E:\>(if "09-07-11 14:46 " LEQ "2009-07-05" ”,如何批处理实现?谢谢!

Batcher 发表于 2009-7-11 16:27

回复 17楼 的帖子

打开注册表编辑器,看看这个键值是什么样子的:
HKEY_CURRENT_USER\Control Panel\International\sShortDate

xiongmao 发表于 2009-7-13 09:14

回复楼主:yyyy-MM-dd

xiongmao 发表于 2009-7-13 09:21

运行,cmd,echo %date%,显示格式为:星期一  2009-07-13

Batcher 发表于 2009-7-13 09:43

回复 20楼 的帖子

[code]@echo off
::如果演示结果无误,把del前面的echo去掉,即可实现真正删除。
rem 指定待删除文件的存放路径
set SrcDir=C:\Test\BatHome
rem 指定天数
set DaysAgo=1
rem 假设日期格式为:星期一 2009-07-13
call :DateToDays %date:~4,4% %date:~9,2% %date:~12,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%
for /r "%SrcDir%" %%a in (*.*) do (
  if "%%~ta" leq "%DstDate%" (
    if exist "%%a" (
      echo del /f /q "%%a"
    )
  )
)
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF[/code]

xiongmao 发表于 2009-7-13 09:53

你好 楼主 还是这个情况(if "09-07-12 04:04 " LEQ "2009-07-10"
并且不该删除的文件 提示也有删除

xiongmao 发表于 2009-7-13 10:06

运行显示如下,制定三天前的,但是今天的文件也提示将被删除


E:\>rem 指定待删除文件的存放路径

E:\>set SrcDir=e:\crm

E:\>rem 指定天数

E:\>set DaysAgo=3

E:\>rem 假设日期格式为:星期一 2009-07-13

E:\>call :DateToDays 2009 07 13 PassDays

E:\>setlocal ENABLEEXTENSIONS

E:\>set yy=2009  & set mm=07  & set dd=13

E:\>if 12009 LSS 200 if 12009 LSS 170 (set yy=202009 )  else (set yy=192009 )

E:\>set /a dd=10013%100,mm=10007%100

E:\>set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2

E:\>set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633

E:\>endlocal & set PassDays=14438  & goto :EOF

E:\>set /a PassDays-=3

E:\>call :DaysToDate 14435 DstYear DstMonth DstDay

E:\>setlocal ENABLEEXTENSIONS

E:\>set /a a=14435+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a

E:\>set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5

E:\>set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10

E:\>(if 7 LSS 10 set mm=07 )  & (if 10 LSS 10 set dd=010 )

E:\>endlocal & set DstYear=2009  & set DstMonth=07  & set DstDay=10  & goto :EOF


E:\>set DstDate=2009-07-10

E:\>for /R "e:\crm" %a in (*.*) do (if "%~ta" LEQ "2009-07-10" (if exist "%a" (e
cho del /f /q "%a" ) ) )

E:\>(if "08-10-30 08:21 " LEQ "2009-07-10" (if exist "e:\crm\20081030082017hjfor
est@技术规范确认书及项目明细.xls" (echo del /f /q "e:\crm\20081030082017hjforest
@技术规范确认书及项目明细.xls" ) ) )
del /f /q "e:\crm\20081030082017hjforest@技术规范确认书及项目明细.xls"

E:\>(if "08-10-30 08:27 " LEQ "2009-07-10" (if exist "e:\crm\20081030082615hjfor
est@华俊和集团车型对照表.xls" (echo del /f /q "e:\crm\20081030082615hjforest@华
俊和集团车型对照表.xls" ) ) )
del /f /q "e:\crm\20081030082615hjforest@华俊和集团车型对照表.xls"

E:\>(if "08-10-30 08:41 " LEQ "2009-07-10" (if exist "e:\crm\20081030083809hjlll
@营销服务部各岗位人员信息表.doc" (echo del /f /q "e:\crm\20081030083809hjlll@营
销服务部各岗位人员信息表.doc" ) ) )
del /f /q "e:\crm\20081030083809hjlll@营销服务部各岗位人员信息表.doc"

E:\>(if "09-07-12 04:04 " LEQ "2009-07-10" (if exist "e:\crm\mycrm50200907120400
00.bak" (echo del /f /q "e:\crm\mycrm5020090712040000.bak" ) ) )
del /f /q "e:\crm\mycrm5020090712040000.bak"

E:\>(if "09-07-13 04:04 " LEQ "2009-07-10" (if exist "e:\crm\mycrm50200907130400
00.bak" (echo del /f /q "e:\crm\mycrm5020090713040000.bak" ) ) )
del /f /q "e:\crm\mycrm5020090713040000.bak"

E:\>(if "09-07-11 14:46 " LEQ "2009-07-10" (if exist "e:\crm\新建 WPS演示 演示文
稿.dps" (echo del /f /q "e:\crm\新建 WPS演示 演示文稿.dps" ) ) )
del /f /q "e:\crm\新建 WPS演示 演示文稿.dps"

E:\>pause
请按任意键继续 . . .

Batcher 发表于 2009-7-13 12:41

回复 22楼 的帖子

能否把以下注册表分支导出来,传到论坛上来看看:
HKEY_CURRENT_USER\Control Panel\International\

xiongmao 发表于 2009-7-13 14:32

截图如下两图片

Batcher 发表于 2009-7-13 22:10

回复 25楼 的帖子

dir命令的结果如何呢?

[table=100%,black][tr][td][size=1][color=white]C:\Test>dir
驱动器 C 中的卷没有标签。
卷的序列号是 9033-65A2

C:\Test 的目录

2009-07-06  21:13    <DIR>          .
2009-07-06  21:13    <DIR>          ..
2009-07-06  21:21                11 test.bat
2009-07-06  21:03                 0 新建 文本文档.tx.jpg
2009-07-06  21:03                 0 新建 文本文档.txt.jpg
               3 个文件             11 字节
               2 个目录 15,391,432,704 可用字节
[/color][/size][/td][/tr][/table]

把sShortDate改成yyyy-M-d再试试?

kingwu 发表于 2009-8-12 18:41

请教下LZ,能不能按小时来删除呢
在线等,谢谢先了

Batcher 发表于 2009-8-12 21:25

回复 27楼 的帖子

小时的计算跟天数的计算非常类似,可以参照方案二的思路,调用 Ritchie Lawrence 批处理函数库中的代码:
[url]http://bbs.bathome.net/thread-3056-1-1.html[/url]

kingwu 发表于 2009-8-12 22:22

先谢过了



call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

%date:~0,4% %date:~5,2% %date:~8,2%  它是根据什么结论获取来的,另reg里面的内容格式是否会有变动?(小时制,目前只能用分钟替代小时)  另如果分钟的时间太长 会不会出现时间差呢?

[[i] 本帖最后由 kingwu 于 2009-8-12 22:51 编辑 [/i]]

Batcher 发表于 2009-8-13 20:56

回复 29楼 的帖子

根据系统日期格式为yyyy-mm-dd来获取
有可能
不会

页: [1] 2 3 4

Powered by Discuz! Archiver 7.2  © 2001-2009 Comsenz Inc.