【已解决】批处理文件夹名中数字补0

haole · 发表于 2014-6-19 19:17:58

本帖最后由 haole 于 2014-6-20 00:16 编辑

有很多文件夹是以数字命名的，怎样才能让文件夹名中不足3位的数字补0，文件夹中有文件，希望修改文件夹名字，不修改文件名字

例1：文件夹的名字分别是1，2，3……，希望修改为001，002，003……
例2：文件夹的名字分别是1_1，1_2，1_3……，希望修改为001_001，001_002，001_003……

附上解决办法：

例1代码由

522235677

提供

@echo off & setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /ad /b') do (
set a=%%a
if "!a:~1,1!"=="" (ren %%a 00%%a) else (if "!a:~2,1!"=="" ren %%a 0%%a)
)
pause

复制代码

例2代码由

apang

提供

@echo off & setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=_" %%a in ('dir /ad /b *_*') do (
set /a a=%%a+1000,b=%%b+1000
ren %%a_%%b !a:~-3!_!b:~-3!
)
pause

复制代码

522235677 · 发表于 2014-6-19 19:43:56

@echo off & setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /ad /b') do (
set a=%%a
if "!a:~1,1!"=="" (ren %%a 00%%a) else (if "!a:~2,1!"=="" ren %%a 0%%a)
)
pause

复制代码

@echo off & setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=_" %%a in ('dir /ad /b *_*') do (
set a=%%a
if "!a:~1,1!"=="" (set n=00%%a) else (if "!a:~2,1!"=="" set n=0%%a)
set a=%%b
if "!a:~1,1!"=="" (set m=00%%a) else (if "!a:~2,1!"=="" set m=0%%a)
ren %%a_%%b !n!_!m!
)
pause

复制代码

haole · 发表于 2014-6-19 20:11:29

回复 2# 522235677

非常感谢！
第一个代码测试成功！

第二个有点问题：

我测试的文件夹刚开始如下图：

运行bat文件后，结果如下图：

再追问一下，如果处理文件，代码该如何修改

522235677 · 发表于 2014-6-19 20:30:36

回复 3# haole

@echo off & setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=_" %%a in ('dir /ad /b *_*') do (
set a=%%a
if "!a:~1,1!"=="" (set n=00%%a) else (if "!a:~2,1!"=="" (set n=0%%a) else (set n=%%a))
set a=%%b
if "!a:~1,1!"=="" (set m=00%%a) else (if "!a:~2,1!"=="" (set n=0%%a) else (set m=%%a))
ren %%a_%%b !n!_!m!
)
pause

复制代码

Batcher · 发表于 2014-6-19 20:50:42

dir /ad /b 是处理文件夹
dir /a-d /b 是处理文件

haole · 发表于 2014-6-19 20:58:52

回复 3# haole

刚测试了一下，好像还是不行，下面是测试结果：

haole · 发表于 2014-6-19 20:59:40

回复 5# Batcher

哦，学习了，非常感谢

apang · 发表于 2014-6-19 21:59:21

@echo off & setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=_" %%a in ('dir /ad /b *_*') do (
set /a a=%%a+1000,b=%%b+1000
ren %%a_%%b !a:~-3!_!b:~-3!
)
pause

复制代码

haole · 发表于 2014-6-20 00:11:39

回复 8# apang

非常感谢，测试成功

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 【已解决】批处理文件夹名中数字补0

评分

评分

评分