请问：批处理如何实现文件打包及按日期命名？

nintendoww · 发表于 2012-12-3 09:14:29

我想把文件夹里面的TXT、DOC文件打包压缩，并且按照头一天的日期命名，请问该怎么处理，尤其是怎么按照前一天的日期命名？多谢各位

BAT-VBS · 发表于 2012-12-3 14:45:13

你是打算用WinRAR吗？

wjx515 · 发表于 2012-12-3 14:55:52

本帖最后由 wjx515 于 2012-12-3 14:58 编辑

取前一天日期

@echo off
::需要调用VBS
rem 指定天数
set DaysAgo=1
>"%temp%\MyDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\MyDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\MyDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\MyDate.vbs"') do (
set DstDate=%%a
)
echo %DstDate%
pause

复制代码

nintendoww · 发表于 2012-12-3 15:58:18

是，是用RAR，里面有一些命令可以用，但是我就是不会命名为前一天，只会命名为今天

BAT-VBS · 发表于 2012-12-3 16:54:56

回复 4# nintendoww

3楼已经告诉你怎样获得昨天的日期了

namejm · 发表于 2012-12-3 17:15:33

@echo off
for /f %%i in ('tad32.exe -1d -f$Y$0m$0d') do set yDay=%%i
rar.exe a -n*.txt -n*.doc %yDay%.rar
pause

复制代码

需要命令行工具 rar.exe 和 tad32.exe
rar.exe 估计你可以从WinRAR的安装目录中提取出来
tad32.exe 需要从网上下载，官方网站在这里：http://tad.adoxa.cjb.net/

nintendoww · 发表于 2012-12-4 09:04:06

回复 nintendoww

3楼已经告诉你怎样获得昨天的日期了
BAT-VBS 发表于 2012-12-3 16:54

谢谢你们的帮助，谢谢3楼的

但是，我是这方面的小白，前一天的日期是提取出来了，怎么结合RAR，命名到压缩包名字里面去

我现在用的批处理语句是
"C:\Program Files\WinRAR\WinRAR.exe" a -tn21h -o+ -r -rr10p -t -x*.bat -m5 -ag+YYYY-MM-DD- 工作日志
PAUSE

BAT-VBS · 发表于 2012-12-5 10:28:56

回复 7# nintendoww

@echo off
set DaysAgo=1
>"%temp%\MyDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\MyDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\MyDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\MyDate.vbs"') do (
set DstDate=%%a
)
"C:\Program Files\WinRAR\WinRAR.exe" a %DstDate%.rar test.txt

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[日期时间] 请问：批处理如何实现文件打包及按日期命名？