[已解决]批处理获取文件创建时间为何失败？

mms0536 · 发表于 2013-7-26 15:24:47

本帖最后由 mms0536 于 2013-8-5 19:54 编辑

答案2楼三楼都行,非常感谢batman 和apang,问题已经解决,谢谢你们

echo ----------获取工作站文件详细信息---------->>.\info_by_MMS.txt
for /r .\ %%i in (*.*) do (echo 文件名=%%~nxi 文件大小=%%~zi字节修改时间=%%~ti 创建时间=%%~'dir /tc /a-d' 文件属性=%%~ai) >>.\info_by_MMS.txt

如上,运行后不能获取创建时间......

谢谢

batman · 发表于 2013-7-26 20:29:01

本帖最后由 batman 于 2013-7-26 20:35 编辑

@echo off
(
echo ----------获取工作站文件详细信息----------
for /r .\ %%a in (*) do (
for /f "tokens=1,2" %%b in ('dir /tc "%%a"^|findstr "%%~nxa"') do (
echo 文件名=%%~nxa 文件大小=%%~za字节修改时间=%%~ta 创建时间=%%b %%c 文件属性=%%~aa
)
)
)>.\info_by_MMS.txt

复制代码

apang · 发表于 2013-7-26 21:31:34

wmic来一个

@echo off
echo ----------获取工作站文件详细信息---------->.\info_by_MMS.txt
set "p=%~p0"
call :GetSubFolders>>.\info_by_MMS.txt
pause&goto :eof
:GetSubFolders
set w1=wmic datafile where "drive='%~d0' and path='%p:\=\\%'"
set w2=wmic fsdir where "drive='%~d0' and path='%p:\=\\%'"
for /f "tokens=1-3*" %%a in ('%w1% get CreationDate^,FileSize^,LastModified^,Name 2^>nul^|find ":"') do (
for /f "tokens=*" %%i in ("%%d") do (
echo,文件名=%%~nxi 大小=%%b字节修改时间=%%~nc 创建时间=%%~na 文件属性=%%~ai
)
)
for /f "delims=" %%a in ('%w2% get Name 2^>nul^|find ":"') do (
for /f "tokens=*" %%b in ("%%a") do (
set "p=%%~pnxb"
call :GetSubFolders
)
)

复制代码

mms0536 · 发表于 2013-7-29 11:54:45

回复 2# batman

非常感谢,已经可以了,去查查,基础太差了,

mms0536 · 发表于 2013-7-29 11:56:19

回复 3# apang

你的也可以,同样感谢,也去研究下,多谢回复

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]批处理获取文件创建时间为何失败？

评分

评分