批处理判断变量值是否合法。有什么好的思路吗？

chouxia

如题，有的时候需要从txt文件或者回显中获取变量值。
我想知道怎么判断这个变量是否合法。
比如：值全都是数字、字母或者数字字母混合

flyinnet9

抛砖。。

纯数字

1. findstr "^[0-9]*[0-9]$"

复制代码

纯字母

1. findstr  "^[A-Z]*[A-Z]$"

复制代码

混合

1. findstr /v "^[0-9]*[0-9]$"|findstr /v  "^[A-Z]*[A-Z]$"

复制代码

pcl_test

回复 2# flyinnet9
字母数字混合的不妥，如果是非字母数字的也会匹配，修改如下

1. (echo;测试字串|findstr /r /c:"^[A-Z][A-Z]*[0-9][A-Z0-9]*$" /c:"^[0-9][0-9]*[A-Z][A-Z0-9]*$" >nul)&&echo;字母数字混合||echo;非字母数字混合
   

复制代码

pcl_test

判断纯数字

1. set str=123
   
2. set/a 1%str%1 2>nul&&echo;纯数字||echo;含非数字

复制代码

替换法，纯数字、纯字母都适用

1. @echo off&setlocal enabledelayedexpansion
   
2. set str=123#
   
3. for /l %%a in (0 1 9) do set str=!str:%%a=!
   
4. if "%str%" equ "#" (echo;纯数字) else echo;含非数字

复制代码

1. @echo off&setlocal enabledelayedexpansion
   
2. set str=agt#
   
3. for %%a in (a b c d e f g h i j k l n m o p q r s t u v w x y z) do set str=!str:%%a=!
   
4. if "%str%" equ "#" (echo;纯字母) else echo;含非字母
   
5. pause

复制代码

CrLf

回复 4# pcl_test


set /a 解法有很多漏洞
个人偏爱 delims 的解法，通用、高效

pcl_test

回复 5# CrLf

set /a是有漏洞，但在没有特殊字符的情况下，也是特方便的

CrLf

delims 解法示例：

1. @echo off
   
2. 
   
3. set "阿拉伯数字=0123456789"
   
4. set "大写字母=ABCDEFGHIJKLMNOPQRSTUVWXYZ"
   
5. set "小写字母=abcdefghijklmnopqrstuvwxyz"
   
6. 
   
7. for /f "tokens=1*delims=%阿拉伯数字%%大写字母%%小写字母%"eol^= %%a in (
   
8.    "#你的字符串#"
   
9. ) do (
   
10.    if %%b==# (echo 合法) else (echo 不合法)
    
11. )
    
12. 
    
13. pause

复制代码

chouxia

delims 解法示例：
CrLf 发表于 2015-8-6 15:45

    如果需要包含特殊字符呢？

CrLf

回复 8# chouxia


    例子已经很明白了，请自行拓展