批处理之家's Archiver

HAT 发表于 2009-10-4 19:33

VBS简明教程

转自:[url]http://hi.baidu.com/xuejinglan[/url][code]◎VBS脚本编程简明教程之一(为什么要使用VBS?)

     在Windows中,学习计算机操作也许很简单,但是很多计算机工作是重复性劳动,例如你每周也许需要对一些计算机文件进行复制、粘贴、改名、删除,也许你每天启动计算机第一件事情就是打开WORD,切换到你喜爱的输入法进行文本编辑,同时还要播放优美的音乐给工作创造一个舒心的环境,当然也有可能你经常需要对文本中的某些数据进行整理,把各式各样的数据按照某种规则排列起来……。这些事情重复、琐碎,使人容易疲劳。
     第三方软件也许可以强化计算机的某些功能,但是解决这些重复劳动往往事倍功半,我也尝试过使用计算机语言编写程序来解决这些问题,但是随之而来的命令、语法、算法、系统框架和类库常常让我觉得这样是否有必要,难道就是因为猪毛比较难拔,所以我就要去学习机械,为自己设计一个拔猪毛机吗?
     VBS是一种Windows脚本,它的全称是:Microsoft Visual Basic Script Editon.(微软公司可视化BASIC脚本版),VBS是Visual Basic的一个抽象子集,是系统内置的,用它编写的脚本代码不能编译成二进制文件,直接由Windows系统执行(实际是一个叫做宿主host的解释源代码并执行),高效、易学,但是大部分高级语言能干的事情,它基本上都具备,它可以使各种各样的任务自动化,可以使你从重复琐碎的工作中解脱出来,极大的提高工作效率。
     我个人认为VBS脚本其实就是一种计算机编程语言,但是由于缺少计算机程序设计语言中的部分要素,对于事件的描述能力较弱,所以称为脚本,它最方便的地方就是提供了对COM对象的简便支持。那么什么是COM对象呢?
     我这样理解,COM对象就是一些具有特定函数功能项程序模块,他们一般以ocx或者dll作为扩展名,你只要找到包含有你需要的功能的模块文件,并在脚本中规范的引用,就可以实现特定的功能,也就是说VBS脚本就是调用现成的"控件"作为对象,用对象的属性和方法实现目的,完全免去了编写代码、设计算法等等麻烦。说白了,我不是觉得拔猪毛麻烦么?我发觉xx机(比如真空离心器)有一个功能可以实现脱毛,ok,我把它拿来给猪脱毛。什么?大材小用?太浪费资源了?天哪,那是计算机芯片的事情,死道友不死贫道,反正我的事情是方便快速的解决了,这就行了。
     最方便的是它甚至不需要专门的开发环境,在你的计算机中,只要有notepad,就可以编写VBS脚本了,并且可以直接执行。[/code]打包下载:
[url=http://pan.baidu.com/share/link?shareid=3785567446&uk=1124163200]http://pan.baidu.com/share/link?shareid=3785567446&uk=1124163200[/url]

HAT 发表于 2009-10-4 19:34

[code]◎VBS脚本编程简明教程之二(如何开始第一个VBS脚本?)

      就像多数计算机教程一样 ,我们从"Hello  World!"程序开始我们的练习。什么?不知道是什么意思?就是说大部分的计算机程序设计教程开篇入门都是编写一个小程序,执行这个程序的结果就是在计算机的屏幕上或者dos窗口中显示一行文字:Hello  World!好了,我们开始吧。
      打开你的"记事本"程序,在编辑窗口填写:MsgBox "Hello World!"
      然后用鼠标单击"文件"菜单,单击"保存",把"保存在"一栏设为桌面,在"文件名"一栏中填写kk.vbs,单击"保存"就可以了。然后最小化"记事本"窗口,在桌面上寻找你刚刚保存的kk.vbs,然后双击。看到弹出的对话框了没有,单击"确定",对话框消失了。难看了点,不过确实是你编写的第一个脚本程序。
      说明之一:上面的操作中,保存位置放在桌面,仅仅是为了执行方便,你保存到其他的地方完全没有问题,只要你知道你保存在什么地方就可以了,什么?是废话,自己保存的当然知道保存在那里了。不,自己保存的文件自己找不到的人我见的多了去了。文件名你可以随意填写,不一定非要写kk,只要符合Windows的文件命名规则就可以了,但是扩展名必须是VBS,什么?不知道什么是扩展名?就是文件名中"."后的那部分,简单说,就是VBS脚本文件命名时必须是:xxx.vbs,其中xxx你随意。
      说明之二:在记事本编辑窗口中写的这行是什么意思?MsgBox是VBS内建的函数,每一个函数都可以完成一定的功能,你只需要按照语法要求,在函数的相应部分填写相应的内容就可以了,这部分内容我们称为参数,当然函数执行的结果我们称为返回值,一个函数可以有返回值也可以没有,可以有参数也可以没有。你不用了解函数是怎么运作的,只要了解这个函数能干什么就行了。
MsgBox语法:MsgBox  "对话框内容", , "对话框的标题"
你不妨用记事本打开刚才的文件在编辑窗口中输入:MsgBox "Hello World!" , , "系统提示"
执行一下,看看效果和位置。
      说明之三:如果执行失败,看看你的标点符号,所有的标点符号必须是在英文状态下输入的。
当然,这个脚本实在是太简单了,甚至连最简单的交互都没有,所以你可以把脚本这样修改一下:
Dim name
name=InputBox("请输入你的名字:","名称")
MsgBox  name, , "您的名字是"
保存执行一下,看到弹出的对话框了么?填入你的名字,点确定,看到结果了吗?
说明之一:第一句是定义变量,Dim是定义变量的语句
其格式为:Dim 变量1,变量2……,
VBS只有一种变量类型,所以不用声明变量类型。系统会自动分辨变量类型。
说明之二:InputBox是VBS内建的函数,可以接受输入的内容,其语法格式为:
InputBox("对话框内容","对话框标题")
第二句的意思是接受用户的输入,并把输入结果传递给变量name。
好了,到此脚本基本的输入输出函数都有了,已经可以完成一些比较简单的功能了,你可以编写一个简单的脚本,然后拷贝的"程序"—>"启动"中,然后重新启动计算机看看结果。[/code]

HAT 发表于 2009-10-4 19:34

[code]◎VBS脚本编程简明教程之三(VBS的基本语法)

VBScript基础知识

一、变量

1、所有单引号后面的内容都被解释为注释。
2、在VBScript中,变量的命名规则遵循标准的命名规则,需要注意的是:在VBScript中对变量、方法、函数和对象的引用是不区分大小写的。在申明变量时,要显式地申明一个变量,需要使用关键字Dim来告诉VBScript你要创建一个变量,并将变量名称跟在其后。申明多个同类型变量,可以用逗号分隔。注意:VBScript中不允许在申明变量的时候同时给变量赋值。但是允许在一行代码内同时对两个变量进行赋值,中间用冒号分隔。
3、你可以使用OptionExplicit来告诉宿主变量必须先声明后使用。
4、VBScript在定义时只有一种变量类型,在实际使用中需要使用类型转换函数来将变量转换成相应的变量类型。
CBool函数将变量转换成布尔值;
CByte函数将变量转换为0到255之间的整数。
CCur函数、CDbl函数和CSng函数将变量转换为浮点数值,前者只精确到小数点后四位,后两者要更加精确,数值的范围也要大的多。
CDate函数将变量转换为日期值。
CInt函数和CLng函数将变量转换为整数,后者的范围比前者要大的多。
CStr函数将变量转换为字符串。

二、数组

数组的定义与变量非常类似,只需要在变量后描述这个数组的个数和维数。需要注意的是:数组的下标总是从0开始,而以数组定义中数值减一结束。也就是说你以要定义一个有十个数据的数组,将这样书写代码:Dim Array(9),同样,当你要访问第五个元素时,实际的代码是Array(4)。当然,你可以通过不指定数组的个数和维数来申明动态数组。等到数组的个数和维数固定后,使用关键字ReDim来改变数组。注意,在改变数组的大小时,数组的数据会被破坏,使用关键字preserve来保护数据。例如:
ReDim preserve Array(个数,维数)

三、操作符

在VBScript运算符中,加减乘除都是我们常用的符号,乘方使用的是 ^ ,取模使用的Mod。
在比较操作符中,等于、小于、大于、小于等于、大于等于都与我们常用的符号是一致的,而不等于是小于和大于连用。
逻辑运算符为:和操作AND,非操作NOT,或操作OR
你可以使用操作符 + 和操作符 & 来连接字符串,一般使用&操作符;
另外还有一个比较特殊的操作符Is用来比较对象,例如按钮对象,如果对象是同一类型,结果就是真,如果对象不是同一类型,结果就是假。

四、条件语句主要有if……then语句和selectcase语句两种形式

在if……then语句中,其基本形式为:
If  条件  then
处理条件的语句;
……
Endif
基本形式只能对单个条件进行验证,如果有两个条件,则需要在基本形式中添加单行语句else,如果还有更多的条件需要验证,则需要添加语句
Elseif 条件  then
处理条件语句

在selectcase语句中,其基本形式为:
Select  case  变量
Case  条件值
处理条件语句
Select  case  变量
Case  条件值
处理条件语句
......
case  else
处理语句
End  select
注意:在执行字符串比较时,需要特别注意大小写,一般情况下,我们在比较前,使用lcase函数将字符串转换成小写,使用ucase函数将字符串转换成大写大写。

五、循环控制语句

循环控制语句有for……next循环、for……each循环、do……while循环、do……until循环、while循环五种形式。
在使用循环控制语句前,首先要对循环条件进行判断,如果循环次数是有固定次数的,那么使用For……next循环,其结构为:
For   计数器变量=开始计数值  to  最后计数值
执行循环体
Next

如果是需要对数组或对象集合中的每一个元素进行判断,则需要使用for……each循环,其结构为:
For  each  循环计数变量  in  要查看的对象或数组
执行处理语句
Next
注意:在上述两种循环中随时可以使用exit  for来退出循环

如果你希望在条件满足时执行一段代码则使用do……while语句,结构为:
Do  while  条件
执行循环体
Loop

如果你希望在条件不满足时执行代码,则使用do……until语句,结构为:
Do until 条件
执行循环体
Loop
当然,在这两种循环语句中,你可以使用exit  do来退出循环

最后一种循环语句是条件满足时一直执行循环,
While  条件
执行循环体
Wend

六、使用过程

常用的过程有两种,一种为函数,给调用者返回值,一种为子程序,无返回值,还有一种叫事件的特殊子程序,用的比较少。
函数的基本定义方法为:
Function  函数名称(参数列表)
函数代码
函数名称=某值 ‘用来返回值
end  function
子程序一些都类似,不过没有返回值
注意:尽管在定义子程序的时候,参数列表要加括号,但在调用子程序的时候,参数列表不加括号,括号只在函数中使用。另外,子程序不能在表达式中使用。
而函数只能出现在赋值语句的右边,或者表达式中,函数不能直接使用,如果必须直接使用函数,则必须使用call语句调用,并取消返回值[/code]

HAT 发表于 2009-10-4 19:35

[code]◎VBS脚本编程简明教程之四(如何利用VBS运行外部程序?)

     VBS只提供了编程的一个基本框架,用户可以使用VBS来定义变量、过程和函数,VBS也提供了一些内部函数和对象,但是VBS没有提供任何命令来访问Windows系统内部的部件,但是值得庆幸的是,VBS虽然不能自己完成这些任务,但是它提供了一条极为方便、功能也相当强的命令——CreateObject,这条命令可以访问windows系统内安装的所有com对象,并且可以调用这些部件中存放的命令。
     于是问题解决了,比如说,我手头有1000个小文本,我首先要对每一个文本的语法进行查错和修改,然后按照预先定义好的规则对这些文本进行排序,最后将这些文本合并成为一个文件。正常情况下,我们需要把打开第一个小文本,然后把它复制到WORD中,然后利用里面的除错功能进行除错和修改,然后再导入到EXCEL中进行排序,将这个过程重复1000遍,然后再将所有得到的文本复制到一个大文本中。实在是太枯燥、工作量太大了。有了VBS和CreateObject,问题得到解决,我只需要找到相应的模块,调用相应的功能就可以了,作为脚本,把一个枯燥的过程重复1000次,本就是它的拿手好戏。好了,我们走入正题,从最简单的启动一个程序开始。
WSH也就是用来解析VBS的宿主,本身包含了几个个常用对象:
1、Scripting.FileSystemObject  —>  提供一整套文件系统操作函数
2、Scripting.Dictionary  —>  用来返回存放键值对的字典对象
3、WScript.Shell  —>  提供一套读取系统信息的函数,如读写注册表、查找指定文件的路径、读取DOS环境变量,读取链接中的设置
4、WScript.NetWork  —>  提供网络连接和远程打印机管理的函数。
其中,所有Scripting对象都存放在SCRRUN.DLL文件中,所有的WScript对象都存放在WSHOM.ocx文件中。
现在我们需要的是第三个对象,好了,让我们先连接一下对象看看,在记事本的编辑窗口中输入:
Set ObjShell = CreateObject("WScript.Shell")
ObjShell.Run "notepad"
同样,保存执行。那么看到了一个什么样的结果呢?在桌面上又打开了一个记事本。
     说明之一:Set是VBS指令,凡是将一对象引用赋给变量,就需要使用Set关键字。那么什么是对象引用呢?凡是字符串、数值、布尔值之外的变量都是对象引用。ObjShell是变量名,可以随意修改。
     说明之二:凡是正确引用的对象,其本身内置有函数和变量,其引用方法为在变量后加".",后紧跟其实现功能的函数就可以了。ObjShell.run 的意思就是调用WScript.Shell中的运行外部程序的函数Run,notepad是记事本程序的文件名。当然你也可以改成"calc",这是计算器的文件名,winword是word的文件名,等等吧,所有可执行文件的文件名都可以。但是需要注意的是,如果你要执行的可执行文件存放的地方不是程序安装的常用路径,一般情况下,需要提供合法的路径名,但是Fun在运行解析时,遇到空格会停止,解决的方法是使用双引号,例如:在我的机器上运行qq,代码为:
ObjShell.Run """C:\Program Files\QQ2006\QQ.exe"""  ‘注:三个引号
好, 我们再进一步,启动两个程序会如何呢?
输入如下代码:
Set objShell = CreateObject("WScript.Shell")
objShell.Run "notepad"
objShell.Run "calc"
执行会如何呢?两个程序基本上同时启动了。如果我们需要先启动notepad再启动calc将如何呢?很简单在需要顺序执行的代码后加 , , True参数就可以了。好了输入代码:
Set objShell = CreateObject("WScript.Shell")
objShell.Run "notepad" ,,true
objShell.Run "calc"
看看执行的结果怎么样吧!
     总结:run函数有三个参数,第一个参数是你要执行的程序的路径,第二个程序是窗口的形式,0是在后台运行;1表示正常运行;2表示激活程序并且显示为最小化;3表示激活程序并且显示为最大化;一共有10个这样的参数我只列出了4个最常用的。第三个参数是表示这个脚本是等待还是继续执行,如果设为了true,脚本就会等待调用的程序退出后再向后执行。
其实,run做为函数,前面还有一个接受返回值的变量,一般来说如果返回为0,表示成功执行,如果不为0,则这个返回值就是错误代码,可以通过这个代码找出相应的错误[/code]

HAT 发表于 2009-10-4 19:35

[code]◎VBS脚本编程简明教程之五(错误处理)

      引发错误的原因有很多,例如用户输入了错误类型的值,或者脚本找不到必需的文件、目录或者驱动器,我们可以使用循环技术来处理错误,但是VBS本身也提供了一些基本技术来进行错误的检测和处理。

1、最常见的错误是运行时错误,也就是说错误在脚本正在运行的时候发生,是脚本试图进行非法操作的结果。例如零被作为除数。在VBS中,任何运行时错误都是致命的,此时,脚本将停止运行,并在屏幕上显示一个错误消息。你可以在脚本的开头添加
On  Error Resume  Next
这行语句可以告诉VBS在运行时跳过发生错误的语句,紧接着执行跟在它后面的语句。发生错误时,该语句将会把相关的错误号、错误描述和相关源代码压入错误堆栈。

2、虽然On Error Resume Next语句可以防止VBS脚本在发生错误时停止运行,但是它并不能真正处理错误,要处理错误,你需要在脚本中增加一些语句,用来检查错误条件并在错误发生时处理它。
VBScript提供了一个对象err对象,他有两个方法clear,raise,5个属性:description,helpcontext,helpfile,number,source
err对象不用引用实例,可以直接使用,例如:
on error resume next
a=11
b=0
c=a/b
if err.number<>0 then
WScript.echo err.number & err.description  & err.source
end if[/code]

HAT 发表于 2009-10-4 19:35

[code]◎VBS脚本编程简明教程之六(修改注册表)

VBS中修改注册表的语句主要有:

1、读注册表的关键词和值:
可以通过把关键词的完整路径传递给wshshell对象的regread方法。例如:
set ws=WScript.CreateObject("WScript.shell")
v=ws.regread("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\nwiz")
WScript.echo v

2、写注册表
使用wshshell对象的regwrite方法。例子:
path="HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\"
set ws=WScript.CreateObject("WScript.shell")
t=ws.regwrite(path & "jj","hello")
这样就把
HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\jj这个键值改成了hello.不过要注意:这个键值一定要预先存在

如果要创建一个新的关键词,同样也是用这个方法。
path="HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\run\sssa2000\love\"
set ws=WScript.CreateObject("WScript.shell")
val=ws.regwrite(path,"nenboy")
val=ws.regread(path)
WScript.echo val

删除关键字和值
使用regdelete方法,把完整的路径传递给regdelete就可以了
val=ws.regdel(path)
注意,如果要删除关键词的值的话 一定要在路径最后加上"\",如果不加斜线,就会删除整个关键词。[/code]

HAT 发表于 2009-10-4 19:36

[code]◎VBS脚本编程简明教程之七(FSO的常见对象和方法)

      文件系统是所有操作系统最重要的部分之一,脚本经常会需要对文件及文件夹进行访问和管理,在VBS中对桌面和文件系统进行访问的顶级对象是FileSystemObject(FSO),这个对象特别复杂,是VBS进行文件操作的核心。此节内容应了如指掌。

FSO包含的常见对象有:
Drive对象:包含储存设备的信息,包括硬盘、光驱、ram盘、网络驱动器
Drives集合:提供一个物理和逻辑驱动器的列表
File  对象:检查和处理文件
Files 集合:提供一个文件夹中的文件列表
Folder对象:检查和处理文件夹
Folders集合:提供文件夹中子文件夹的列表
Textstream对象:读写文本文件

FSO的常见方法有:
BulidPath:把文件路径信息添加到现有的文件路径上
CopyFile:复制文件
CopyFolder:复制文件夹
CreateFolder:创建文件夹
CreateTextFile:创建文本并返回一个TextStream对象
DeleteFile:删除文件
DeleteFolder:删除文件夹及其中所有内容
DriveExists:确定驱动器是否存在
FileExists:确定一个文件是否存在
FolderExists:确定某文件夹是否存在
GetAbsolutePathName:返回一个文件夹或文件的绝对路径
GetBaseName:返回一个文件或文件夹的基本路径
GetDrive:返回一个drive对象
GetDriveName:返回一个驱动器的名字
GetExtensionName:返回扩展名
GetFile:返回一个file对象
GetFileName:返回文件夹中文件名称
GetFolder:返回一个文件夹对象
GetParentFolderName:返回一个文件夹的父文件夹
GetSpecialFolder:返回指向一个特殊文件夹的对象指针
GetTempName:返回一个可以被createtextfile使用的随机产生的文件或文件夹的名称
MoveFile:移动文件
MoveFolder:移动文件夹
OpenTextFile:打开一个存在的文件并返回一个TextStream对象[/code]

HAT 发表于 2009-10-4 19:37

[code]◎VBS脚本编程简明教程之八(FSO中文件夹的基本操作)

1、使用fso
由于fso不是wsh的一部分,所以我们需要建立他的模型
例如set fs=WScript.CreateObject("scripting.filesystemobject")
这样就建立了fso的模型。如果要释放的话也很简单,set fs=nothing

2、使用文件夹
创建(先检查该文件夹是否存):
Dim fs,s //定义fs、s两个变量
set fs=WScript.CreateObject("scripting.filesystemobject") //fs为FSO实例
if (fs.folderexists("c:\temp")) then //判断c:\temp文件夹是否存在
s="is available"
else
s="not exist"
set foldr=fs.createfolder("c:\temp") //不存在则建立
end if

删除:  set fs=WScript.CreateObject("scripting.filesystemobject")
fs.deletefolder("c:\windows")

拷贝: set fs=WScript.CreateObject("scripting.filesystemobject")
fs.copyfolder "c:\data" "d:\data"
注意:如果c:\data 和d:\data都存在,脚本会出错,复制也就会停止,如果要强制覆盖,使用fs.copyfolder "c:\data" "d:\data",true

移动:  set fs=WScript.CreateObject("scripting.filesystemobject")
fs.movefolder "c:\data" "d:\data"

我们可以使用统配符,来方便操作:
例如, fs.movefolder :c:\data\te*" , "d:\working"
注意:在目的路径最后没有使用"\" 也就是说我没有这样写:
fs.movefolder c:\data\te*" , "d:\working\"
这样写的话,如果d:\working 目录不存在,windows就不会为我们自动创建这个目录。
注意:上面我们所举的例子都是在利用fso提供的方法,如果使用folder对象也完全是可以的:
set fs= WScript.CreateObject("scripting.filesystemobject")
set f=fs.getfolder("c:\data")
f.delete  //删除文件夹c:\data。如果有子目录,也会被删除
f.copy "d:\working",true    //拷贝到d:\working
f.move "d:\temp"    //移动到d:\temp

3、特殊文件夹
一般指的就是系统文件夹:\windows\system32, 临时文件夹,windows文件夹,在前几篇的时候,我们提过一下:例如
set fs=WScript.CreateObject("scripting.filesystemobject")
set wshshell=WScript.CreateObject("WScript.shell")
osdir=wshshell.expandenvironmentstrings("%systemroot%")
set f =fs.getfolder(osdir)
WScript.echo f
当然,还有简单的方法 那就是使用getspecialfolder()
这个方法使用3种值:
0  表示windows文件夹,相关常量是windowsfolder
1  系统文件夹,相关常量是systemfolder
2  临时目录,相关常量temporaryfolder
例如:
set fs=WScript.CreateObject("scripting.filesystemobject")
set wfolder=fs.getspecialfolder(0) ‘返回windows目录
set wfolder=fs.getspecialfolder(1) ‘返回system32\
set wfolder=fs.getspecialfolder(2)'返回临时目录[/code]

HAT 发表于 2009-10-4 19:37

[code]◎VBS脚本编程简明教程之九(妙用SendKeys简化重复操作)

      每次开机的时候,你想自动登陆你的QQ或者网志吗?巧妙使用VBS中的SendKeys命令(这个命令的作用就是模拟键盘操作,将一个或多个按键指令发送到指定Windows窗口来控制应用程序运行),可以极大的方便我们的常用操作。其使用格式为:
Object.SendKeys string
其中:
Object:为WshShell对象,即脚本的第一行为:Set WshShell=WScript.CreateObject("WScript.Shell"),将Object替换为WshShell
"string":表示要发送的按键指令字符串,需要放在英文双引号中。它包含如下内容:

1.基本键:一般来说,要发送的按键指令都可以直接用该按键字符本身来表示,例如要发送字母"x",使用"WshShell.SendKeys "x""即可。当然,也可直接发送多个按键指令,只需要将按键字符按顺序排列在一起即可,例如,要发送按键"cfan",可以使用"WshShell.SendKeys "cfan""

2.特殊功能键:对于需要与Shift、Ctrl、Alt三个控制键组合的按键,SendKeys使用特殊字符来表示:
Shift +
Ctrl ^
Alt %
      如要发送的组合按键是同时按下Ctrl+E,需要用"WshShell.SendKeys "^e""表示,如果要发送的组合按键是按住Ctrl键的同时按下E与C两个键,这时应使用小括号把字母键括起来,书写格式为"WshShell.SendKeys "^(ec)"",这里要注意它与"WshShell.SendKeys "^ec""的区别,后者表示组合按键是同时按住Ctrl和E键,然后松开Ctrl键,单独按下"C"字母键。由于"+"、"^"这些字符用来表示特殊的控制按键了,如何表示这些按键呢?只要用大括号括住这些字符即可。例如,要发送加号"+",可使用"WshShell.SendKeys "{+}""。另外对于一些不会生成字符的控制功能按键,也同样需要使用大括号括起来按键的名称:
发送回车键,需要用"WshShell.SendKeys "{ENTER}""表示
发送向下的方向键用"WshShell.SendKeys "{DOWN}""表示
      如果需要发送多个重复的单字母按键,不必重复输入该字母,SendKeys允许使用简化格式进行描述,使用格式为"{按键 数字}"。例如要发送10个字母"x",则输入"WshShell.SendKeys "{x 10}""即可。
例一:WshShell.SendKeys "^{ESC}u"
代码的含义为:按下Ctrl+Esc组合键(相当于按Win键)打开"开始"菜单,接着按U键打开"关机"菜单。
例二:让VBS脚本自动在记事本中输入一行文字"hello, welcome to cfan"。
Dim WshShell
Set WshShell=WScript.CreateObject("WScript.Shell")
WshShell.Run "notepad"
'暂停2秒,给notepad一个打开的时间,有时时间太短可能导致后面的字符无法进入编辑区
WScript.Sleep 2000
'AppActivate为寻找可执行程序的标题框,"无标题-记事本"内容你的自己打开看一下
WshShell.AppActivate "无标题 - 记事本"
WshShell.SendKeys "hello, welcome to cfan"

作业1:让脚本自动输入下面两段小短句
This is the most wonderful day of my life
because I'm here with you now
作业2:让脚本在输入短句后自动关闭记事本,并保存文件名为"test",注意关闭记事本可以直接使用组合按键Alt+F4来实现
例三:制作能自动定时存盘的记事本
我们最常用的记事本没有Word、WPS那样的自动定时存盘功能,其实利用VBS脚本再加上SendKeys命令,就能弥补这个遗憾。打开记事本,输入以下内容(为容易描述和分析,把代码分为四个部分):
'第一部分:定义变量和对象
Dim WshShell, AutoSaveTime, TXTFileName
AutoSaveTime=300000
Set WshShell=WScript.CreateObject("WScript.Shell")
TXTFileName=InputBox("请输入你要创建的文件名(不能用中文和纯数字):")
'第二部分:打开并激活记事本
WshShell.Run "notepad"
WScript.Sleep 2000
WshShell.AppActivate "无标题 - 记事本"
'第三部分:用输入的文件名存盘
WshShell.SendKeys "^s"
WScript.Sleep 300
WshShell.SendKeys TXTFileName
WScript.Sleep 300
WshShell.SendKeys "%s"
WScript.Sleep AutoSaveTime
'第四部分:自动定时存盘
While WshShell.AppActivate (TXTFileName)=True
WshShell.SendKeys "^s"
WScript.Sleep AutoSaveTime
Wend
WScript.Quit
将其保存为记事本.vbs,以后要使用记事本时,都通过双击这个脚本文件来打开。
程序说明:这个脚本的基本思路是定时向记事本发送Ctrl+S这个存盘组合键。
第一部分:定义了脚本中需要用到的变量和对象。"AutoSaveTime"变量用来设置自动存盘间隔,单位为毫秒,这里设置为5分钟。"TXTFileName"变量通过输入框取得你要创建的文本文件名称。
第二部分:运行记事本,对于Windows本身提供的程序,比如计算器等,可直接在"WshShell.Run"后输入程序名称,如"calc",对于非系统程序,则可输入完全路径,但要注意使用8.3格式输入,比如""D:\Progra~1\Tencent\QQ.exe""。
第三部分:这里用SendKeys命令执行了这样的操作流程(请注意每个操作之间延时命令的使用):在记事本中按Ctrl+S组合键→弹出保存文件的窗口→输入文件名→按Alt+S组合键进行保存(默认保存在"我的文档"目录)。
第四部分:定时存盘的关键,通过"While……Wend"这个当条件为"真"时循环命令,实现自动存盘代码"WshShell.SendKeys "^s""和定时代码"WScript.Sleep AutoSaveTime"的重复执行。因为不能让这个定时存盘循环一直执行,退出记事本后,必须自动退出脚本并结束循环,所以设计了一个循环判断条件"WshShell.AppActivate TXTFileName=True",当记事本运行中时,可以激活记事本窗口,这个条件运行结果为"True",定时存盘循环一直执行,退出记事本后,脚本无法激活记事本窗口,就会跳出循环,执行"Wend"后面的"WScript.Quit"退出脚本。
例四:快速登陆QQ软件。假设QQ号码是:10001,密码是:123456,隐身登陆:
set ws=WScript.CreateObject("WScript.shell")
    ws.run "C:\Progra~1\Tencent\QQ\QQ.exe",0
    WScript.Sleep 2000
    ws.AppActivate "QQ用户登录"
    ws.SendKeys "7015247"
    WScript.Sleep 200
    ws.SendKeys "{TAB}"
    ws.SendKeys "*********"
    WScript.Sleep 200
ws.SendKeys "{ENTER}"
例五:关机菜单立刻显身
打开记事本,输入以下命令,并将其保存为1.vbs:
set WshShell = CreateObject("WScript.Shell")
WshShell.SendKeys "^{ESC}u"
双击运行它,你会发现关机菜单立刻出现了。
将"WshShell.SendKeys "^{ESC}u""改为"WshShell.SendKeys "^+{ESC}"",运行一下看看是否打开了任务管理器
妙用SendKeys自动上网并登陆网志
将下面的脚本复制到一个文本文件中,并将其文件名命名为:自动登陆.vbs,然后将拨号软件及本脚本一起复制到程序——启动项中,就可以实现自动拨号上网,并登陆到网志上。
代码如下:
Set wshshell=CreateObject("WScript.shell")
wshshell.AppActivate "连接 MAE-301U 拨号连接"
WScript.Sleep 20000
wshshell.SendKeys "{enter}"
wshshell.Run "iexplore"
WScript.Sleep 2000
wshshell.AppActivate "hao123网址之家---实用网址,搜索大全,尽在www.hao123.com - Microsoft Internet Explorer" '引号中的内容修改为你的浏览器打开后标题栏中的内容
wshshell.SendKeys "%d"
wshshell.SendKeys "http://passport.baidu.com/?login"
wshshell.SendKeys "{enter}"
WScript.Sleep 2000
wshshell.SendKeys "此处修改为网志帐号"
wshshell.SendKeys "{tab}"
wshshell.SendKeys "此处修改为网志密码"
wshshell.SendKeys "{enter}"
'wshshell.SendKeys "%d"[/code]

HAT 发表于 2009-10-4 19:38

[code]◎VBS脚本编程简明教程之十(VBS脚本编程常用的编辑器)

1、VBSEDit汉化版
2、primalscript汉化版,可以对30多种脚本进行编辑[/code]

HAT 发表于 2009-10-4 19:38

[code]◎VBS脚本编程简明教程之十一(FSO中文件的基本操作)

一、文件属性:
在windows中,文件的属性一般用数字来表示:
0代表normal,即普通文件未设置任何属性。
1代表只读文件
2代表隐藏文件
4代表系统文件
16代表文件夹或目录
32代表存档文件
1024代表链接或快捷方式
例如:
set fs=WScript.CreateObject("scripting.filesystemobject")
set f=fs.getfile("d:\index.txt")
MsgBox f.Attributes  'attributes函数的作用是显示文件属性
需要说明的是:MsgBox显示的结果往往不是上面说明的数字,而是有关属性代表数字的和。

二、创建文件:object.createtextfile方法,注意创建前一般需要检查文件是否存在。
例如:set fso=WScript.CreateObject("scripting.filesystemobject")
if fso.fileexists("c:\kk.txt") then
MsgBox "文件已存在"
else
set f=fso.createtextfile("c:\kk.txt")
end if
如需要强制覆盖已存在的文件,则在文件名后加true参数。

三、复制、移动、删除文件:使用copyfile方法、movefile方法、deletefile方法。例如:
set fso=WScript.CreateObject("scripting.filesystemobject")
fso.copyfile "c:\kk.txt","d:\1\kk.txt",true   '如上文说述,true代表强制覆盖
fso.movefile "c:\kk.txt", "d:\"  '移动文件
fso.deletefile "c:\kk.txt"  '删除文件

四、文件的读写:
1、打开文件:使用opentextfile方法
如:set ts=fso.opentextfile("c:\kk.txt",1,true)
说明:第二个参数为访问模式,1为只读、2写入、8为追加;第三个参数指定如文件不存在则创建。
2、读取文件:read(x)读x个字符;readline读一行;readall全部读取
如:set ffile=fso.opentextfile("c:\kk.txt",1,true)
value=ffile.read(20)
line=ffile.readline
contents=ffile.readall
3、常见的指针变量:
atendofstream属性:当处于文件结尾的时候这个属性返回true。一般用循环检测是否到达文件末尾。例如:
do while ffile.atendofstream<>true
ffile.read(10)
loop
atendofline属性:如果已经到了行末尾,这个属性返回true。
Column属性(当前字符位置的列号)和line属性(文件当前行号):在打开一个文件后,行和列指针都被设置为1。
4、在文件中跳行:skip(x)  跳过x个字符;skipline  跳过一行
5、在文件中写入字符:可以用2(写入)和8(追加)的方式来写入
其方法有:write(x)写入x字符串;writeline(x)写入x代表的一行
writeblanklines(n) 写入n个空行
注意:最后一定要使用close方法关闭文件。读文件后一定要关闭,才能以写的方式打开。[/code]

HAT 发表于 2009-10-4 19:38

[code]◎VBS脚本编程简明教程之十二(使用系统对话框)

      在VBS脚本设计中,如果能使用windows提供的系统对话框,可以简化脚本的使用难度,使脚本人性化许多,很少有人使用,但VBS并非不能实现这样的功能,方法当然还是利用COM对象。
1、SAFRCFileDlg.FileSave对象:属性有:FileName — 指定默认文件名;FileType — 指定文件扩展名;OpenFileSaveDlg — 显示文件保存框体方法。
2、SAFRCFileDlg.FileOpen 对象:FileName — 默认文件名属性;OpenFileOpenDlg — 显示打开文件框体方法。
3、UserAccounts.CommonDialog对象:Filter — 扩展名属性("VBS File|*.vbs|All Files|*.*");
FilterIndex — 指定
InitialDir — 指定默认的文件夹
FileName — 指定的文件名
Flags — 对话框的类型
Showopen方法:
很简单,ok,让我们来举两个简单的例子:

例一:保存文件
Set objDialog = CreateObject("SAFRCFileDlg.FileSave")
Set objFSO = CreateObject("Scripting.FileSystemObject")
objDialog.FileName = "test"
objDialog.FileType = ".txt"
intReturn = objDialog.OpenFileSaveDlg
If intReturn Then
objFSO.CreateTextFile(objDialog.FileName & objdialog.filetype)
Else
WScript.Quit
End If
注意:1、SAFRCFileDlg.FileSave对象仅仅是提供了一个方便用户选择的界面,本身并没有保存文件的功能,保存文件还需要使用FSO对象来完成。2、用FileType属性来指定默认的文件类型。3、在调用OpenFileSaveDlg方法时,最好把返回值保存到一变量中,用它可以判断用户按下的是确定还是取消。

例二:.打开文件
set objFile = CreateObject("SAFRCFileDlg.FileOpen")
intRet = objFile.OpenFileOpenDlg
if intret then
MsgBox "文件打开成功!文件名为:" & objFile.filename
else
WScript.quit
end if

例三:比较复杂的打开文件对话框
Set objDialog = CreateObject("UserAccounts.CommonDialog")
objDialog.Filter = "VBS File|*.vbs"
objDialog.InitialDir = "c:\"
tfile=objDialog.ShowOpen
if tfile then
strLoadFile = objDialog.FileName
MsgBox strLoadFile
else
WScript.quit
end if
说明:在脚本中加入 objDialog.Flags = &H020 看看会出现什么结果。[/code]

HAT 发表于 2009-10-4 19:39

[code]◎VBS脚本编程简明教程之十三(WMI基础)

      WMI即Windows 管理规范,是用户管理本地和远程计算机的一种模型。通过它可以访问、配置、管理和监视几乎所有的 Windows 资源。WMI的语法十分简单,基本上常见的命名空间、对象等用几乎一模一样。它对应的是Windows里的WMI服务(winmgmt)。

一、WMI的起源
几年前,几家资深的计算机公司由于系统管理领域缺少标准,委托DMTF启动了CIM(通用信息模型)项目,理想的CIM是一种不受限制于任何特定实现环境的管理工具。WMI是CIM的微软实现,它有很多类是从CIM中派生出来的。

二、WMI的命名空间
那么命名空间是做什么作用的呢?我简单这样说,在同一段代码中,如果有两个变量或函数的名字完全相同,就会出现冲突。命名空间就是为解决变量、函数的命名冲突而服务的。解决的办法就是将你的变量定义在一个不同名字的命名空间中。就好像财政局有个张三,公安局也有个张三,但我们清楚,就是因为他们分属不同的单位。有些地方可能不太准确,但大致意思就是这样了。
WMI的命名空间创建了一个层次结构,有点类似于我们的目录文件结构。
1、  root-作为所有其他名字的占位符;
2、  root\default-与注册表操作有关的类;
3、  root\security-与系统安全有关的类;
4、  root\cimv2-从CIM派生的类,代表我们最常用的工作环境。

三、WMI的对象路径
WMI的对象路径用来在CIM库中定位类和它的事例,对象路径用两个反斜杠\\开头,第一个元素是目标计算机的名字,第二个元素是相应的WMI命名空间,第三个元素是相应的类名,并用 : 将它与命名空间分隔开来。例如:\\..\root\cimv2:win32_service
其中那个 . 代表是本地系统。

四、WMI的查询语言——WQL仅仅是ANSI SQL的一个子集,只能用于数据的提取。
数据、事件查询的基本语法为:
Select pro1 , pro2 , pro3  from myclass(myclassevent)
例如:Select name , path from Win32_share  说明:列出所有共享的名称和路径
也可以使用通配符 * ,例如:Select * from Win32_share
关键字Where 用于限定查询的范围。
例如:Select * from Win32_share where name="Admin"

五、WMI脚本中使用的三个步骤
步骤 1:连接到 WMI 服务
在任何 WMI 脚本中,第一个步骤都是建立一个到目标计算机上的 Windows 管理服务的连接。方法是调用 VBScript 的 Getobject 函数并将 WMI 脚本库的名字对象的名称(即"winmgmts:",后跟目标计算机的名称)传递到 Getobject,并返回一个对象的引用,此时,您就可以调用其提供的方法如:InstancesOf,正如方法名所示,InstancesOf 返回由资源的类名标识的托管资源的所有实例。
步骤 2:检索 WMI 托管资源的实例
一般采用WQL来实现。
步骤 3:显示 WMI 托管资源的属性
最后一个步骤是枚举 检索得到集合的内容。一般采用
For each enum in  myclass
……
Next       结构来实现。

六、WMI 测试器 (wbemtest.exe)验证脚本执行结果
现在,您对可用于浏览和查看 CIM 的工具已经有了一些认识,让我们使用 WMI 测试器 (wbemtest.exe) 来检查 Win32_Process 类定义,以便从在您的本地计算机上运行的进程检索一些属性。
1.打开一个命令提示,键入 C:\>按下 Enter 来开始 WMI 测试器工具。请注意,大部分按钮在主 WMI 测试器窗口上是被禁用的,这说明此时您没有连接到 WMI。
2.单击 "连接"按钮 连接到本地或远程计算机上的 WMI 服务。显示"连接"对话框,它提供一个标记为 名称空间 的文本输入区域,该区域默认值为 root\default。将 名称空间 区域的值更改为 root\cimv2,单击"连接"对话框的 连接 按钮返回到主 WMI 测试器窗口。
3.主窗口中左上角的命名空间标识符应该显示为 root\cimv2。请注意,所有的按钮现在都已启用,这说明在当前凭据环境下,您已经成功连接到本地主机上的 WMI。单击 枚举类别 打开"超类信息"对话框。
4.在"超类信息"对话框中,不要填写 输入超类别名称 区域,单击 递归 选项,单击 确定 以枚举 root\cimv2 名称空间中定义的所有 CIM 类。
请注意,列于"查询结果"对话框顶部的类是以两个下划线为开头的。这些是系统类。系统类是预定义的 CIM 类,支持内部 WMI 配置与操作,例如提供程序注册、命名空间安全性及事件通知等。现在,忽略系统类,向下滚动"查询结果"对话框直至看到以 CIM_ 开头的类。名称以 CIM_ 开头的类是由 DMTF 维护的核心与公共基类。继续向下滚动直至到达以 Win32_ 开头的类。名称以 Win32_ 开头的类是 Microsoft 扩展类,表示 Windows 特定的托管资源。如果这是您第一次检查 root\cimv2 命名空间,您可能希望熟悉root\cimv2 命名空间中的类的完整集合,尤其是有 Win32_ 前缀的类。
5.向下滚动"查询结果"对话框直至到达 Win32_Process 类,双击该类名打开 Win32_Process 对话框的对象编辑器。
6."对象编辑器"对话框显示被选定类的定义和实现的详细信息(属性和方法)。选择 Hide System Properties 复选框隐藏系统属性。剩余的 Win32_Process 属性表示您可以从在本地或远程计算机上运行的进程检索的信息。
运行如下代码:
strComputer = "."
Set wbemServices = Getobject("winmgmts:\\" & strComputer)
Set wbemObjectSet = wbemServices.InstancesOf("Win32_Process")
For Each wbemObject In wbemObjectSet
    WScript.Echo "Name:          " & wbemObject.Name      & vbCrLf & _
                 "   Handle:     " & wbemObject.Handle    & vbCrLf & _
                 "   Process ID: " & wbemObject.ProcessID
Next
7.在运行脚本之后,您可以用 WIMI 测试器验证脚本的结果。在 Win32_Process 对话框的对象编辑器中,单击 Instances。产生的查询结果对话框列出在计算机上运行的进程的实例。双击一个指定的进程实例,查看该实例的详细信息
阻止客人运行你不想运行的程序
很多人都有这样的经验,刚刚装好的系统,让人运行了一些你不想他运行的程序,比如说QQ,又是聊天,又是下载表情,不过一会,流氓插件、病毒、木马已经盘踞了你的计算机,常常是忍痛将这个程序卸载,可是不知情的人很自觉的下载安装,使整个系统无法正常运行。
其实用VBS和wmi结合起来,使你的计算机上有相应的程序安装,别人又无法运行起来太容易了,现在给出代码:
On Error Resume Next    '忽略所有的错误
Dim bag,pipe,honker,good
Do
good="."     '定义为本地计算机
set bag=getobject("winmgmts:\\"& good &"\root\cimv2")     'l连接到cimv2命名空间
set pipe=bag.execquery("select * from win32_process where name='qq.exe' or name='qqgame.exe' or name='winmine.exe'")    '看,这是我的计算机上不允许运行的程序,qq、qqgame、winmine(扫雷)如果你还有其他的程序不允许运行,很简单,在其中添加 or name='你不允许运行的程序名'
for each i in pipe
i.terminate()
'此行其实可有可无,有这行只是为了免去怀疑
MsgBox "发现盗版系统,现已进行功能限制!" & vbcrlf & "请使用正版软件!",,"微软提示"
next
WScript.sleep 60000    '每1分钟检测一次
loop
那么如果我自己想运行这些程序该怎么办呢?很简单,Ctrl+Alt+Del三个键齐按,打开windows任务管理器,在进程中结束WScript.exe和wmiprvse.exe进程的运行就可以了[/code]

HAT 发表于 2009-10-4 19:39

[code]◎VBS脚本编程简明教程之十四(使用dictionary对象)

    VBS中存在一个特殊的对象-dictionnary,是一个集合对象。一般情况下,我把这个特殊的集合想象为数组,可以使用其中内建的函数完成存储和操纵数据等基本任务,无须担心数据是在哪些行列,使用唯一的键进行访问或者是一个只能运行在内存中的数据库,并只有两个字段分别是:key和item,在使用中,字段key是索引字段。
set sdict=CreateObject("Scripting.Dictionary")
sdict.add "a","apple"
sdict.add "b","banana"
sdict.add "c","copy"
for each key in sdict.keys
MsgBox     "键名" &   key     & "是" & " = " & sdict (key)
next
sdict.removeall
这个脚本很简单,就是定义了一个 dictionary 对象的实例sdict,并加入了三条数据,然后对每一条数据进行了枚举,最后,将对象的实例清空。
Dictionary 对象的成员概要
属性和说明
CompareMode    设定或返回键的字符串比较模式
Count     只读。返回 Dictionary 里的键/条目对的数量
Item(key)  设定或返回指定的键的条目值
Key(key)  设定键值
方法和说明
Add(key,item)  增加键/条目对到 Dictionary
Exists(key)  如果指定的键存在,返回 True,否则返回 False
Items()  返回一个包含 Dictionary 对象中所有条目的数组
Keys()  返回一个包含 Dictionary 对象中所有键的数组
Remove(key)  删除一个指定的键/条目对
RemoveAll()   删除全部键/条目对[/code]

HAT 发表于 2009-10-4 19:40

[code]◎VBS脚本编程简明教程之十五(VBS内置函数)

Abs 函数:返回数的绝对值。
Array 函数:返回含有数组的变体。
Asc 函数:返回字符串首字母的 ANSI 字符码。
Atn 函数:返回数值的反正切。
CBool 函数:返回已被转换为 Boolean 子类型的变体的表达式。
CByte 函数:返回已被转换为字节子类型的变体的表达式。
CCur 函数:返回已被转换为货币子类型的变体的表达式。
CDate 函数:返回已被转换为日期子类型的变体的表达式。
CDbl 函数:返回已被转换为双精度子类型的变体的表达式。
Chr 函数:返回与指定的 ANSI 字符码相关的字符。
CInt 函数:返回已被转换为整形子类型的变体的表达式。
CLng 函数;返回已被转换为Long子类型的变体的表达式。
Cos 函数:返回角度的余弦。
CreateObject 函数:创建并返回对"自动"对象的引用。
CSng 函数:返回已被转换为单精度子类型的变体的表达式。
CStr 函数:返回已被转换为字符串子类型的变体的表达式。
Date 函数:返回当前系统日期。
DateAdd 函数:返回的日期已经加上了指定的时间间隔。
DateDiff 函数:返回两个日期之间的间隔。
DatePart 函数:返回给定日期的指定部分。
DateSerial 函数:返回指定年月日的日期子类型的变体。
DateValue 函数:返回日期子类型的变体。
Day 函数:返回日期,取值范围为 1 至 31。
Eval 函数:计算表达式并返回结果。
Exp 函数:返回 e (自然对数的底) 的多少次方。
Filter 函数:根据指定的筛选条件,返回含有字符串数组子集的、下限为 0 的数组。
Fix 函数:返回数的整数部分。
FormatCurrency 函数:返回的表达式为货币值格式,其货币符号采用系统控制面板中定义的。
FormatDateTime 函数:返回的表达式为日期和时间格式。
FormatNumber 函数:返回的表达式为数字格式。
FormatPercent 函数:返回的表达式为百分数(乘以 100)格式,后面有 % 符号。
GetObject 函数:返回从文件对"自动"对象的引用。
GetRef 函数:返回对能够绑定到一事件的过程的引用。
Hex 函数:返回一字符串,代表一个数的十六进制值。
Hour 函数:返回表示钟点的数字,取值范围为 0 至 23。
InputBox 函数:在对话框中显式一提示,等待用户输入文本或单击按钮,并返回文本框的内容。
InStr 函数:返回一个字符串在另一个字符串中首次出现的位置。
InStrRev 函数;返回一个字符串在另一个字符串中出现的位置,但是从字符串的尾部算起。
Int 函数:返回数的整数部分。
IsArray 函数:返回 Boolean 值,反映变量是否为数组。
IsDate 函数:返回 Boolean 值,反映表达式能否转换为日期。
IsEmpty 函数:返回 Boolean 值,反映变量是否已被初始化。
IsNull 函数:返回 Boolean 值,反映表达式是否含有无效数据(Null)。
IsNumeric 函数:返回 Boolean 值,反映表达式能否转换为数字。
IsObject 函数:返回 Boolean 值,反映表达式是否引用了有效的"自动"对象。
Join 函数:返回通过连接许多含有数组的子串而创建的字符串。
LBound 函数;返回指定维数数组的最小有效下标。
LCase 函数:返回的字符串已被转换为小写字母。
Left 函数:返回字符串最左边的指定数量的字符。
Len 函数:返回字符串中的字符数或存储变量所需的字节数。
LoadPicture 函数:返回图片对象。只用于 32 位平台。
Log 函数:返回数的自然对数。
LTrim 函数;返回去掉前导空格的字符串。
Mid 函数:从字符串中返回指定数量的字符。
Minute 函数:返回分钟数,取值范围为 0 至 59。
Month 函数:返回表示月份的数,取值范围为 1 至 12。
MonthName 函数:返回表示月份的字符串。
MsgBox 函数:在对话框中显示消息,等待用户单击按钮,并返回表示用户所击按钮的数值。
Now 函数:返回计算机的当前系统日期和时间。
Oct 函数:返回表示该数八进制数值的字符串。
Replace 函数:返回一字符串,其中指定的子串已被另一个子串替换了规定的次数。
RGB 函数:返回代表 RGB 颜色值的数字。
Right 函数:返回字符串最右边的指定数量的字符。
Rnd 函数:返回随机数。
Round 函数:返回指定位数、四舍五入的数。
RTrim 函数:返回去掉尾部空格的字符串副本。
ScriptEngine 函数:返回反映使用中的脚本语言的字符串。
ScriptEngineBuildVersion 函数:返回使用中的脚本引擎的编译版本号。
ScriptEngineMajorVersion 函数:返回使用中的脚本引擎的主版本号。
ScriptEngineMinorVersion 函数:返回使用中的脚本引擎的次版本号。
Second 函数:返回秒数,取值范围为 0 至 59。
Sgn 函数:返回反映数的符号的整数。
Sin 函数:返回角度的正弦值。
Space 函数:返回由指定数量的空格组成的字符串。
Split 函数:返回下限为 0 的、由指定数量的子串组成的一维数组。
Sqr 函数:返回数的平方根。
StrComp 函数:返回反映字符串比较结果的数值。
String 函数:返回指定长度的重复字符串。
StrReverse 函数:返回一字符串,其中字符的顺序与指定的字符串中的顺序相反。
Tan 函数:返回角度的正切值。
Time 函数:返回表示当前系统时间的"日期"子类型的"变体"。
Timer 函数:返回时经子夜 12:00 AM 后的秒数。
TimeSerial 函数:返回含有指定时分秒时间的日期子类型的变体。
TimeValue 函数:返回含有时间的日期子类型的变体。
Trim 函数:返回去掉前导空格或尾部空格的字符串副本。
TypeName 函数:返回一字符串,它提供了关于变量的变体子类型信息。
UBound 函数:返回指定维数数组的最大有效下标。
UCase 函数:返回的字符串已经被转换为大写字母。
VarType 函数:返回标识变体子类型的数值。
Weekday 函数:返回表示星期几的数值。
WeekdayName 函数:返回表示星期几的字符串。
Year 函数:返回表示年份的数值。[/code]

HAT 发表于 2009-10-4 19:40

[code]◎VBS脚本编程简明教程之十六(响应事件)

        什么是事件?在我看来,事件就象我们手机上的闹钟,闹钟一响,我们就要去做某些特定的事情。或者这样说,事件就像警钟,当程序运行时,有特殊的事情发生,就会激发事件,事件本身就是一条消息,如果你编写的脚本要对事件进行处理,就需要一个特殊的过程或者函数来接受和处理事件。那么这个特殊的过程或者函数在程序运行时,就不断的监听,看系统是否传来了相应的事件,一旦接受到事件,脚本对此作出反应。
        那么事件是从那里来的呢?是否需要我们在脚本中对事件进行编写呢?一般情况下,事件是某个程序在运行中的特殊状态发出的,我们不需要对事件进行编写,只需要编写处理事件的函数。比如说我们用VBS建立了ie的一个实例,那么当ie的窗口被关闭的时候,就会激发出一个叫做OnQuit的事件。
是不是脚本自然而然就能接受事件并进行处理呢?我们说不是的,在创建对象的时候,我们将使用WSH的CreateObject命令,例如:
Set objie=WScript.CreateObject("internetexplorer.application","event_")
注意到了吗?多了一个参数,这个参数的作用是什么呢?它叫做事件接收端,当脚本连接的对象包含事件时,如果对象调用的事件是OnBegin,那么WSH将会在脚本中调用一个event_OnBegin的事件处理程序。当然事件接受端并不是固定的,如果对象将其定义为MyObj_的话,那么事件处理程序将是:MyObj_OnBegin。
是否很熟悉?在打造个性化QQ一讲中,曾经出现过Window_OnSize(cx,cy)函数,它其实就是一个事件处理程序。
让我们来举个实际的例子完整的看看事件的处理过程:
Set objie=WScript.CreateObject("InternetExplorer.Application","event_")
objie.Visible=True
MsgBox "请关闭浏览器窗口看看效果!",VBSystemModal
WScript.sleep 6000
MsgBox "现在已经正常关闭了"
Sub event_onquit()
MsgBox "您确定要关闭浏览器吗?",VBSystemModal
End Sub
这段脚本打开了一个IE窗口,然后要求你关闭IE窗口,当你关闭窗口的时候,自动调用事件响应程序。[/code]

HAT 发表于 2009-10-4 19:40

[code]◎VBS脚本编程简明教程之十七——访问ADO数据库之一

ADO是Microsoft提供和建议使用的新型数据访问接口,它是建立OLEDB之上的一个抽象层。微软公司在操作系统中默认提供了 Access 的 ODBC 驱动程序以及 JET 引擎,

一、对ADO对象的主要操作,一般包括6个方面:

1.连接到数据源。通常使用ADO的Connection对象。一般使用相应的属性打开到数据源的连接,设置游标的位置,设置默认的当前数据库,设置将使用的OLEDBProvider,直接提交SQL脚本等。

2.向数据源提交命令。通常涉及ADO的Command对象。可查询数据库并返回结果在Recordset对象中。

3.执行SELECT查询命令。在提交SQL脚本的任务时,不用创建一个Command对象,就可完成查询。

4.可以通过ADO的Recordset对象对结果进行操作。

5.更新数据到物理存储。

6.提供错误检测。通常涉及ADO的Error对象。

二、ADO中主要对象的功能

Recordset对象,用来封装查询的结果。

Field对象,用来表达一行结果中各子段的类型和值。

Error对象,用来检测和判断在数据库操作中出现的错误,比如连接失败。 在ADO中,许多对象名后多了一个"s",比如Error->Errors,Field->Fields等等。添加"s"意味着是相应对象的Collection(集合)对象,比如Errors是Error对象的Collection对象。Collection有点像数组(Array),但不同的是,Collection可以以不同类型的数据或对象作为自己的元素,而数组中的各元素通常都是相同类型的。所以,在看到一个对象名最后是"s",通常表明这是一个Collection对象,比如Errors中的各元素是由Error对象的实例组成的。

三、具体应用

1、创建mdb数据库

ADOX 是ADO 对象的扩展库。它可用于创建、修改和删除模式对象,如数据库和表格等。

其常用的对象有:Catalog—>创建数据库。Column—>表示表、索引或关键字的列。

Key—>表示数据库表中的关键字。

常用的方法有: Append 将对象添加到 其集合。Delete 删除集合中的对象。

set cat= createobject("ADOX.Catalog")
cat.Create "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=d:\shujuku.mdb"
Set  tbl=createobject("ADOX.Table")
tbl.Name ="MyTable"
tbl.Columns.Append  "姓名",  202  'adInteger
tbl.Columns.Append  "性别",  3  'adInteger
tbl.Columns.Append  "工作单位",  202  ,50  'adVarWChar
cat.Tables.Append  tbl

不过你要操纵数据库就连一个数据库也不建,未免懒惰了点,用代码虽然可以完成,但是我觉得对数据约束完成的比较困难,本代码也就是示范个例子,并不推荐使用此类方法。

2、打开数据库

Provider=″Provider=Microsoft.Jet.OLEDB.4.0 ; Data Source="
Set Objconn = createobject("ADODB.Connection")
Objconn.Open Provider & "数据库名称"

3、创建记录集

Set Objrs = CreateObject("ADODB.Recordset")

4、执行SQL查询语句

Sql="SQL查询语句"  '例如:Select count(*) from table1
Set objrs = objconn.execute(sql)

一般情况下,我们将绝大多数的操作转化为SQL语句完成。[/code]

HAT 发表于 2009-10-4 19:41

[code]◎VBS脚本编程简明教程之十七——访问ADO数据库之二

在学习SQL语句之前,让我们先来对数据库做一个基本的了解。一个数据库中可能包含了很多个基本单位叫做表。表格被分为“行”和“列”。每一行代表表的一个单独组成部分,每一列代表相同性质的一组数据。举例来说,如果我们有一个记载顾客资料的表格,行包括姓、名、地址、城市、国家、生日等。而一列则代表了所有的地址或者国家等。

一、建立数据表,我们前边说过利用ADOX.Catalog建立数据库和数据表的方法,但是用的似乎不是很多,一般情况下,如果我们需要在数据库中动态建立一个表,我们将工作交给SQL语句来做,其基本语法是:

CREATE TABLE [表格名]([列名1] 数据类型 , [列名2]  数据类型,... )

例如我们要建立一个基本顾客表:

Create table [顾客表]([姓名] text(8), [性别] text(2),[住址] text(30))

二、插入数据项

insert into [数据表名称] (数据项1,数据项2,...) values (值1,值2,...)

insert into语句用来添加新的数据到数据库中的指定表。通过(数据项1,数据项2,...) values (值1,值2,...)来为新添加的数据赋初值。

三、删除数据项

delete from [数据表名称] where [数据项1] like [值1] and/or [数据项2] like [值2] ...作者:临汾市外事旅游局薛靖澜,转载请注明出处]

四、更新数据项

update [数据表名称] set 数据项1=值1,数据项2=值2,... where [数据项1] like [值1] and/or [数据项2] like [值2] ...
该语句可以修改数据库中指定数据表内的指定数据,如果不是用where限定条件就表示修改该表内所有的数据条目。

五、查询数据项

select [数据内容] from [数据表名称] where [数据项1] like [值1] and/or [数据项2] like [值2] ... order by [数据项] asc/desc

[数据内容]部分表示所要选取的表格中的数据项,使用*表示选取全部。[数据表名称]表示要从哪一个表格中选取,如果你没有接触过数据库可能很难了解什么是数据表格,没关系,我将在后面用到它的时候再说明。where表示选取的条件,使用like表示相等,也支持>=这样的判断符号,同时使用多个条件进行选取时中间要使用and进行连接。order by决定数据的排列顺序,asc表示按照[数据项]中的数据顺序排列,desc表示倒序,默认情况为顺序。select语句中除select和from之外其它均为可选项,如果都不填写表示选取该数据表中的全部数据。例如:下面的语句查询某数据库中表名称为:testtable中姓名为“张三”的nickname字段和email字段。

SELECT nickname,email FROM testtable WHERE name='张三'

(一) 选择列表

选择列表(select_list)指出所查询列,它可以是一组列名列表、星号、表达式、变量(包括局部变量和全局变量)等构成。

1、选择所有列

例如,下面语句显示testtable表中所有列的数据:

SELECT * FROM testtable

2、选择部分列并指定它们的显示次序查询结果集合中数据的排列顺序与选择列表中所指定的列名排列顺序相同。

例如:SELECT nickname,email FROM testtable

3、更改列标题

在选择列表中,可重新指定列标题。定义格式为:列标题=列名

列名 列标题如果指定的列标题不是标准的标识符格式时,应使用引号定界符,例如,下列语句使用汉字显示列标题:

SELECT 昵称=nickname,电子邮件=email FROM testtable

(二) FROM子句指定SELECT语句查询的表。

最多可指定256个表,它们之间用逗号分隔。如果选择列表中存在同名列,这时应使用对象名限定这些列所属的表或视图。例如在usertable和citytable表中同时存在cityid列,在查询两个表中的cityid时应加以限定。

◎VBS脚本编程简明教程之十七——访问ADO数据库之三

(三) WHERE子句设置查询条件

WHERE子句设置查询条件,过滤掉不需要的数据行。例如下面语句查询年龄大于20的数据:

SELECT * FROM usertable WHERE age>20

WHERE子句可包括各种条件运算符:

比较运算符(大小比较):>、>=、=、<、<=、<>、!>、!<

范围运算符(表达式值是否在指定的范围):BETWEEN…AND…

NOT BETWEEN…AND…

列表运算符(判断表达式是否为列表中的指定项):IN (项1,项2……)

NOT IN (项1,项2……)

模式匹配符(判断值是否与指定的字符通配格式相符):LIKE、NOT LIKE

空值判断符(判断表达式是否为空):IS NULL、NOT IS NULL

逻辑运算符(用于多条件的逻辑连接):NOT、AND、OR

1、范围运算符例:age BETWEEN 10 AND 30相当于age>=10 AND age<=30

2、列表运算符例:country IN ('Germany','China')

3、模式匹配符例:常用于模糊查找,它判断列值是否与指定的字符串格式相匹配。可用于char、 varchar、text、ntext、datetime和smalldatetime等类型查询。

可使用以下通配字符:

百分号%:可匹配任意类型和长度的字符,如果是中文,请使用两个百分号即%%。

下划线_:匹配单个任意字符,它常用来限制表达式的字符长度。

方括号[]:指定一个字符、字符串或范围,要求所匹配对象为它们中的任一个。

[^]:其取值也[] 相同,但它要求所匹配对象为指定字符以外的任一个字符。

例如:作者:临汾市外事旅游局薛靖澜,转载请注明出处]

限制以Publishing结尾,使用LIKE '%Publishing'

限制以A开头:LIKE '[A]%'

限制以A开头外:LIKE '[^A]%'

4、空值判断符例WHERE age IS NULL

5、逻辑运算符:优先级为NOT、AND、OR

最后,让我们用一个简单的例子结束这篇教程:

Objku = InputBox("请输入单位数据库的路径","默认位置","d:\jbqk.mdb")
Set Objconn = createobject("adodb.connection")
Objconn.open ="provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Objku
作者:临汾市外事旅游局薛靖澜,转载请注明出处]
sql = "CREATE TABLE [单位资料](ID Autoincrement PRIMARY KEY,[姓名] text(8),[性别] text(2),[科室] text(6),[住址] text(30))"
Objconn.execute(sql)
sql = "INSERT INTO [单位资料]([姓名],[性别],[科室],[住址]) VALUES('张三','男','行管科','解放路12号')"
Objconn.execute(sql)
sql = "INSERT INTO [单位资料]([姓名],[性别],[科室],[住址]) VALUES('李斯','女','市场科','五一路12号')"
Objconn.execute(sql)
sql = "DELETE FROM [单位资料] WHERE [姓名] = '张三' "
Objconn.execute(sql)
sql = "UPDATE [单位资料]"
sql = "SELECT COUNT(ID) FROM [单位资料]"[/code]

HAT 发表于 2009-10-4 19:42

[code]◎WMI轻松入门之一——基本概念

其实我给文章起这样的名字,绝对没有轻视WMI的意思,事实上就连微软也有“WMI非常难于学习而且更难于使用”的说法,在近日的学习过程中更感觉到了WMI检索功能的强大,之所以起个“轻松入门”的名字,我只是有感于外国人写教程在思路上和国人不太一致,西方式的幽默看起来困难无比,再加上一上手就在类的基本结构上展开讨论,吓跑了无数Vbs的爱好者,想从国人常见的角度出发来说说怎么学习WMI而已。百度空间的长度限制太讨厌了,一次发不完,只好分割成三部分,题目只能大致起了,见谅。

一、什么是WMI?微软有很多说法,大家可以到脚本中心查阅,我这样理解,WMI是一个用于管理Windows系统资源的对象,其内部应是一个树状的数据库,数据库中包含了很多个分支,每个分支被称作命名空间,每个命名空间包含了很多个对托管资源的抽象定义,这种定义叫做类。在很多计算机教材中喜欢把类比作建筑蓝图,依据蓝图建造的楼宇叫做类的实例,我更喜欢将类和其实例的关系比作表格,类就是表格的字段定义,而表中的数据就是一个个的类的实例,也许我这样说会让很多朋友更加糊涂,但是依此类推,WMI中最终存在的是各种软硬件资源的抽象定义,我们利用WMI,就是要按图索骥,通过类定义,获得类实例,检索出符合要求的属性,调用其内置的方法,实现我们的目标。相信很多朋友已经发现,我将WMI等同于CIM库了,我清楚他们不是一回事,但我相信这样更容易理解。如图:

二、WMI的基本结构

严格说来,WMI由四部分组成:

1、         公共信息模型对象管理器——CIMOM
2、         公共信息模型——CIM
3、         WMI提供程序
4、         WMI脚本对象库

其中其第1、2、3三个部分,在使用中很少加以区别,我们一般统称为CIM库。

所以我们可以认为WMI实际是由两部分组成:CIM库和WMI脚本对象库。在具体使用过程中,我们是通过WMI脚本对象库去访问CIM库,管理托管的资源。也就是说,在我们编写脚本的过程大致可以分为这么几步:

1、         创建WMI对象脚本库的指针实例;
2、         调用其实例的方法,连接到CIM库,并指明需要访问的资源的逻辑位置;
3、         获得托管资源也就是类的实例的集合;
4、         枚举实例,完成工作。

这几个步骤在我们将来编写的代码中可以明确的反映出来。

三、常用的命名空间

命名空间是个很复杂的概念,相信在微软的网站上一定有很多的篇幅介绍这个概念,据我个人理解,命名空间是对类所处逻辑位置的一个约定。打个比方说:张家也有个孩子叫小强,李家也有个孩子小强。大家站在一起,你大声叫"小强",你说这到底是叫哪一个小强呢?张家,李家都是一个姓,一个人的姓实际上就是现实中的一种名字空间。好了,现在你大声叫“张小强”,我们就明确的知道你到底是叫哪一个小强了。这就好比在变量名前加上名字空间前缀。所以可以通俗的说,名字空间就是一个变量的姓氏。问题是这样我们还会碰到一个问题,世界上有很多姓张的,也有可能有很多的张小强,这怎么办呢?这时候我们可以这样说"张老三家的小强",张是一个名字空间,张老三又是张下面的二级名字空间.

张.老三的家.小强 = 110
张.三丰的家.小强= 119

也许说的更糊涂,但大致就这样吧,我本来也就不是说明这个的。

据微软称,WMI的命名空间共有16个,不过不用担心,我们常用的只有两个:

1、         root\cimv2  在这个命名空间里包括了绝大多数与计算机、操作系统相关联的类。
2、         root\default  管理注册表的类

在使用中,我们用一个字符串表示命名空间,就像文件路径一样。[/code]

HAT 发表于 2009-10-4 19:42

[code]◎WMI轻松入门之二——连接到指定的CIM命名空间

四、常用的脚本对象库

WMI脚本对象库由24个对象组成,在脚本中心有一副脚本库对象模型的图,有兴趣的朋友可以参考一下,作为入门,我们一般只用到其中的四个对象,其继承和层级关系如下:

SwbemLocator教本库对象→SwbemServicesWMI服务对象→SwbemObjectSet类实例集合对象→SwbemObject类的实例

好了,现在让我们来举个例子,详细说明一下这四个对象在脚本中的应用方法:

例一:用来检索计算机上安装的光驱:

strComputer = "."
Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator")
Set objSWbemServices = objSWbemLocator.ConnectServer
Set colItems = objSWbemServices.ExecQuery("Select * from Win32_CDROMDrive")
For Each objItem in colItems
   WScript.Echo "光盘驱动器的类型: " & objItem.Caption
   WScript.Echo "盘符是: " & objItem.Id
Next

例二:用来检索CPU型号

strComputer = "."
Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator")
Set objSWbemServices = objSWbemLocator.ConnectServer
Set objSWbemObjectSet = objSWbemServices.InstancesOf("Win32_Processor")
For Each objSWbemObject In objSWbemObjectSet
   Wscript.echo  "CPU的型号为:" & objSWbemObject.name
Next

请注意,这两个脚本虽然简单,却代表了WMI脚本设计中最普遍的东西,可以说是很典型的脚本。让我们来仔细观察一下这两个脚本,讨论讨论一下脚本访问WMI的基本方法:我们可以看到整个脚本的执行过程基本相同:

①定义了SwbemLocator的实例;SwbemServices、SwbemObjectSet、SwbemObject对象;创建了SwbemLocator的实例;②通过SwbemLocator的ConnectServer方法连接到WMI,获得SwbemServices的实例集合;③枚举集合中的每个实例;④显示各实例的一些属性。

让我们来详细说明一下各行代码的详细含义,并请仔细回想我们第二部分WMI基本结构中谈到的编写WMI脚本的基本步骤:(注意:考虑到脚本的简易,我们编写的脚本一般只在本地计算机进行检索,我们只介绍涉及本地的这一部分,涉及到访问远程计算机的部分我们就省略了,其实随着计算机安全技术的发展,仅凭WMI访问远程计算机的可行性是越来越小了)

1、连接到指定的CIM命名空间

要用WMI对象编程,必须首先创建WMI对象脚本库的实例,连接到目标计算机的CIM命名空间。

方法一:

步骤一、建立SwbemLocator对象的实例。代码为:

Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator")

然后用SwbemLocator对象的ConnectServer方法(SwbemLocator对象只有1个只读属性Security_和1个方法ConnectServer)建立WMI服务的连接,返回一个命名空间的连接(SwbemServices对象),代码为:

Set objSWbemServices = objSWbemLocator.ConnectServer()

ConnectServer方法共有8个参数,所有参数都是可选的,其参数格式如下:

ConnectServer([strComputName],[strNamespace],[strUser],[strPassword],[strLocale],[strAuthority],[iSecurityFlags],[objwbemNamedValueSet])

考虑到WMI的复杂性,在使用中我们如果只是在本地计算机上进行检索和查询,那么我们只需要设置第1、2个参数,其它参数都可以省略;如果想连接到远程计算机,一般需要对前4个参数进行设置,我们也只对此做个简单的介绍。

strServer——计算机名,缺省为本机,本机也可以用”.”

strNamespace——需要登录的CIM命名空间,例如:"root\CIMV2",缺省为"root\CIMV2"。

方法二:用moniker名字法建立WMI服务的连接,这也是微软推荐的连接方法

moniker名字法是利用GetObject函数直接建立WMI服务的连接,它的要点就是通过编写一个moniker字符串作为GetObject函数的参数,然后返回一个SwbemServices对象。

关于moniker字符串的完整格式如下:

"winmgmts:[{SecuritySettings}!][\\ComputerName][\Namespace][:ClassName][.KeyProperty='Value']"

"winmgmts:"是前缀, 表示为WMI服务,必须使用;第二部分用来验证权限和假冒级别的,省略。第三部分为计算机名字:"\\.\"是计算机名字,默认可省略,其余同上;第四部分CIM命名空间:缺省的命名空间为"root\CIMV2",默认可省略。

第五部分为类名。第六部分为属性值。注意:当该moniker字符串不包括最后2项时(即为:"winmgmts:[\\ComputerName][\Namespace]"),则GetObject(moniker字符串)返回的是一个命名空间的已验证的连接(SwbemServices对象);当不包括最后1项时,返回的是一个CIM类(SWbemObject对象);当包括最后2项时,返回的是一个类的单独实例(SWbemObject对象)。[/code]

HAT 发表于 2009-10-4 19:42

[code]◎WMI轻松入门之三——获得类的实例

2.获得类的实例

我们有4种方法获得类的实例,其中方法1和方法2是通过SwbemServices对象的InstancesOf方法和ExecQuery方法来获得某个类的多个实例组成的集合对象。方法3和方法4则是返回单独的类的实例,即返回的是一个SWbemObject对象。

1)InstancesOf方法获得类的实例集合

InstancesOf方法的语法参数格式如下:

SwbemServices.InstancesOf(strClass)

strClass为类名,例如"Win32_Service"

回顾例二,就是用语句:Set objSWbemObjectSet = objSWbemServices.InstancesOf("Win32_Processor ") 来获得"Win32 Processor "类的所有实例集合,然后我们可以用

For Each objSWbemObject In objSWbemObjectSet

……

Next

语句获得每一个类的实例SWbemObject对象,然后就可以根据我们的需要,进行相应的操作。

2)ExecQuery方法获得类的实例集合

与InstancesOf方法不一样的是,ExecQuery方法可以通过查询语句,只返回匹配部分实例和属性。ExecQuery方法的语法参数格式如下:

SwbemServices.ExecQuery(strQuery)

strQuery为WMI查询语言(WQL)构造的一个查询语句字符串。

例如:

Set objSWbemObjectSet = objSWbemServices.ExecQuery("select ProcessorId from Win32_Processor where DeviceID='cpu0'")

3)Get方法获得一个类的实例(SWbemObject对象)

此方法也就不必再用 For Each objSWbemObject In objSWbemObjectSet :……:Next 语句从SWbemObjectSet对象中获得每一个类的实例SWbemObject对象,Get方法的语法参数格式如下:

SwbemServices.Get([strObjectPath][.KeyProperty='Value'])

strObjectPath是类的名字

KeyProperty是主键属性名

Value是指定的主键属性值

这里要注意的是如果要获得一个类的实例,则strObjectPath.KeyProperty='Value'中的任何一项都不能省略,例如:

Set objSWbemServices = GetObject("winmgmts:")
Set objSWbemObject = objSWbemServices.Get("Win32_Processor.DeviceID='cpu0'")
Wscript.echo “CPU的型号为”:" & objSWbemObject.ProcessorId

看,结果一样,脚本却简化了不少。

4)直接用moniker名字法获得一个类的实例

在说明Moniker名字法的时候我们说过,当包括最后2项时,返回的是一个类的单独实例,如:
Set objSWbemObject = GetObject("winmgmts:Win32_Processor.DeviceID='cpu0'")
Wscript.echo "首枚CPU序列号:" & objSWbemObject.ProcessorId

是不是更加简单?仅仅2条语句就获得了CPU的序列号。

3.读取类的实例属性,调用类的方法

实在是太多了,你可以参照C:/WINDOWS/system32/wbem/cimwin32.mfl文件中,对所有类的属性和方法的描述。也可以用下列代码查询,虽然看起来有点困难,不过看的多了也就明白了。

strClass=inputbox("请输入你要查询的类")
strComputer = "."
strNameSpace = "root\cimv2"
Const wbemFlagUseAmendedQualifiers = &h20000
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\" & strNameSpace)
Set objClass = objWMIService.Get(strClass, wbemFlagUseAmendedQualifiers)
strMOF = objClass.GetObjectText_
WScript.Echo strMOF[/code]

HAT 发表于 2009-10-4 19:43

[code]◎WMI轻松入门之四——解析类定义

  在上一篇文章中我们说过,WMI中用类对托管资源进行抽象定义和和管理,那么,什么是类?
  类的定义相信在很多面向对象的计算机教材中都能找到,我的理解是:类,是包含了一组独立功能的模块,这个模块由数据和功能组成,其中数据叫做类的属性,完成功能的部分叫做类的方法。我认为类的优点是:类完全可以由张三进行设计,李四可以拿来直接使用,在使用的时候,李四不需要知道类是如何设计、如何实现的,只要知道:这个类可以实现什么样的功能,这个类包含有什么样的方法和属性就可以了。更加重要的是,类还可以进行继承,就像父亲亡故,儿子继承了父亲所有的财产一样,如果我们发现某个类A已经完成了我们需要的大部分功能,我们再去重新设计一个新类来完成我们所有的功能,未免费时费力,根据类可以继承的特性,我们只要声明一个类继承了类A,然后按照需要添加需要的新的数据元素、扩展现有的功能模块,相信工作会简单很多。我看到很多书里都在说代码重用,我不是程序员,不知道所谓的代码重用具体是如何实现的,但是相信类应该在其中起了很重要的作用。
  在微软的教程中,对类从功能和继承关系上进行了详细的说明,我不再赘述,仅仅做一个摘要:

  任何资源如果要求WMI进行托管,至少需要两个文件:提供程序和托管对象格式 (MOF) 文件。提供程序是一个中间件,通过调用托管资源的本地 API 来响应 WMI 请求。
  每一个WMI托管的硬件和软件资源均有一个类来定义,反过来说,一个CIM类就是一个WMI托管资源的模板,而且资源的所有实例都使用这个模板。这些模板是由属性、方法和限定符组成的。这些属性、方法和限定符都定义在MOF文件中。方法和属性是我们经常遇到的,那么什么是限定符呢?限定符是关于类、属性或方法类型的附加修饰符,类是静态的、抽象的、还是关联的,属性是只读的还是可写的,方法的返回参数等,都定义在其中,那么我们如何知道某个类有那些限定符呢?如下代码可以帮助我们方便的获得类的属性、方法和限定符的信息。

Code:
strComputer = "."
strNameSpace = "root\cimv2"
strClass=inputbox("请输入你要查询的类")

Set objClass = GetObject("winmgmts:\\" & strComputer & _
                           "\" & strNameSpace & ":" & strClass)

WScript.Echo strClass & " 的类限定信息如下:"
WScript.Echo "------------------------------"
i = 1
For Each objClassQualifier In objClass.Qualifiers_
      If VarType(objClassQualifier.Value) = (vbVariant + vbArray) Then    '常数 VBVariant 只与 VBArray 一起返回,以表明 VarType 函数的参数是一个 Variant 类型的数组。
          strQualifier = i & ". " & objClassQualifier.Name & " = " & _
                                    Join(objClassQualifier.Value, ",")
      Else
          strQualifier = i & ". " & objClassQualifier.Name & " = " & _
                                    objClassQualifier.Value
      End If
      WScript.Echo strQualifier
      strQualifier = ""
      i = i + 1
Next

WScript.Echo
WScript.Echo strClass & " 类的属性和属性限定信息"
WScript.Echo "-------------------------------------------------"
i = 1 : j = 1
For Each objClassProperty In objClass.Properties_
      WScript.Echo i & ". " & objClassProperty.Name
      For Each objPropertyQualifier In objClassProperty.Qualifiers_
          If VarType(objPropertyQualifier.Value) = (vbVariant + vbArray) Then
              strQualifier = i & "." & j & ". " & _
                             objPropertyQualifier.Name & " = " & _
                             Join(objPropertyQualifier.Value, ",")
          Else
              strQualifier = i & "." & j & ". " & _
                             objPropertyQualifier.Name & " = " & _
                             objPropertyQualifier.Value
          End If
          WScript.Echo strQualifier
          strQualifier = ""
          j = j + 1
      Next
      WScript.Echo
      i = i + 1 : j = 1
Next

WScript.Echo
WScript.Echo strClass & " 类的方法和方法限定信息"
WScript.Echo "-------------------------------------------------"
i = 1 : j = 1
For Each objClassMethod In objClass.Methods_
      WScript.Echo i & ". " & objClassMethod.Name
      For Each objMethodQualifier In objClassMethod.Qualifiers_
          If VarType(objMethodQualifier.Value) = (vbVariant + vbArray) Then
              strQualifier = i & "." & j & ". " & _
                             objMethodQualifier.Name & " = " & _
                             Join(objMethodQualifier.Value, ",")
          Else
              strQualifier = i & "." & j & ". " & _
                             objMethodQualifier.Name & " = " & _
                             objMethodQualifier.Value
          End If
          WScript.Echo strQualifier
          strQualifier = ""
          j = j + 1
      Next
      WScript.Echo
      i = i + 1 : j = 1
Next
如果我们执行上述代码来查找win32_service类的限定符,一般情况下可以得到如下信息:
win32_service 的类限定信息如下:
------------------------------
1. dynamic = True
2. Locale = 1033
3. provider = CIMWin32
4. SupportsUpdate = True
5. UUID = {8502C4D9-5FBB-11D2-AAC1-006008C78BC7}

win32_service 类的属性和属性限定信息
------------------------------------------------------
1. AcceptPause
1.1. CIMTYPE = boolean
1.3. read = True
……
win32_service 类的方法和方法限定信息
-------------------------------------------------
1. StartService
1.1. MappingStrings = Win32API|Service Functions|StartService
1.2. Override = StartService
1.3. ValueMap = 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,..
……
  返回的信息很多,我省略了其中的绝大部分,只保留了一部分典型的来说明我们应该如何读懂类的限定信息。
  返回信息的第一部分表明了对于此类的限定信息:
  1. dynamic = True    Abstract——抽象类,Dynamic——动态类,Association——关联类,表明win32_service类是动态类。
  2. Locale = 1033      代表着区域设置或者叫本地化编码,是一组与用户的语言、国家/地区以及文化传统有关的用户首选信息,确定诸如:键盘布局、字母的排序顺序,以及日期、时间、数字、货币等的格式,一般不用管它。
  3. provider = CIMWin32    Provider代表的是类的提供程序,说明win32_service类是由CimWin32.dll提供的。
  4. SupportsUpdate = True    指出类是否支持实例的修改。
  5. UUID = {8502C4D9-5FBB-11D2-AAC1-006008C78BC7}    代表本地计算机上的全球通用唯一的标识符,我不知道有什么用处。
  
  返回信息的第二部分代表了类的属性限定符
  1. AcceptPause
  这第一行表明检索到的类的属性名是:AcceptPause
  1.1. CIMTYPE = boolean    CIMType代表属性的数据类型,说明这个属性是布尔型。
  1.3. read = True     read代表属性可读,而Write则代表属性的值是否可以修改,如果属性没有定义Write限定符,代表什么意思呢?它代表从该类获得的实例的那个属性是不可以改写的,也就是说不能给这个属性赋值。这其实解决了一个困惑我很久的一个问题,为什么我在对很多类的属性进行了赋值后,用Put_方法对修改进行了提交,可是事实上却什么也没有改变。此外还有Key限定符指出该属性是类的键,用于识别在相同资源集合中的托管资源的唯一实例。
  
  返回信息的第三部分代表了类的方法及方法的限定符。现在我们能用到的还不多,就不介绍了,有兴趣的朋友可以参照:http://msdn2.microsoft.com/en-us/library/aa393650.aspx
  需要说明的是,不是在每一个类定义或者属性、方法定义中,这所有的限定符都要出现的,可能只出现了其中的一部分。
  当然,我们也可以从system32\wbem\cimwin32.mof以及system32/wbem/cimwin32.mfl两个文件中读取整个托管资源的类定义和类描述,以及对每个类的属性、方法和限定符的描述,其中包含的信息很多,也包含了更多的类限定符,阅读起来有一定的难度。将上面的例子的代码和vbsedit中包含的Object Browser联合起来,可以得到我们需要的绝大部分的信息。[/code]

HAT 发表于 2009-10-4 19:43

[code]◎简单WSC组件的基本结构

WSC是微软公司提供的使用脚本语言来创建 COM 部件的便利途径,它可以应用于支持 COM 部件的应用程序。WSC采用XML语言编写。一个标准的WSC组件本身涉及到XML标记相当复杂,但幸好它的结构非常规范,了解结构,填入代码,一个WSC脚本部件就可以工作了。
就我个人而言,把WSC部件分成三个部分:注册部分,定义属性、方法、事件部分和实现部分。

1、注册部分:
主要包含了向注册表注册部件时需要填写的信息。一般包含了部件描述、版本信息、progid、clsid等四个内容。基本格式如下:
<registration
description="部件描述的信息"
version="部件的版本号"
progid="XXXX.XXX"        /程序ID
clsid="xxxxxxxx-xxxx-xxxx-xxxxxxxxxxxx"/>
需要说明的是:
①registration是XML标记。
②progid是VBS通过CreateObject函数通过绑定组件创建实例时的标志,一个组件如果没有ProgId,几乎是无法使用的。例如:
Set obj=CreateObject("scripting.filesystemobject")
代码中的scripting.filesystemobjec就是ProgId。
③Clsid是部件在注册表项中的唯一标志,系统注册时把有关部件的信息放在注册表中,应用时通过读取注册信息,应用程序可以找到并载入该部件。可以使用Uuidgen.exe 的程序随机生成。当然如果你不指定Clsid,系统注册时regsvr32会为它自动创建一个,但正常情况下应该指定一个。由于我的计算机上没有安装VC,所以Uuidgen.exe和GUIDGen.exe文件,Clsid从一直是我极为头疼的问题,幸好UMU给出了一个脚本产生,现把代码抄录如下:
Dim objSLTL
Set objSLTL = CreateObject( "Scriptlet.TypeLib" )
Wscript.echo objSLTL.GUID
Set objSLTL = Nothing

2、定义属性、方法、事件部分
在这个部分定义了用户在脚本中可以使用的属性、方法、事件,其基本结构如下:
<Public>
<property name="属性一" >
<get/>
       <Put/>
</property>

<method name="方法一">
       <parameter name="参数一"/>
</method>

<event name="事件一">
       <parameter name="参数一"/>
</event>
</Public>
其中Public是XML的标记,property、method、event标记分别定义了部件属性、方法、事件。Name标记定义了其名称,Parameter标记定义了其参数。作为property标记来说,本身带有两个子标记,它们分别是<get/><put/>,它们两个分别定义了读写属性的方式。当需要读写属性的时候,就会自动执行它们中的一个。在实现部分中,它们会以Put_属性名 或者 Get_属性名的形式出现。如果忽略了<get/>标记,则此属性是只可写的,忽略了<Put/>标记,说明此属性是只读的。作为vbs脚本,在脚本中响应事件的机会是比较少的,对此也就不再详细的说明。

3、实现部分
在上一部分定义的所有的属性、方法、事件的实现函数都必须包含在<Script>标记中。结构如下:
<script language="VBScript">
<![CDATA[
定义公用变量
进行初始化
Function 函数名称()
函数实现
End funciton
]]>
</script>
抛开XML的标记不管,我们只需要有关的部分进行修改就可以了。在Public部分定义的属性和方法,在本部分必须定义相应的变量和函数。
当然,WSC作为一个XML格式的文件,一些基本的标记还是需要知道的,下面有关标记说明摘自微软。
<component>和<package>元素:<component> 元素包含的是一个完整的脚本部件定义。在同一个 .wsc 文件中可以出现多个 <component> 元素,但这些元素应包含在一个 <package> 元素内。
<registration>元素:包括用来将脚本部件注册为 COM 部件的信息。
<public>元素:包含脚本部件所说明的属性、方法和事件的定义。这些定义指向定义在独立的 <script> 块中的变量或函数。
<implements>元素:给脚本部件指定COM接口处理程序,这将确定该脚本部件属于哪种COM部件类型。例如,通过指定 <implements type=ASP>,就可以实现 ASP 接口处理程序,并因此在脚本部件中可以访问ASP对象模型。
<public>元素:指定了脚本部件将实现 COM Automation 接口处理程序。因此,对 Automation 处理程序无需创建<implements>元素。
<script>元素:包含用来实现脚本部件逻辑的脚本,这取决于所创建的COM部件类型。例如,如果要创建的是 COM Automation 部件,则可以在

<public> 元素中声明属性、方法和事件,然后用一个或多个 <script> 元素编写脚本来定义这些内容。
<object>元素:包含脚本中所使用的某个对象的信息,如另一个 COM 部件的信息。
<resource>元素:包含不应被硬编码到脚本部件代码中的值。资源元素可能包括在各个版本间可能更改的信息,可能需要翻译的字符串以及其他值。
<reference>元素:引用在脚本中需要使用的类型库。
<comment>元素:包含在分析和执行该脚本部件时将被忽略的文字,说明或者注释。

了解了这些知识,让我们来看一个最最简单的例子:

<?XML version="1.0"?>
       <package>
         <component id="test">
           <registration
             progid="ID"
             description="description"
             version="1"
             clsid="{A66E243C-CF13-42AC-BE67-558F2FA82B39}"/>

           <public>
             <property name="du"/>
               <get/>
             <method name="xie"/>
           </public>

           <script language="VBScript">
             <![CDATA[
               dim du
               function get_du()
          du=get_du
               End function

               Function xie()
                 msgbox du
               End Function
             ]]>
           </script>
         </component>
       </package>

用代码调用
Set test=CreateObject("ID")
test.du=5
test.xie
显示正常[/code]

HAT 发表于 2009-10-4 19:44

[code]◎使用脚本部件向导简化WSC设计

尽管XML语言被设计成为一种相对精简的标记语言,符合XML格式的WSC部件也设计的极为规范,但就我而言,在具体的设计过程中,出错最多的仍然在XML的各种标记上,幸好,微软推出了专门生成WSC部件代码的工具Windows Script Component Wizard,这个工具可以迅速的为我们搭建好WSC部件的框架,极大的方便了我们对WSC部件的编写,此向导除了在微软的网站上下载外,在我的网盘上也有一份拷贝。

它的使用方法也极为简单,就连诸如我之流E文程度极差者也能使用。

如上例,生成如下代码:

<?xml version="1.0"?>
<component>
<?component error="true" debug="false"?>
<registration
       description="测试用的WSC部件"
       progid="test.WSC"
       version="1.00"
       classid="{155642f0-fbad-4f98-90cb-b38b7a3cf428}"
>
</registration>
<public>
       <property name="start">
              <get/>
       </property>
       <property name="end">
              <get/>
              <put/>
       </property>
       <method name="print">
              <PARAMETER name="para1"/>
              <PARAMETER name="para2"/>
       </method>
       <method name="list">
              <PARAMETER name="para3"/>
       </method>
</public>
<implements type="Behavior" id="Behavior"/>
<script language="VBScript">
<![CDATA[
dim start
dim end

function get_start()
       get_start = start
end function

function get_end()
       get_end = end
end function

function put_end(newValue)
       end = newValue
end function

function print(para1,para2)
       print = "Temporary Value"
end function

function list(para3)
       list = "Temporary Value"
end function
]]>
</script>
</component>

呵呵,该有的东西全有了,属性对应的变量也定以来,我们只要对其中实现部分稍加修改就可以注册应用了,需要注意的是,如果在WSC编码设计中出现汉字,则必须在第一行添加encoding="gb2312"标记,既第一行为:

<?xml version="1.0" encoding="gb2312" ?>

才能正常通过注册。[/code]

HAT 发表于 2009-10-4 19:45

[code]◎Adodb.Stream 的使用说明(转发)

  ADODB.Stream组件是很重要的组件,以前一直找不全,先转过来有时间好好看看。

  1、注册ADODB.Stream组件

  regsvr32 "C:\Program Files\Common Files\System\ado\msado15.dll"
  
  2、使用说明
  组件:"Adodb.Stream"
  有下列方法:
  Cancel 方法
  使用方法如下
  Object.Cancel
  说明:取消执行挂起的异步 Execute 或 Open 方法的调用。
  Close 方法
  使用方法如下
  Object.Close
  :关闭对像
  CopyTo 方法
  使用方法如下
  Object.CopyTo(destStream,[CharNumber])
  说明:将对像的数据复制,destStream指向要复制的对像,CharNumber为可选参数,指要复制的字节数,不选为全部复制。
  Flush 方法
  使用方法如下
  Object.Flush
  说明:
  LoadFromFile 方法
  使用方法如下
  Object.LoadFromFile(FileName)
  说明:将FileName指定的文件装入对像中,参数FileName为指定的用户名。
  Open 方法
  使用方法如下
  Object.Open(Source,[Mode],[Options],[UserName],[Password])
  说明:打开对像,
  参数说明:Sourece 对像源,可不指定
  Mode 指定打开模式,可不指定,可选参数如下:
  adModeRead =1
  adModeReadWrite =3
  adModeRecursive =4194304
  adModeShareDenyNone =16
  adModeShareDenyRead =4
  adModeShareDenyWrite =8
  adModeShareExclusive =12
  adModeUnknown =0
  adModeWrite =2
  Options 指定打开的选项,可不指定,可选参数如下:
  adOpenStreamAsync =1
  adOpenStreamFromRecord =4
  adOpenStreamUnspecified=-1
  UserName 指定用户名,可不指定。
  Password 指定用户名的密码
  Read 方法
  使用方法如下:
  Object.Read(Numbytes)
  说明:读取指定长度的二进制内容。
  参数说明:Numbytes指定的要读取的找度,不指定则读取全部。
  ReadText 方法
  使用方法如下:
  Object.ReadText(NumChars)
  说明:读取指定长度的文本
  参数说明:NumChars指定的要读取的找度,不指定则读取全部。
  SaveToFile 方法
  使用方法如下:
  Object.SaveToFile(FileName,[Options])
  说明:将对像的内容写到FileName指定的文件中
  参数说明:FileName指定的文件
  Options 存取的选项,可不指定,可选参数如下:
  adSaveCreateNotExist =1
  adSaveCreateOverWrite =2
  SetEOS 方法
  使用方法如下:
  Object.setEOS()
  说明:
  SkipLine 方法
  使用方法如下:
  Object.SkipLine()
  说明:
  Write 方法
  使用方法如下:
  Object.Write(Buffer)
  说明:将指定的数据装入对像中。
  参数说明:Buffer 为指定的要写入的内容。
  WriteText 方法
  使用方法如下:
  Object.Write(Data,[Options])
  说明:将指定的文本数据装入对像中。
  参数说明:Data 为指定的要写入的内容。
  Options 写入的选项,可不指定,可选参数如下:
  adWriteChar =0
  adWriteLine =1
  有下列属性:
  Charset
  EOS 返回对像内数据是否为空。
  LineSeparator 指定换行格式,可选参数有
  adCR =13
  adCRLF =-1
  adLF =10
  Mode 指定或返加模式。
  Position 指定或返加对像内数据的当前指针。
  Size 返回对像内数据的大小。
  State 返加对像状态是否打开。
  Type 指定或返回的数据类型,可选参数为:
  adTypeBinary =1
  adTypeText =2

  用了6行代码实现了无组件上传:
  strFileName = Request.QueryString("file1")
  Set objStream = Server.CreateObject("ADODB.Stream")
  objStream.Type = 1 ' adTypeBinary
  objStream.Open
  objStream.LoadFromFile strFileName
  objStream.SaveToFile Server."123_onweb.gif",2

  使用方法:
  把上面的代码写成upload.asp
  在浏览器里面输入:
  http://XXX/upload.asp?file1=c:\上传文件\123.gif
  XXX为你的主机地址
  执行完后你会看到你的目录下面多了一个123_onweb.gif
  他就是你要文件拉!!!!

  根据原理我们可以扩展以下代码:
  upload.asp文件
  <%
  Function GetFileName(ByVal strFile)
  If strFile <> "" Then
  GetFileName = mid(strFile,InStrRev(strFile, "\")+1)
  Else
  GetFileName = ""
  End If
  End function
  strFileName = Request.Form("file1")
  Set objStream = Server.CreateObject("ADODB.Stream")
  objStream.Type = 1 ' adTypeBinary
  objStream.Open
  objStream.LoadFromFile strFileName
  objStream.SaveToFile Server.MapPath(GetFileName(strFileName)),2
  objStream.Close
  %>
  upload.htm文件
  <form name="FORM" action="upload.asp" method="post">
  <input type="submit" name="submit" value="OK">
  <input type="file" name="file1" style="width:400" value="">
  </form>
  读文件不想用FSO,有的空间不支持。
  有一个LoadFromFile的方法。可以读取文件。
  下面是我的代码。
  function readfile(URL,chartype)
  set srmObj = server.CreateObject("adodb.stream")
  srmObj.type=1
  srmObj.mode=3
  srmObj.open
  srmObj.Position=0
  srmObj.LoadFromFile URL
  srmObj.Position = 0
  srmObj.type=2
  srmObj.charset=chartype
  readfile=srmObj.readtext()
  end function
  两个参数。URL是文件的路径,好像只能绝对路径。chartype是文件以什么编码存放的。
  返回一个字符串,存放文件的内容。
  这个函数只能读文本文件。读二进制文件也差不多。要用的人可以自己改
  < = src="/article/js/c9.js"> 基于adodb.stream的文件操作类
  <%
  ’*************************************************************
  ’转发时请保留此声明信息,这段声明不并会影响你的速度!
  ’*************************************************************
  ’*************************************************************
  ’@author: 面条
  ’@realname: 徐仁禄
  ’@email: xurenlu@sohu.com
  ’@QQ: 55547082
  ’@Homepage: http://www.ksdn.net
  ’@版权申明:
  ’ 非盈利性质团体或者个人可以免费使用.
  ’*************************************************************
  ’*************************************************************
  ’ 类名称: files
  ’ 类功能: 实现文件读写功能,利用adodb.stream实现,在不支持fso的主机上也可以读写文件.
  ’*************************************************************
  class files
  private adSaveCreateOverWrite ’创建文件的时候可以覆盖已经存在的文件.
  private adSaveCreateNotExist ’保存文件的时候如果文件不存在,可以创建文件.
  ’*************************************************************
  ’ 事件名称: Class_Initialize()
  ’ 事件发生条件: 类创建时候产生该事件
  ’ 事件内容: 给私有变量赋值
  ’ 事件传入参数: 无
  ’*************************************************************
  sub Class_Initialize()
  adSaveCreateOverWrite =2
  adSaveCreateNotExist = 1
  end sub
  ’*************************************************************
  ’ 函数名称: function readfile(filepath)
  ’ 函数内容: 读出文件
  ’ 传入参数: filepath:要读的文件的绝对路径
  ’ 返回参数: 要读的文件的内容.
  ’*************************************************************
  function readfile(filepath)
  on error resume next
  dim stm2
  set stm2 =server.createobject("ADODB.Stream")
  stm2.Charset = "gb2312"
  stm2.Open
  stm2.LoadFromFile filepath
  readfile = stm2.ReadText
  end function
  ’*************************************************************
  ’ 函数名称: function writefile(filepath,str)
  ’ 函数内容: 写入文件
  ’ 传入参数: filepath:要读的文件的绝对路径
  ’ str: 要写入的内容
  ’ 返回参数: 无返回
  ’*************************************************************
  function writefile(filepath,str)
  on error resume next
  Set stm = server.createobject("ADODB.Stream")
  stm.Charset = "gb2312"
  stm.Open
  stm.WriteText str
  stm.SaveToFile filepath, adSaveCreateOverWrite
  end function
  ’*************************************************************
  ’ 函数名称: function copy(filepath_s,filepath_d)
  ’ 函数内容: 读出文件
  ’ 传入参数: filepath_d:目的文件的绝对路径
  ’ filepath_s:源文件路径
  ’*************************************************************
  function copy(filepath_s,filepath_d)
  on error resume next
  dim stm2
  set stm2 =server.createobject("ADODB.Stream")
  stm2.Charset = "gb2312"
  stm2.Open
  stm2.LoadFromFile filepath_s
  stm2.SaveToFile filepath_d, adSaveCreateOverWrite
  end function
  end class

  利用Adodb.Stream直接下载文件
  在浏览器的地址栏里直接输入一个doc或xls或jpg的文件的url路径,那么该文件会直接显示在浏览器里。而在很多时候我们希望能直接弹出下载提示框让用户下载,我们该怎么办呢?这里有两种方法:
  1、设置你的服务器的iis,给doc等后缀名做映射
  2、在向客户端发送时设置其contenttype
  下面详细说明方法2
  程序代码:
  _code style="DISPLAY: none" name="html_code"><%
  Response.Buffer = true
  Response.Clear
  dim url
  Dim fso,fl,flsize
  dim Dname
  Dim objStream,ContentType,flName,isre,url1
  '*********************************************调用时传入的下载文件名
  Dname=trim(request("n"))
  '******************************************************************
  If Dname<>"" Then
  '******************************下载文件存放的服务端目录
  url=server.MapPath("/")&"\"&Dname
  '***************************************************
  End If
  Set fso=Server.CreateObject("Scripting.FileSystemObject")
  Set fl=fso.getfile(url)
  flsize=fl.size
  flName=fl.name
  Set fl=Nothing
  Set fso=Nothing
  %>
  <%
  Set objStream = Server.CreateObject("ADODB.Stream")
  objStream.Open
  objStream.Type = 1
  objStream.LoadFromFile url
  Select Case lcase(Right(flName, 4))
  Case ".asf"
  ContentType = "video/x-ms-asf"
  Case ".avi"
  ContentType = "video/avi"
  Case ".doc"
  ContentType = "application/msword"
  Case ".zip"
  ContentType = "application/zip"
  Case ".xls"
  ContentType = "application/vnd.ms-excel"
  Case ".gif"
  ContentType = "image/gif"
  Case ".jpg", "jpeg"
  ContentType = "image/jpeg"
  Case ".wav"
  ContentType = "audio/wav"
  Case ".mp3"
  ContentType = "audio/mpeg3"
  Case ".mpg", "mpeg"
  ContentType = "video/mpeg"
  Case ".rtf"
  ContentType = "application/rtf"
  Case ".htm", "html"
  ContentType = "text/html"
  Case ".txt"
  ContentType = "text/plain"
  Case Else
  ContentType = "application/octet-stream"
  End Select
  Response.AddHeader "Content-Disposition", "attachment; filename=" & flName
  Response.AddHeader "Content-Length", flsize
  Response.Charset = "UTF-8"
  Response.ContentType = ContentType
  Response.BinaryWrite objStream.Read
  Response.Flush
  response.Clear()
  objStream.Close
  Set objStream = Nothing
  %>
  _lightcode style="BORDER-RIGHT: #999999 1px dotted; PADDING-RIGHT: 5px; BORDER-TOP: #999999
  1px dotted; PADDING-LEFT: 5px; FONT-SIZE: 11px; PADDING-BOTTOM: 5px; BORDER-LEFT: #999999
  1px dotted; PADDING-TOP: 5px; BORDER-BOTTOM: #999999 1px dotted; FONT-FAMILY: sans-serif;
  HEIGHT: 40px; BACKGROUND-COLOR: #f9f9f9" name="html_lightcode"><%
  Response.Buffer = true
  Response.Clear
  dim url
  Dim fso,fl,flsize
  dim Dname
  Dim objStream,ContentType,flName,isre,url1
  '*********************************************调用时传入的下载文件名
  Dname=trim(request("n"))
  '******************************************************************
  If Dname<>"" Then
  '******************************下载文件存放的服务端目录
  url=server.MapPath("/")&"\"&Dname
  '***************************************************
  End If
  Set fso=Server.CreateObject("Scripting.FileSystemObject")
  Set fl=fso.getfile(url)
  flsize=fl.size
  flName=fl.name
  Set fl=Nothing
  Set fso=Nothing
  %>
  <%
  Set objStream = Server.CreateObject("ADODB.Stream")
  objStream.Open
  objStream.Type = 1
  objStream.LoadFromFile url
  Select Case lcase(Right(flName, 4))
  Case ".asf"
  ContentType = "video/x-ms-asf"
  Case ".avi"
  ContentType = "video/avi"
  Case ".doc"
  ContentType = "application/msword"
  Case ".zip"
  ContentType = "application/zip"
  Case ".xls"
  ContentType = "application/vnd.ms-excel"
  Case ".gif"
  ContentType = "image/gif"
  Case ".jpg", "jpeg"
  ContentType = "image/jpeg"
  Case ".wav"
  ContentType = "audio/wav"
  Case ".mp3"
  ContentType = "audio/mpeg3"
  Case ".mpg", "mpeg"
  ContentType = "video/mpeg"
  Case ".rtf"
  ContentType = "application/rtf"
  Case ".htm", "html"
  ContentType = "text/html"
  Case ".txt"
  ContentType = "text/plain"
  Case Else
  ContentType = "application/octet-stream"
  End Select
  Response.AddHeader "Content-Disposition", "attachment; filename=" & flName
  Response.AddHeader "Content-Length", flsize
  Response.Charset = "UTF-8"
  Response.ContentType = ContentType
  Response.BinaryWrite objStream.Read
  Response.Flush
  response.Clear()
  objStream.Close
  Set objStream = Nothing
  %>[/code]

HAT 发表于 2009-10-4 19:46

[code]◎VBS脚本编程简明教程(补充读物-初窥WMI)

    今天,我沼泽将给大家介绍个朋友,它就是Microsoft Windows Management Instrumentation (WMI)。中文名字叫Windows管理规范。从Windows 2000开始,WMI(Windows 管理规范)就内置于操作系统中,并且成为了Windows系统管理的重要组成部分。所以大家很容易就能见到它的,因为我们至少也应该是个Windows 2000的使用者了。下面我将详细介绍它的每个细节,让你从不认识它到喜欢上它。

WMI能做什么?
WMI不仅可以获取想要的计算机数据,而且还可以用于远程控制。远程控制计算机可是大家都喜欢的东西。很多远程监视控制类软件通常的做法是:在远程计算机上运行服务端后台程序,在本地计算机上运行一个客户端控制程序,通过这二个程序的勾结来实现对计算机的远程控制。这种作法的缺点是十分明显的,当服务端程序关了,这种远程监控就无法实现了,因为没有内线了。而WMI实现的远程监视和控制完全不需要另外装什么服务端的东西,系统默认就将WMI服务给开了。具体说来,WMI的本领如下:
1.获取本地和远程计算机的硬件软件信息。
2.监视本地和远程计算机的软件和服务等运行状况。
3.控制本地和远程计算机的软件和服务运行。
4.高级应用。

如何访问WMI?
当我们知道WMI的某些本领后,我们已经很想知道如何认识他并利用他了。利用WMI有许多途径,简单说来有三种了:
1.通过微软给我们提供的各种工具来实现普通查询和操作。主要包括命令提示符下面的WMIC,还有就是微软给我们提供的WMI TOOL,大家可以到微软的网站上免费下载,当然我也可以给大家免费提供。
2.通过自己编写脚本来实现更灵活操作。要想真正灵活实用,对WSH脚本的熟悉是必须的,当然如果你不熟悉也没有关系,稍后我会给大家详细解释的。
3. 通过编写我们自己的程序来访问并操作它。什么语言都行。如果用.NET类程序要简单些了,如果用VC等要复杂些了,起码我是这么认为的。
4.还有个访问它的方法,就是到它的一个巢穴。在C:\WINDOWS\system32\wbem目录中的东西都和它有密切联系,有日志和各种工具,在里面你可以找到很多答案的。不过这些东西一般都不适合我们新手玩了,感觉有点吓人。

我们今天的任务?
今天我们的任务有五个:
任务一:利用WMIC列出远程计算机上的所有进程。
任务二:利用WMIC关闭本地进程。
任务三:通过WMIC把远程主机的进程信息保存在一个网页中
任务四:利用脚本实时监视对方进程
任务五:利用脚本给对方开放共享
查看和监视进程,还要把进程给杀掉,最后还要给对方开个共享,我们这位朋友快把坏事做尽了。明白了我们的任务,我们就可以上路了。这次我们将主要借助WMIC和脚本来实现我们的任务,所以我们将主要分为两大部分来讲解。在五个任务的实战中我们将更加深入地理解它,没有基础没有关系,我将尽力去解释所有的所谓的基础,让大家能很轻松地和这位朋友交流。

第一部分:利用WMIC来认识WMI
WMIC是Windows Management Instrumentation Commandline的简称,WMIC扩展WMI,提供了从命令行接口和批命令脚本执行系统管理的支持。为WMI名称空间提供了一个强大的、友好的命令行接口。有了WMIC,WMI就显的平易近人了。
执行"WMIC"命令将启动WMIC命令行环境。第一次执行WMIC命令时,Windows首先要安装WMIC,然后显示出WMIC的命令行提示符。在WMIC命令行提示符上,命令将以交互的方式执行。如果你不知道该如何和它交互,请敲个"/?",细细看完全部的说明,你就知道了。WMIC也可以按照非交互的模式运行。如果要执行某个单步的任务,或者运行批命令中的一系列WMIC命令,非交互模式就很有用。要使用非交互模式,只要在同一个命令行上启动WMIC并输入要执行的命令就可以了。

1.任务一:利用WMIC列出远程计算机上的所有进程
这是一个实现起来很简单的任务,和你用一个DOS命令一样简单,因为我们要循序渐进嘛,所以安排了这么一个热身任务。在命令提示符下敲入下面的命令,我们将看到。
WMIC /node:192.168.1.2 /user:net process
解说:
1)上面命令中的NODE和USER是全局开关。如果你不愿意另外输一次密码,你也可以用PASSWORD开关,后面写上密码就可以了(WMIC /node:192.168.1.2 /user:net /password:password process)。千万要注意,这里的用户名和密码都必须是管理员级别的,其它的无效。WMIC提供了大量的全局开关、别名、动词、命令和丰富的命令行帮助增强用户接口。全局开关是用来配置整个WMIC会话的选项。
2)Process是个别名,执行了一个Win32_process类的WQL查询,至于说是WMI的类是什么东西,感兴趣的就自己找资料多多了解,如果你很懒的话,就等我有时间给你开课讲解。别名是用户和WMI名称空间一个简化语法的中间层。当你指定一个别名时,动词(Verb)表示要执行的动作。
3)如果你愿意,你可以在该后面加上个动词等,比如 LIST FULL等(如:WMIC /node:192.168.1.2 /user:net /password:password process),这样你就看得更清楚了。

小提示:安装了WMIC的机器可以连接到任何一台安装了WMI的机器,被连接的机器不需要安装WMIC。

2.任务二:利用WMIC关闭本地进程
执行下面的命令将关闭正在运行的QQ。我比较胆小,所以不敢关别人的QQ,只能拿我的QQ试验了,如果你的智商还够用的话,胆子比较大的话,你很快就会去关别人的了。
WMIC
process where name="qq.exe" call terminate
解说:
1)这次我们是用交互式的方法来执行任务,具体界面我就不多说了,图上画的比我说的好多了。
2)Call也是个动词,这个动词可是厉害了,控制类的没有不用它的,它就是可以调用各种类的各种方法的大将。这里我们调用了terminate方法。从字面上你就可以看出是恶狠狠的。
3)Where能够让你查询和筛选。在超级多的实例中找到你想要的。实例就是指每个类的具体实现了。前面的例子中看到的各个进程都分别算是WIN32_PROCESS中的一个实例。

3.任务三:通过WMIC把远程主机的进程信息保存在一个网页中
这个任务和任务一中的大致相同,是任务一的加强。在任务一中信息以文本的形式显示出来了。其实除了文本形式的输出之外,WMIC还能够以其他形式返回命令执行结果,例如XML、HTML或者CSV(逗号分隔的文本文件),如图3所示。我们可以敲入下面的命令:
wmic /output:C:\1.html /node:192.168.1.2 /user:net process list full /format:hform.xsl
输入密码 :******

解释:
1)全局开关OUTPUT指明将这些信息保存在什么地方。
2)全局开关FORMAT指明了用什么样的格式,至于说有那些格式可以用,你可以参看C:\WINDOWS\system32\wbem目录中的*.xsl文件,你甚至不用管它们从哪里来的,用就是了。挨着看看,一定可以找到你喜欢的。

第二部分:利用脚本来认识WMI
命令提示符的工具确实好用,但是却显示不出我们是高手,高手都是能利用程序来实现目的的。下面我们就开始用脚本来实现我们的任务,功能将更加强大,操作将更加灵活。
无论脚本还是真正意义上的程序,要检索 WMI 托管资源信息进而查询并利用WMI,都需要遵循以下三个步骤的。
1.连接到 WMI 服务。建立一个到目标计算机上的 Windows 管理服务的连接。
2.检索 WMI 托管资源的实例。主要取决于要执行的任务。
3.显示WMI 某实例属性和调用其方法。

1.任务四:利用脚本实时监视对方进程
在任务一和任务三中我们都是在查看对方的进程,出来的结果对我们意义不是很大,在这个任务中我们要从现在开始每当他开一个任务我们就察觉到,并把它记录下来。我们要在他开进程的那一秒开始报告并记录,我们要清楚他所开的程序所在的位置,我们要比他更清楚地知道这些信息。
现在我们就按照前面提到的三个步骤来实现任务。
首先,我们连接到对方的WMI。在这里我们首先调用 VBScript 的中的CreateObject()来得到一个对象,然后利用这个特殊的对象的方法来连接到远程的计算机上。这个特殊的对象就是wbemscripting.swbemlocator。
set olct=CreateObject("wbemscripting.swbemlocator")
set wbemServices=olct.connectserver(strComputer,"root\cimv2",strUser,strPwd)
注意其中的strComputer就是你所要连接的计算机的名称或者IP地址,strUser,strPwd当然就是用户名和密码了,我们说过这个用户必须是具有管理员权限的才可以。root\cimv2是WMI的命名空间,关于WMI的命名空间,大家可以到"计算机管理\WMI控件"中看到,这里面的学问就大了,得慢慢琢磨,为了我们的任务快速实现,我就不多解释了。用这种方法连接到WMI,返回一个对SWbemServices对象的引用,一旦有一个对 SWbemServices对象的引用。我们就可以进行第二个步骤了。
在第二个步骤中,我们将得到WMI 托管资源的实例,我们利用WbemServices中的一个方法ExecNotificationQuery可以查询我们所要的类,进而可以得到该类中实例。
Set colMonitoredProcesses = wbemServices. _
ExecNotificationQuery("select * from __instancecreationevent " _
& " within 1 where TargetInstance isa 'Win32_Process'")
注意这里有个类似于SQL语言的查询语言,这里叫做WQL语言,懂SQL的一看就明白了,不懂的就在网上找找它的资料,满天都是。得到的colMonitoredProcesses是所查询的类的实例的集合。有了这些我们的第三个步骤就可以开始了。
在第三个步骤中,我们将显示出得到的实例中的属性。刚才我们得到的是实例的集合,在这里我们通过colMonitoredProcesses.NextEvent来获取每一个具体的实例,得到每一个具体的实例后,我们就可以显示出他们的属性,也就是我们想看的东西了。这里我们显示了CommandLine的属性值。
到现在你是否有些迷惑了,因为你还不知道到底WMI里面有那些类,具体类又有哪些属性,呵呵,没有关系的,用一些工具可以很轻松的得到这些信息。比如系统自带的wbemtest,在运行中敲入这个程序名,你就可以看到这些了,它也遵循连接、查询、枚举这三个步骤。自己慢慢玩吧,很快你就会发现WMI太大了,单是命名空间就有10多个,然后单是我们常用的空间root\CIMV2里面就有近1000个类,每个类里面又有好多的属性,有些类还有好多方法。哈哈,头晕了吧?没关系,其实你只需要知道其中的一些就好了。
看到这些估计你的头已经很大了,但是恭喜你,我们的这个任务已经完成了,是的,就是这么简单,下面我将完整代码奉献出来。
Set colArgs = WScript.Arguments
If WScript.arguments.count < 3 then
WScript.Echo "USAGE:" & vbCrLf & " Monitor Computer User Password files"
WScript.quit
End If
strComputer = WScript.arguments(0)
strUser = WScript.arguments(1)
strPwd = WScript.arguments(2)
strFile = WScript.arguments(3)

set olct=CreateObject("wbemscripting.swbemlocator")
set wbemServices=olct.connectserver(strComputer,"root\cimv2",strUser,strPwd)
Set colMonitoredProcesses = wbemServices. _
ExecNotificationQuery("select * from __instancecreationevent " _
& " within 1 where TargetInstance isa 'Win32_Process'")

i = 0
Do While i = 0
Set objLatestProcess = colMonitoredProcesses.NextEvent
WScript.Echo now & " " & objLatestProcess.TargetInstance.CommandLine
Set objFS = CreateObject("Scripting.FileSystemObject")
Set objNewFile = objFS.OpenTextFile(strFile,8,true)
objNewFile.WriteLine Now() & " " & objLatestProcess.TargetInstance.CommandLine
objNewFile.Close
Loop

到这个程序的核心了吧?相信你已经懂了其中的很多,剩余的部分代码我稍后解释。我们先来感性认识一下,先看它该怎么用吧!把上面的代码拷贝到记事本中,然后保存为monitor.vbs的文件,然后在命令提示符下输入:
CSCRIPT monitor.vbs
回车,你就会看到帮助,下面举例说明这个脚本的具体用法:
CSCRIPT monitor.vbs 192.168.1.2 user password C:\1.txt
在命令提示符下敲入上面的命令就OK了,每当对方开一个程序的时候,你就可以看到时间,程序路径和程序名。如果你没有时间去看这些信息,你还可以等有时间的时候到C:\1.txt看到这些信息。

小知识:
每次使用脚本,都必须敲入CSCRIPT和脚本的后缀名,很麻烦。这是因为系统默认的执行引擎是WScript,可以将它改成CSCRIPT。另外一个让人不爽的是脚本执行后总要显示微软的说明,好像脚本不是我们写的一样。不过你可以通过在命令提示符下敲入下面的命令来解决这个问题:
cscript //nologo //h:cscript //s
这样你以后再运行这些脚本的时候就不用在敲入CSCRIPT了,也不用在写入.vbs的后缀名了,就上面的例子来说,你可以这样用:
monitor 192.168.1.2 user password C:\1.txt

解释:
1)前面的那几行,大概就是为了显示帮助和处理我们在后面输入的参数。应用到了WScript.Arguments这个对象,利用它我们可以来获取并处理脚本的参数。
2)那个死循环是为了让我们一直监视他(她),每当他开一个程序,我们就得到一个新的实例,我们就可以知道他更多的信息,哈哈,够狠吧。这样你也就知道了,当我们这个脚本运行后,只有通过我们人为中止才能中断监视,人为中止的方法大家可以用CTRL+C来完成,也可以用各种野蛮的方法来中止。
3)在代码中出现的另外一个核心对象就是FileSystemObject,应该是大家的老朋友了吧,我这里就不再做解释了,我们在这里应用它主要是为了将结果同时保存到一个文件中,我们利用它来创建或打开一个文件,将信息追加进去。
4)至于那个NOW,虽然体积很小,但是却正是它给我们提供了时间这个重要的信息。
5)如果你想要监视的是自己的计算机而不是远程的计算机(据我所知,这个应用还是很广的)。那么请将计算机名的参数写为一个小点,用户名和密码留为空。如下所示:
monitor . "" "" C:\1.txt

2.任务五:利用脚本给对方开放共享
有了任务四的基础,这次我们就先看代码吧:
Set colArgs = WScript.Arguments
If WScript.arguments.count < 5 then
WScript.Echo "USAGE:" & vbCrLf & " Rshare Computer User Password SharePath ShareName"
WScript.quit
End If
strComputer = WScript.arguments(0)
strUser = WScript.arguments(1)
strPwd = WScript.arguments(2)
strPath = WScript.arguments(3)
strShareName = WScript.arguments(4)

intMaximumAllowed = 1
strDescription = "Temporary share"
Const SHARED_FOLDER = 0

set olct=CreateObject("wbemscripting.swbemlocator")
set wbemServices=olct.connectserver(strComputer,"root\cimv2",strUser,strPwd)
Set objSWbemObject = wbemServices.Get("Win32_Share")
intReturnValue = objSWbemObject.Create(strPath, _
strShareName, _
SHARED_FOLDER, _
intMaximumAllowed, _
strDescription)

if(intReturnValue = 0) Then
WScript.Echo "The share have been created successfully"
End If

解说:
1)我们可以看出来前面的那几行是为显示帮助和处理输入参数而存在的。
2)紧接着设置了几个变量,为以后做参数用的。这里我们可以先不理会它。
3)连接到主机的WMI,然后就是查询。前面已经说的很详细了。
4)这次得到实例集后,我们用了它的一个方法,也就是这个方法让共享成为了可能,联系到第二部分的内容,我们不难知道第一个参数表示要共享的路径和文件名,第二个参数表示共享名,第三个参数为0就可以了,第四个参数是指可以连接的人数,第五个参数是共享描述了,而我们只关心前面的两个参数。如果手头有MSDN那就好办了,到MSDN中可以查到该方法的更详细的内容。
5)这次我们根据第四步的返回值来得到共享是否成功,并给出提示。不同的返回值代表不同的意义。这个信息在MSDN中可以很清楚地查到。比如0代表成功返回,2代表拒绝访问,9代表用户名错误,25代表主机名没有找到等等。
6)这次我们要注意的是,用这个脚本来实现远程文件共享,要求远程存在这个文件,否则无法共享。当然你也可以利用教本创建自己的文件夹,很容易的,自己创建吧。
7)如上脚本创建后的共享是完全共享。就是可以删除修改文件的。
8)用法举例:share netp net swswsw C:\dodo marsh

好了,到现在为止,大家应该对这位朋友有些了解了,我的介绍任务也就告一段落了,如果大家想进一步认识它,那就主要靠大家的主动性了。这次我们主要通过WMIC和脚本来认识它,下次我将带领大家通过真正的程序代码来认识它,让它也有个象Windows一样漂亮的脸蛋。今天我所提到的估计只能算是WMI的万分之一,都算不上是冰山一角。剩余的要靠自己来发挥了。如果你肯利用你的所学,那么奇迹就会产生[/code]

HAT 发表于 2009-10-4 19:46

[code]◎VBS脚本应用(打造个性化QQ)

       昨天,要找一个以前写的VBS脚本,可是当时写的就随便,名起的也糊涂,就搜索了一下,咦!~~QQ下怎么还有VBScript.dll和VBScript.vbs这么两个文件来着???我实在太奇怪了。复制出来,打开看看。当然是先看脚本啦!

我晕倒,居然是真正的VBS脚本文件,哦,几个函数似乎在脚本里没有定义,不过很正常,现在好多软件都是这么干的。挨个往下看,Window_OnSize(cx,cy)大概是拉伸面板时调用的吧,Window.LockPaint() 锁定绘图,当然了还有onClick、onMouseMove、onMouseLeave等等都是响应事件的函数,Window.ExeCommand 1,2这是干什么的,网上搜搜,Window.ExeCommand n,m是QQ内部的一些命令,n、m值如下的时候代表不同的操作:1,1 皮肤管理器;1,2 最小化;1,3 close;4,1 ChatRoom;4,2 发送手机短信;4,3 search;4,4 腾讯浏览器;4,5 Game;4,6 信息管理器;4,7 color;4,8 个人帐户;4,9 面板选择;4,10 Mail相关;50,1 显示信息;60,2 个人设置;7,1 Mail;15,1 host

呵呵,太好了,让我修改它一下看看,有响应没有。得了,捡不如撞,就在Window_OnSize(cx,cy)函数的响应后添加一个MsgBox "你确定要改变吗?"退出qq,再次进入,拖动边框,呵呵,出来了。好了,再加一句:CreateObject("WScript.shell").run "notepad.exe",呵呵,退出qq,再次进入,拖动边框,咦?!没有反应?百度一下,哦,QQ自带的VBScript.dll文件不支持外部调用,要外部调用,必须用破解的VBScript.dll文件覆盖原来的?太麻烦了,要不用系统自带的覆盖行不行?试验一下,呵呵,可以!赶紧试试其他的按钮啊,功能啊什么的有没有变化?似乎没有,那!?QQ自己带的这个VBScript.dll到底干了些什么工作?还是有什么我没有发现?!不管它,我们接着来,比如说,我的QQ上的那个收发邮件的那个按钮我从来也不用,放着也是闲着,要不……,把它换成我常用的记事本程序,可以方便我在聊天的时候粘贴从网上复制下的好文章,ok,让我搜索一下mail,找到Sub MailButton_onClick()函数,在函数代码Window.ExeCommand 7,1前加一个小小的 ‘ ,然后加入一行代码:

CreateObject("WScript.shell").run "notepad.exe",退出,重新进入,单击"收发邮件"按钮,呵呵记事本打开了。可是上面怎么老是显示收发邮件啊,怎么能改一下呢?百度一下,ok,图表啊、说明啊,都在Config.xml文件中放着,坏了,xml我不是很熟悉,不过没关系,只要我认识汉字就可以了,还是拿记事本打开看看,单击搜索,填入收发邮件,找到,修改为"记事本",保存,退出QQ,再次进入,呵呵,鼠标移到那个图标上,显示"记事本",完成。呵呵,如果愿意甚至可以把常用的软件的快捷方式都放在QQ皮肤上,把QQ打造成一个完全个性的软件,彻底改变QQ的用处。[/code]

zqz0012005 发表于 2009-10-4 20:32

这个没必要转了,以前在管理群里讨论过,都放在这里:
批处理之家VBS系列教程——第一节 工具与资料
[url]http://www.bathome.net/thread-2382-1-1.html[/url]

Seter 发表于 2009-10-4 21:07

[quote]自己保存的文件自己找不到的人我见的多了去了。[/quote]
这句话太好了...说的不就是我嘛...

liuzhengzhen 发表于 2009-10-29 20:18

写的比较口语化啊 通俗易懂 不像官方教程那么难以理解

页: [1] 2

Powered by Discuz! Archiver 7.2  © 2001-2009 Comsenz Inc.