[已解决]求BAT代码修改实现条件同时满足

meiszp · 发表于 2019-1-14 20:48:47

本帖最后由 meiszp 于 2019-1-21 20:13 编辑

学习了下面的代码

先使用findstr给每行添加行号，然后分割，提取含有“问题”的行号，赋值给n，第二个循环，还是先添加行号，当满足“”行号=含“问题”行号+5“时，输出此行。

希望修改成m<%%a<n，满足行号大于含“问题”行号，且小于含“问题”行号+5，这样就可以输出含“问题”行及之后5的行。

不知道同时满足两个条件该怎么表达。

@Echo Off&Setlocal Enabledelayedexpansion
For /f "tokens=1* delims=:" %%i in ('Type a.txt^|Findstr /n "问题"') do (
Set m=&Set /a m=%%i
Set n=&Set /a n=%%i+5
Echo %%j>>b.txt
For /f "tokens=1* delims=:" %%a in ('Type a.txt^|Findstr /n "."') do (If %%a==!n! Echo %%b>>b.txt)
)
Pause

复制代码

Batcher · 发表于 2019-1-14 22:14:21

@echo off
setlocal enabledelayedexpansion
(for /f "tokens=1* delims=:" %%i in ('type a.txt^|findstr /n "问题"') do (
set m=%%i
set /a n=%%i+5
echo,%%j
for /f "tokens=1* delims=:" %%a in ('type a.txt^|findstr /n "."') do (
if %%a gtr !m! (
if %%a leq !n! (
echo,%%b
)
)
)
))>b.txt

复制代码

meiszp · 发表于 2019-1-16 20:54:00

谢谢，完美实现。如果要改成m<%%a<n不输出，其他情况输出，即删除m行到n行，该怎么表达呢？谢谢！

Batcher · 发表于 2019-1-16 21:01:30

回复 3# meiszp

@echo off
setlocal enabledelayedexpansion
(for /f "tokens=1* delims=:" %%i in ('type a.txt^|findstr /n "问题"') do (
set m=%%i
set /a n=%%i+5
echo,%%j
for /f "tokens=1* delims=:" %%a in ('type a.txt^|findstr /n "."') do (
if %%a leq !m! (
echo,%%b
) else if %%a gtr !n! (
echo,%%b
)
)
))>b.txt

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]求BAT代码修改实现条件同时满足

评分

评分