【已解决】批处理命令for嵌套中怎样使用变量嵌套？

ge_xin_yu · 发表于 2014-3-2 14:05:47

本帖最后由 ge_xin_yu 于 2014-3-4 20:53 编辑

文件sample.xml：

<gfx-1 id="page" group-id="1" />

复制代码

现在想将sample.xml中的字符“page”替换为随机数，输出2次，代码如下：

@echo off & SETLOCAL EnableDelayedExpansion
for /l %%i in (1,1,2) do (
set r=!random!
for /f "delims=" %%j in (sample.xml) do (
set a=%%j
set var=!a:page=%r%!
echo 替换后的值: !var!
)
)
pause

复制代码

运行，输出如下：

<gfx-1 id="" group-id="1" />
<gfx-1 id="" group-id="1" />

复制代码

没有效果，“page”替换为空，测试发现如果去掉外层的for语句，替换正常。估计和变量延迟有关，于是将set var=!a:page=%r%!改为set var=!a:page=!r!!，运行，却得到了另外的结果，后面多了个“r”，如下：

<gfx-1 id="" group-id="1" /> r
<gfx-1 id="" group-id="1" /> r

复制代码

也是失败，对这个变量延迟仍然比较糊涂，变量中不允许两组感叹号存在吗？如果在复合语句嵌套中需要嵌套变量，该怎么办呢？另外第二次替换后为何多个“r”呢？请教大家，深致谢意！！

battab · 发表于 2014-3-2 16:56:42

回复 1# ge_xin_yu

我也不懂怎么搞，同盼高人指点，在此给出达到目的的方法。

@echo off &setlocal enabledelayedexpansion
set c=0
:l
set r=%random%
for /f "delims=" %%j in (sample.xml) do (
set a=%%j
set var=!a:page=%r%!
echo 替换后的值: !var!
)
set/a c+=1
if %c% geq 2 (goto end) else goto l
:end
pause

复制代码

ge_xin_yu · 发表于 2014-3-2 17:27:24

回复 ge_xin_yu

我也不懂怎么搞，同盼高人指点，在此给出达到目的的方法。
battab 发表于 2014-3-2 16:56

感谢！去掉一层嵌套是可以正常替换，但加了一层for为什么就不行呢，我想搞清楚如果在两层for中变量嵌套的话该如何写。原文件大概有一千个多个相似的语句，用for最为简洁。

Batcher · 发表于 2014-3-2 17:42:44

变量中不允许两组感叹号存在吗？

是的

Batcher · 发表于 2014-3-2 17:45:38

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,2) do (
set r=!random!
call :Change_Str !r!
)
pause
goto :eof
:Change_Str
for /f "delims=" %%j in (sample.xml) do (
set a=%%j
set var=!a:page=%1!
echo 替换后的值: !var!
)

复制代码

ge_xin_yu · 发表于 2014-3-2 22:55:49

Batcher 发表于 2014-3-2 17:45

成功解决，强烈感谢，谨祝愉快！！

zhanglei1371 · 发表于 2014-3-3 11:24:49

本帖最后由 zhanglei1371 于 2014-3-3 11:41 编辑

回复 1# ge_xin_yu

可以再加一层for来解决：

for /l %%i in (1,1,2) do (
set r=!random!
for /f "delims=" %%j in (sample.xml) do (
set a=%%j
for %%s in (!r!) do (
set var=!a:page=%%s!
echo 替换后的值: !var!)
)
)

复制代码

或用sed

for /l %%i in (1,1,2) do (
set r=!random!
for /f "delims=" %%j in (sample.xml) do (
set a=%%j
echo 替换后的值为： "!a!"|sed "s/page/!r!/g"
)
)

复制代码

DAIC · 发表于 2014-3-3 12:23:02

回复 7# zhanglei1371

内层for循环可以省去

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,2) do (
set r=!random!
sed "s/page/!r!/g" sample.xml
)

复制代码

zhanglei1371 · 发表于 2014-3-3 13:54:53

回复 8# DAIC

谢谢，问题是如要要原样显示出这几个字：”替换后的值为：“，不用内层for的话怎么做到？
另外还想请教下，
set a=abcd
echo !a!|sed "/s/b/000/",
用sed将b替换为000，后可得到,那么如要赋予变量str
最后可得到：
echo ！str！显示为a000cd
这个过程该如何操作？

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 【已解决】批处理命令for嵌套中怎样使用变量嵌套？

评分