[已解决]批处理如何提取ping命令结果的指定信息？

lijinpengying · 发表于 2012-5-5 10:22:57

是这么一个事情……
我突然想试试自己学到一个什么程度了。于是在百度上去回答问题，有一个问题是：
在一个文本里有若干的ＩＰ地址。
写一个批处理依次对其进行ping处理。（：：这个我还是能做得出来的，嘻嘻……）
对结果进行处理。要求提取出所有能ping通的ＩＰ。（：：就是这，我不能有效的提取出来……）
亲爱的大大些。仁慈如您们的人，一定会不吝赐教的，对吧！
嘻嘻！谢谢各位大大！在我的成长路上，希望有诸位的见证……
求符合要求的代码以供小菜研究！
不胜感激，感激涕零啊大大！

yangfengoo · 发表于 2012-5-5 10:57:26

ping www.bathome.net&&echo 成功||echo 失败

秋风·飞扬 · 发表于 2012-5-5 12:48:12

for /f %%i in (1XXX.txt) do (
set /a n+=1
ping %%i
if %errorlevel%==0 echo %%i>>2XXX.txt
)
1XXX.txt是你装IP的文件
2XXX.txt是可以平通的文件，能PING通的都在里面

秋风·飞扬 · 发表于 2012-5-5 12:50:21

回复 3# 秋风·飞扬

哦上面没有set /a n+=1 这句没用，我忘删掉了

秋风·飞扬 · 发表于 2012-5-5 12:54:48

回复 1# lijinpengying

互相帮助，尽力而为，。

秋风·飞扬 · 发表于 2012-5-5 13:39:21

如果问题解决，就在标题上修改【已解决】

秋风·飞扬 · 发表于 2012-5-5 14:17:38

代码需要改，先等一下吧

lijinpengying · 发表于 2012-5-5 15:27:06

回复 7# 秋风·飞扬

代码是错误的。因为无论如何ping命令都是成功执行的，所以你这个代码是不可能判断出哪些能拼通哪些不能。唉……
我记得以前见过正确的代码，可是忘了在哪里看到的了。好像是利用了findstr命令。

lijinpengying · 发表于 2012-5-5 15:54:15

@echo off &setlocal enabledelayedexpansion
for /f %%i in (ip.txt) do (
set ip=%%i
ping /n 1 !ip! | findstr /i "reply"&&if errorlevel==0 echo !ip! >>now.txt
)

解决啦！嘻嘻！

秋风·飞扬 · 发表于 2012-5-5 18:29:59

回复 8# lijinpengying

对不起啊，真是不好意思，我下午去上课了，那个代码 for循环里面的两句合并为一句，ping /n 2 %%i && echo %%i >>2.txt 即可，sorry~

ShenMian · 发表于 2017-10-4 15:22:01

根据这个改吧，作者QQ:2294394563

@echo off
set pingTimes=1
if "%1"=="/?" (
echo Usage: %~n0 [-f filename] [-o filename] domain [-call skip lines ^| -t Threads_NUM All_lines]
echo Options:
echo -f Dict file used to brute sub names.
echo Default:resolvers.txt
echo -o Output file name.
echo -t Number of threads and lines.
rem echo -call emm...
echo;
echo 20171003
exit /b
)
:0
if "%1"=="-f" (
set resolvers=%~2
shift
shift
goto 0
)
if not defined resolvers set resolvers=resolvers.txt
if not exist "%resolvers%" (
echo Can't found "%resolvers%".
exit /b
)
if "%1"=="-o" (
set output=%~2
shift
shift
goto 0
)
if not defined output set output=nul
set domain=%~1
if "%2"=="-t" (
if "%output%"=="nul" (
echo Output file is not specified.
exit /b
)
set /a threads=%3-1
set allLines=%4
setlocal enabledelayedexpansion
if !threads! lss 0 (
echo Threads leq 0!
exit /b
)
if !allLines! lss !threads! (
echo All_lines lss Threads_NUM!
exit /b
)
set /a lines=allLines/(threads+1^)
for /l %%a in (1,1,!threads!) do (
set /a skip=%%a*lines
start "SubBrute Threads:%%a" subbrute -o "%output%" -f "%resolvers%" %domain% -call !skip! !lines! >nul
)
title SubBrute Threads:0
echo All threads are running.
)
if "%2"=="-call" (
if "%output%"=="nul" (
echo Output file is not specified.
exit /b
)
setlocal enabledelayedexpansion
set skip=%3
if !skip! leq 0 (
echo Skip leq 0!
exit /b
)
set times=%4
shift
shift
shift
for /f "usebackq skip=%skip%" %%a in ("%resolvers%") do (
ping /n %pingTimes% %%a.%domain% >nul 2>nul
if !errorlevel!==0 (
echo %%a.%domain%
echo %%a.%domain% >>"%output%"
)
set /a times-=1
if "!times!"=="0" exit
)
)
if defined lines setlocal enabledelayedexpansion
set scan=0
set found=0
for /f usebackq %%a in ("%resolvers%") do (
ping /n %pingTimes% %%a.%domain% >nul 2>nul
if !errorlevel!==0 (
echo %%a.%domain%
echo %%a.%domain% >>"%output%"
set /a found+=1
)
set /a scan+=1
set /a lines-=1
if !lines!==0 exit
)
echo;
echo %found% found ^| %scan% sacnned
exit /b

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[网络连接] [已解决]批处理如何提取ping命令结果的指定信息？

评分

评分