bathome比赛题第二题

ADSL0125

2、检查系统里面是否有非法增加和减少的用户账号
注意：
（1）假设文件 D:\BatHome_User_List.txt 里面保存着所有的合法用户的列表
（2）需要分别找出当前系统里面非法增加的账号和减少的账号

分析:
批处理查看用户帐号的命令是NET USER,不过,这个看不到隐藏帐号(以$结束的用户名)
结果以表方式列出,一行三个
用户名最多20个字符,后面用空格补全到25个字符
用户名中是是可以使用空格的,直接用For来分割可能会有问题

1.处理NET USER的结果,循环去D:\BatHome_User_List.txt 验证是否存在,计算出合法用户,非法增加的帐号
2.NET USER的结果找个地方存起来
3.循环D:\BatHome_User_List.txt,与NET USER的结果比较验证,检查减少的帐号

1. @ECHO OFF
   
2. 
   
3. :: NET USER结束语
   
4. SET @NETUSER_EndWord=命令成功完成。
   
5. :: 合法用户列表
   
6. SET @UserList=D:\BatHome_User_List.txt
   
7. :: 比较时使用的Log
   
8. SET @CompareLog=D:\BatHome_User_List_Compare.log
   
9. 
   
10. REM 读取现有系统中有用户,随便检查然后输出到@CompareLog
    
11. DEL /Q %@CompareLog%>NUL 2>NUL
    
12. 
    
13. SET /A r1=0,r2=0,r3=0
    
14. SET k=
    
15. SET u=
    
16. FOR /F "tokens=*" %%a IN ('NET USER') DO (
    
17.         REM 发现结束语,终止输出
    
18.         ECHO %%a|FIND "%@NETUSER_EndWord%" >NUL&&SET k=
    
19. 
    
20.         IF DEFINED k (
    
21.                 SET s=%%a
    
22.                 FOR /L %%b IN (0,25,50) DO (
    
23.                         REM 截取20位
    
24.                         CALL;SET "u=%%s:~%%b,20%%"
    
25.                         REM 去掉左右空格
    
26.                         FOR /F "delims=" %%d IN ('ECHO %%u%%') DO SET "u=%%~nxd"
    
27. 
    
28.                         FOR /F %%c IN ('ECHO %%u%%') DO (
    
29.                                 IF "%%c" NEQ "%%u%%" (
    
30.                                         FINDSTR /B /E "%%c" %@UserList%>NUL&&SET K2=0||SET K2=1
    
31.                                         FOR /F %%d IN ('ECHO %%K2%%') DO (
    
32.                                                 IF "%%d"=="0" (
    
33.                                                         SET /A r1+=1
    
34.                                                         ECHO %%c [合法用户]
    
35.                                                         ECHO %%c [合法用户]>>%@CompareLog%
    
36.                                                 ) ELSE (
    
37.                                                         SET /A r2+=1
    
38.                                                         ECHO %%c [非法增加]
    
39.                                                         ECHO %%c [非法增加]>>%@CompareLog%
    
40.                                                 )
    
41.                                         )
    
42.                                 )
    
43.                         )
    
44.                 )
    
45.         ) ELSE (
    
46.                 REM 以-为开始行,设置k用于纪录输出
    
47.                 ECHO %%a|FIND "-" >NUL&&SET k=OK
    
48.         )
    
49. )
    
50. REM 读取现有列表中有用户,检查减少
    
51. FOR /F "tokens=*" %%a IN (%@UserList%) DO (
    
52.         FINDSTR /B "%%a [" %@CompareLog%>NUL&&SET K2=0||SET K2=1
    
53.         FOR /F %%b IN ('ECHO %%K2%%') DO (
    
54.                 IF "%%b"=="1" (
    
55.                         SET /A r3+=1
    
56.                         ECHO %%a [不明减少]
    
57.                         ECHO %%a [不明减少]>>%@CompareLog%
    
58.                 )
    
59.         )
    
60. )
    
61. ECHO =============================================================================
    
62. ECHO 比较后%r1%位用户与列表一致,%r3%位用户不明减少,%r2%位用户非法增加
    
63. 
    
64. DEL /Q %@CompareLog%>NUL 2>NUL
    
65. 
    
66. PAUSE
    
67. EXIT /B

复制代码

之后题目好难啊

xpw

6个嵌套，头都晕了..