【已解决】批处理如何将文本中特定字符串的部分内容替换成其他内容

owe911 · 发表于 2015-3-3 11:33:39

本帖最后由 pcl_test 于 2016-10-9 21:17 编辑

譬如 e:\123.txt 内容中的某一行 NUM=0，这个数值是变化的
我想写一个bat，可以替换NUM为指定的数值，譬如4。
我写了以下的代码，发现最终文档是在最后一行加上了NUM=4，而并非替换以前的NUM=0
请大家指点以下，如何修改，是替换NUM=后面的数字，而不是在增加~

@echo off
for /f "tokens=* delims=" %%i in (e:\123.txt) do (
for /f "tokens=1" %%m in (';findstr "NUM" e:\123.txt';) do (
if "%%i"=="%%m" ( echo NUM=4 >>123.txt)
))
start e:\123.txt
exit

复制代码

pcl_test · 发表于 2015-3-3 11:59:25

回复 1# owe911

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%a in ('findstr /n "NUM=" "e:\123.txt"') do set n=%%a
set m=1
for /f "tokens=1* delims=:" %%b in ('findstr /n .* "e:\123.txt"') do (
if !m! == !n! (
>>$ echo,NUM=4
) else (
>>$ echo,%%c
)
set /a m+=1
)
move $ "e:\123.txt"
pause

复制代码

DAIC · 发表于 2015-3-13 10:55:45

重定向放在for循环外面可以提高效率

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%a in ('findstr /n "NUM=" "e:\123.txt"') do set n=%%a
set m=1
(for /f "tokens=1* delims=:" %%b in ('findstr /n .* "e:\123.txt"') do (
if !m! == !n! (
echo,NUM=4
) else (
echo,%%c
)
set /a m+=1
))>123.txt.tmp
move 123.txt.tmp "e:\123.txt"
pause

复制代码

DAIC · 发表于 2015-3-13 11:41:05

用 sed 替换文件内容比较方便

sed -i -r "s/NUM=[0-9]+/NUM=4/" 1.txt

复制代码

owe911 · 发表于 2015-3-13 14:40:41

回复 3# pcl_test
感谢大神

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 【已解决】批处理如何将文本中特定字符串的部分内容替换成其他内容

评分