[已解决]批处理怎样计算某天是当年中的某一天，某一周？

珠七七

请问一下，我要用批处理计算某天是当年中的某一天，某一周。请各位帮忙设计一下代码。谢谢！
例如：
2012年02月02日   
是2012年的第33天，第5周。

forfiles

1. @echo off
   
2. set mydate=2012-02-02
   
3. call :DateToOrdinal %mydate:~0,4% %mydate:~5,2% %mydate:~8,2% year doy
   
4. call :DateToWeek %mydate:~0,4% %mydate:~5,2% %mydate:~8,2% yn cw dw
   
5. echo %mydate%是%year%年的第%doy%天，第%cw%周。
   
6. pause
   
7. goto :eof
   
8. 
   
9. :DateToOrdinal %yy% %mm% %dd% year doy
   
10. setlocal ENABLEEXTENSIONS
    
11. set yy=%1&set mm=%2&set dd=%3
    
12. if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
    
13. set /a dd=100%dd%%%100,mm=100%mm%%%100
    
14. set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
    
15. set /a j=j/5+dd+y*365+y/4-y/100+y/400-32045
    
16. set /a y=yy+4799,k=y*365+y/4-y/100+y/400-31738,o=j-k+1
    
17. if %o% LSS 100 set o=0%o%&if %o% LSS 10 set o=00%o%
    
18. endlocal&set %4=%yy%&set %5=%o%&goto :EOF
    
19. 
    
20. :DateToWeek %yy% %mm% %dd% yn cw dw
    
21. setlocal ENABLEEXTENSIONS
    
22. set yy=%1&set mm=%2&set dd=%3
    
23. if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
    
24. set /a dd=100%dd%%%100,mm=100%mm%%%100
    
25. set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,Jd=153*m+2
    
26. set /a Jd=Jd/5+dd+y*365+y/4-y/100+y/400-32045
    
27. set /a y=yy+4798,Jp=y*365+y/4-y/100+y/400-31738,t=Jp+3,Jp=t-t%%7
    
28. set /a y=yy+4799,Jt=y*365+y/4-y/100+y/400-31738,t=Jt+3,Jt=t-t%%7
    
29. set /a y=yy+4800,Jn=y*365+y/4-y/100+y/400-31738,t=Jn+3,Jn=t-t%%7
    
30. set /a Jr=%Jp%,yn=yy-1,yn+=Jd/Jt,yn+=Jd/Jn
    
31. if %Jd% GEQ %Jn% (set /a Jr=%Jn%) else (if %Jd% GEQ %Jt% set /a Jr=%Jt%)
    
32. set /a diff=Jd-Jr,cw=diff/7+1,wd=diff%%7,wd+=1
    
33. if %cw% LSS 10 set cw=0%cw%
    
34. endlocal&set %4=%yn%&set %5=%cw%&set %6=%wd%&goto :EOF

复制代码

珠七七

非常谢谢！！