[已解决]批处理如何实现类似and 的判断条件(i<0 and j=4)？

newfish

伪代码如下.

1. 
   
2. for /f  "delims= tokens=1" %%a in ('1.txt') do (
   
3.        
   
4.         if %%a leq 5120000 and %%b==xxx
   
5.         echo %%a
   
6. )
   

复制代码

想实现类似这样的,...批处理代码该怎么写.求教了.

cb02356828

两个 if 连用

1. if %i% lss 0 (if %j% equ 4 echo xxx)

复制代码

yangfengoo

if %%a leq 5120000 if %%b==xxx echo %%a

newfish

多谢 CB023...兄弟 那else 该加在哪..

apang

回复 4# newfish

加2个else

1. if %i% lss 0 (
   
2.   if %j% equ 4 (echo ok
   
3.   ) else echo nok
   
4. ) else echo nok

复制代码

neorobin

cmd 下 if 仅能处理最简单的逻辑表达式, set /a 的位运算是针对这个欠缺的补充

1. @echo off & setlocal enabledelayedexpansion
   
2. echo,TEST (i^<0 and j=4)
   
3. 
   
4. <nul (
   
5.   set /p "= i \ j"
   
6.   for /l %%j in (-3 1 6) do set "O=     %%j" & set /p "=!O:~-4!"
   
7.   echo,
   
8.   for /l %%i in (-2 1 3) do (
   
9.     set "O= %%i" & set /p "=!O:~-2!    "
   
10.     for /l %%j in (-3 1 6) do (
    
11.       set /a i=%%i, j=%%j
    
12.       set /a "r=(i>>31) & ^!(j-4)" & rem 31 取值为 cmd 下无符号数的位数 - 1
    
13.       if !r! equ 1 (set /p "=   T") else (set /p "=   F")
    
14.     )
    
15.     echo,
    
16.   )
    
17. )
    
18. pause

复制代码