[已解决]批处理如何去除含特定字符的项（特定字符不止一个）？

batpro · 发表于 2011-7-8 17:24:12

本帖最后由 batpro 于 2011-7-9 09:30 编辑

在1.txt中有：
版主手下留情，我要用颜色说明情况

============================================================================
[HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Run]
→  <Vistadrv><C:\Program Files\vsdrv\vsdrv.exe>[]
→  <AzMixerSel><C:\Program Files\Realtek\InstallShield\AzMixerSel.exe>  [Realtek Semiconductor Corp.]
→  <RTHDCPL><RTHDCPL.EXE>  [Realtek Semiconductor Corp.]
→  <Alcmtr><ALCMTR.EXE>  [Realtek Semiconductor Corp.]
[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run]
→  <Adobe Reaed Launcher>[N/A]
===================================================

如何生成2.txt？
[HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Run]
→ <Vistadrv><C:\Program Files\vsdrv\vsdrv.exe>[]
][HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run]
→ <Adobe Reaed Launcher>[N/A]

复制代码

文件描述下，我的意思是要把1.txt中所有含【含公司数字签名的部分】替换为空，
从而得到2.txt
如何写这代码呢？

batpro · 发表于 2011-7-8 17:38:28

本帖最后由 batpro 于 2011-7-8 17:42 编辑

这边讨论下我以前的代码

cd.>temp.txt
setlocal enabledelayedexpansion
for /f "tokens=*" %%i in (1.txt) do (
set var=%%i
set "var=!var:[Realtek Semiconductor Corp.]=正常!"
echo !var!>>temp.txt
)
@findstr /v "正常" temp.txt >>2.txt

复制代码

这个代码可以用，但是在实际操作中需要添加太多的白名单了

而[N/A]和[]、[File is missing]只有三项，所有请求下如何写能添加黑名单的代码

batpro · 发表于 2011-7-8 17:41:19

如何把上面的代码中
set "var=!var:[Realtek Semiconductor Corp.]=正常!"

变成:[任意值除了【N/A】/【】/【File is missing】]=正常!"

batpro · 发表于 2011-7-8 17:41:19

如何把上面的代码中
set "var=!var:[Realtek Semiconductor Corp.]=正常!"

变成:[任意值除了【N/A】/【】/【File is missing】]=正常!"

ArdentMan · 发表于 2011-7-8 17:43:38

@Echo Off&SetLocal EnableDelayedExpansion
(For /F "delims=" %%i IN (1.txt) Do (
Set "Str=%%i"
If "!Str!" EQU "!Str:[Realtek Semiconductor Corp.]=!" Echo !Str!
))>2.txt
Start 2.txt

复制代码

batpro · 发表于 2011-7-8 17:47:55

5# ArdentMan

代码中不应出现:[Realtek Semiconductor Corp.]
因为只是个例子而已，具体值很多应该出现[N/A]、[]和[File is missing ]

ArdentMan · 发表于 2011-7-8 17:56:25

本帖最后由 ArdentMan 于 2011-7-8 17:57 编辑

@Echo Off&SetLocal EnableDelayedExpansion
(For /F "delims=" %%i IN (1.txt) Do (
Set "Str=%%i"&Set "Flag="
For %%a IN ("N/A" "File is missing" "") Do (
If "!Str!" NEQ "!Str:[%%~a]=!" Set "Flag=a"
)
If Defined Flag Echo !Str!
))>2.txt
Start 2.txt

复制代码

batpro · 发表于 2011-7-8 18:45:45

本帖最后由 batpro 于 2011-7-8 18:47 编辑

7# ArdentMan

谢谢兄弟的辛苦

不过我要说的是，你给的第一个代码和第二个代码出来的结果不同，结果应该是

[HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Run]
→ <Vistadrv><C:\Program Files\vsdrv\vsdrv.exe>[]
[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run]
→ <Adobe Reaed Launcher>[N/A]

复制代码

而你的第二个代码只是

这个结果

→ <Vistadrv><C:\Program Files\vsdrv\vsdrv.exe>[]
→ <Adobe Reaed Launcher>[N/A]

复制代码

错在:其他部分没了

ArdentMan · 发表于 2011-7-8 18:53:05

@Echo Off&SetLocal EnableDelayedExpansion
(For /F "delims=" %%i IN (1.txt) Do (
Set "Str=%%i"&Set "Flag="
If /I "!Str:~,5!" EQU "[HKEY" Set "Flag=a"
For %%a IN ("N/A" "File is missing" "") Do (
If "!Str!" NEQ "!Str:[%%~a]=!" Set "Flag=a"
)
If Defined Flag Echo !Str!
))>2.txt
Start 2.txt

复制代码

batpro · 发表于 2011-7-8 19:12:48

9# ArdentMan

太棒了，
坚定的相信这里确实高手如云
我想到的，你能办到
我没想到的，你想到了
所以
谢谢你兄弟，谢谢bathome！

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理如何去除含特定字符的项（特定字符不止一个）？

评分

评分