BAT脚本实现分形图:龙形曲线

a20150604

1. %1 @goto :initCON
   
2. @echo off & setlocal enabledelayedexpansion
   
3. call :clearVars
   
4. set /a "w=100,h=68, h1=h+0,t=w*h,xc=w/2+1,yc=h/2"
   
5. 
   
6. set "TAB=        " & for /F %%a in ('"prompt $h&for %%b in (1) do rem"')do Set "BS=%%a"
   
7. set /a "buffwid = w, linesWantBackAbove = h + 1 - 1, cntBS = 2 + (buffwid + 7) / 8 * linesWantBackAbove"
   
8. set "BSs=" & for /L %%a in (1 1 !cntBS!) do set "BSs=!BSs!%BS%"
   
9. set "aLineBS=" & for /L %%a in (1 1 !w!) do set "aLineBS=!aLineBS!%BS%"
   
10. 
    
11. mode %w%,%h1%
    
12. 
    
13. for /l %%i in (1 1 !t!) do set "s=!s! "
    
14. set "xv=-1" & set "yv=0 "
    
15. 
    
16. set "pttn=.@.@.@.@.@.@.@."
    
17. REM 画出初始曲线段
    
18. set /a "x=xinit=28, y=yinit=-10, length=1, len2=(length-1) * 2"
    
19. set /a "i=x-xc + (y-yc) * w + 1, L=i-1"
    
20. for /f "tokens=1,2" %%a in ("!L! !i!") do (set s=!s:~0,%%a!!pttn:~0,1!!s:~%%b!)
    
21. for /L %%L in (0 2 !len2!) do (
    
22.     set /a "x += !xv:~%%L,2!, y += !yv:~%%L,2!"
    
23.     set /a "i=x-xc + (y-yc) * w + 1, L=i-1"
    
24.     for /f "tokens=1,2" %%a in ("!L! !i!") do (set s=!s:~0,%%a!!pttn:~0,1!!s:~%%b!)
    
25. )
    
26. set "pttn=!pttn:~1!"
    
27. call :f !xinit! !yinit! !length! s xv yv
    
28. title complete & >nul pause &exit
    
29. :f xtail ytail length s xv yv
    
30. REM setlocal
    
31. 
    
32.     if %3 lss 4096 (
    
33. 
    
34.         set "vxr=" & set "vyr="
    
35. 
    
36.         set /a "x=%1, y=%2, len2=(%3 - 1) * 2, nextLength=%3 * 2"
    
37.         for /L %%L in (0 2 !len2!) do (
    
38.             set /a "xn = - !yv:~%%L,2!, yn = !xv:~%%L,2!"
    
39.             
    
40.             set /a "x += -xn, y += -yn" & rem xn,yn 得到顺时针90旋转 取反的值
    
41.             set /a "i=x-xc + (y-yc) * w + 1, L=i-1, inScr=(x-(-w/2+1)^x-(w/2+1))&(y-(-h/2+1)^y-(h/2+1))"
    
42.             if !inScr! lss 0 (
    
43.                 for /f "tokens=1,2" %%a in ("!L! !i!") do (set s=!s:~0,%%a!!pttn:~0,1!!s:~%%b!)
    
44. 
    
45.                 <nul set /p "=!aLineBS!" & (2>nul echo;%TAB%!BSs!) & <nul set /p "=%BS%"
    
46.                 <nul set /p "=%BS%!s:~0,-1!"
    
47.             )
    
48. 
    
49.             set "xn=  !xn!" & set "yn=  !yn!"
    
50.             set "vxr=!xn:~-2!!vxr!" & set "vyr=!yn:~-2!!vyr!"
    
51.         )
    
52.         set "pttn=!pttn:~1!"
    
53. 
    
54.         set "xv=!vxr!!xv!" & set "yv=!vyr!!yv!"
    
55. 
    
56.         call :f !x! !y! !nextLength! %4 %5 %6
    
57.     )
    
58. 
    
59. exit /b
    
60. 
    
61. :initCON
    
62. @echo off
    
63. for %%a in (  FontSize:00080008      FontFamily:00000030  WindowSize:00C800C8
    
64.               ScreenColors:0000000f  CodePage:000001b5    ScreenBufferSize:00C800C8
    
65. ) do for /f "tokens=1,2 delims=:" %%b in ("%%a") do (
    
66.   >nul reg add HKCU\Console\Dragon_curve /v %%b /t reg_dword /d 0x%%c /f
    
67. )
    
68. start "Dragon_curve" /max "%ComSpec%" /c "%~0" REM & (call :delReg) & exit
    
69. REM end of :initCON
    
70. exit /b
    
71. :clearVars
    
72. set "Path=%SystemRoot%\system32"
    
73. for /f "delims==" %%a in ('set') do (
    
74.   if /i "%%a" neq "Path" set "%%a="
    
75. )
    
76. exit /b
    
77. REM end of :clearVars
    
78. :delReg
    
79. setlocal enabledelayedexpansion
    
80. set "s=!time:~-4,1!"
    
81. :delReg.loop
    
82. set /a "elapse = (1!time:~-4,1! - s) %% 10"
    
83. if %elapse% lss 2 goto :delReg.loop
    
84. >nul reg delete HKCU\Console\Dragon_curve /f
    
85. endlocal
    
86. exit /b
    
87. REM end of :delReg

复制代码

老刘1号

每次看到这种帖子我都忍不住要安利下aa77dd兄的帖子http://www.bathome.net/thread-41913-1-1.html

codegay

回复 2# 老刘1号


    →__→也许是同一个人呢

老刘1号

回复 3# codegay


    还别说，有可能……
在批家搜索框里输入FontSize:      FontFamily:  WindowSize:
或者ScreenColors:  CodePage:    ScreenBufferSize:
总能搜到一些让人惊奇的东东
话说这样的奇诡用法难道没有什么帖子讲解么。。。

codegay

回复 4# 老刘1号


    猜啊

老刘1号

回复 5# codegay


    兄所言甚善

牛虻

回复 1# a20150604


    能不能画出个中国地图？
世界地图更厉害了

老刘1号

回复 7# 牛虻


    这是算法……不是固定复制上去的……

bbaa

回复 4# 老刘1号


    煋，这是修改CMD属性的注册表HKEY_CURRENT_USER\Console
    比如说你可以通过修改注册表给cmd的字体大小 颜色之类的进行魔改

老刘1号

回复 9# bbaa


太好玩    感觉停不下来了……

shenyu

1. @echo off
   
2. echo "膜拜大佬"
   
3. pause

复制代码