XP下，通过读取注册表获取的桌面路径不完整/缺少字符串是什么原因

ibm

在XP下，如果桌面路径没有更过，是%USERPROFILE%\桌面

下面运行代码：

1. 
   
2. reg QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\USER Shell Folders" /V "Desktop" >tmp.txt
   
3. type tmp.txt
   

复制代码

结果是：“%USERPROFILE%\桌”，少了最后一个汉字“面”

1. 
   
2. reg QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\USER Shell Folders" /V "Desktop" | find "Desktop"
   

复制代码

结果同样是少了最后一个汉字“面”，


这是为什么？
如何解决？

Batcher

XP SP2中文版的reg.exe有bug，当reg query遇到中文字符时可能会"吃字符"，详见http://www.cn-dos.net/forum/viewthread.php?tid=22202

解决方案如下：
1. 用XP SP2以上的版本的操作系统(XP SP3/2003/Vista等，XP SP2英文版也可)中的reg.exe来替换XP SP2中文版的reg.exe
2. 调用VBS读注册表，并把返回结果传递给BAT
3. 用reg export把注册表项导出到一个临时文件，再搜索该文件，值得注意的是reg export导出的文件是Unicode编码格式，可以使用type命令进行处理

ibm

明白了，十分感谢！

ibm

第一个办法：用高版本REG.EXE替换较低版本，失败。
　　　　XP sp3的版本V5.1.2600.5512遇到中文路径有时是乱码。
　　　　Vista的V6.0.6000.16386替换后运行REG QUERY提示拒绝访问，之后会被替换回XPSp2原有版本。

第二个办法：不会，还请指点？

第三个办法：不知道TYPE如何处理Unicode编码格式，还请指点。

ibm

Vista的REG.exe版本为　 REG V6.0.6000.16386
XP sp3的REG.exe版本为　REG V5.1.2600.5512
XP sp2的REG.exe版本为　REG V5.1.2600.2180

用XP sp3的REG.exe替换XP sp2的版本可行，但又有点麻烦，
必须同时替换%SystemRoot%\System32和%SystemRoot%\System32\Dllcache两个目录下的REG.exe，
但这样又会出现“文件保护”的提示，如何解决？

zqz0012005

第二个办法vbs不会？

1. @echo off
   
2. echo wscript.echo CreateObject("WScript.Shell").RegRead("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders\desktop") >t~.vbs
   
3. for /f "delims=" %%a in ('cscript //nologo t~.vbs') do set "mydesk=%%a"
   
4. echo %mydesk%
   
5. del t~.vbs & echo. & pause

复制代码

第三个办法，REG_EXPAND_SZ类型的数据导出后成了Hex(2) 16进制形式，所以这个办法有局限性
type不会？：

1. reg export "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" desktop.reg
   
2. for /f "tokens=1* delims==" %%a in ('type desktop.reg ^| find /i "desktop"') do set "mydesk=%%~b"
   
3. set "mydesk=%mydesk:\\=\%"
   
4. echo %mydesk%

复制代码

ibm

我不懂VBS，第二个办法似乎有点复杂，而且我要提取的不止一个桌面路径，考虑别的办法吧。

版主给的第三个办法，你的代码是没有问题，但我要的是HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders分支，
正是版主所说的REG_EXPAND_SZ类型的数据，还是不成功。

现在看，只能考虑第一种办法了，关闭文件保护。

谢谢版主！

Batcher

不懂VBS没有关系，6楼不是已经给你写好代码了吗？直接调用即可。

ibm

这样为何不行？VBS代码不能嵌套在IF里吗？该如何写？

1. IF NOT DEFINED Desktop (
   
2.    ECHO WSCRIPT.ECHO CREATEOBJECT("WSCRIPT.SHELL").REGREAD("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders\desktop") >"%TEMP%\t~.vbs"
   
3.   FOR /F "DELIMS=" %%I IN ('CSCRIPT //NOLOGO "%TEMP%\t~.vbs"') DO ( CALL SET "Desktop=%%~I" )
   
4.       ECHO -%Desktop%- && PAUSE
   
5. )

复制代码

[ 本帖最后由 ibm 于 2008-11-14 10:26 编辑 ]

Batcher

你检查一下 echo 命令生成的 %TEMP%\t~.vbs 文件内容是否正确

ibm

根本就不生成%TEMP%\t~.vbs 文件

Batcher

1. @echo off
   
2. IF NOT DEFINED Desktop (
   
3.   ECHO 我在括号里面
   
4.   ECHO WSCRIPT.ECHO CREATEOBJECT^("WSCRIPT.SHELL"^).REGREAD^("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders\desktop"^)>"%TEMP%\t~.vbs"
   
5.   TYPE "%TEMP%\t~.vbs"
   
6. )
   
7. PAUSE

复制代码

ibm

明白了，十分感谢！