原创批处理office 365下载安装向导

li495388759 · 发表于 2021-4-25 13:47:50

翻了下远景论坛，最早分享的版本是2015年10月25日
直到刚刚更新，最新版本是2021年4月25日
目前常用功能已经添加完毕，可以说是正式版了（如果没bug的话）
变量标签名什么的用的可能不是那么严谨，但也不是随意的
部分变量标签解析：
标签：
c                check
cd                菜单
bb                版本
az                安装
zj                组件

变量：
ar       add/remove
dz       地址
dd       download down

大家凑合着看。在写批处理方面我只能算个小学生，不知道有没有更高级的方式，令代码更加简略。
欢迎大家提出意见，谢谢！

该批处理需要配合office部署工具使用，下载完成后请双击运行，解压出的setup.exe要与该批处理同一目录

https://www.microsoft.com/en-us/download/details.aspx?id=49117

复制代码

@echo off
setlocal enabledelayedexpansion
title Office 365下载安装向导
color E
:c
cls
if exist setup.exe goto cd
echo 找不到setup.exe，请检查！
echo.
pause
goto c
:cd
set bit=32
set dz=0
set ar=Add
call :zj
del configuration.xml
cls
echo 请选择任务：
echo.
echo 1、安装 2、卸载 3、下载备用 4、退出
echo.
choice /n /c 1234 /m 请选择：
if errorlevel 4 exit
if errorlevel 3 goto xzb
if errorlevel 2 set ar=Remove&goto az
if errorlevel 1 goto cd2
:cd2
cls
echo 请选择安装组件：
echo.
echo 1、Word、Excel、PowerPoint 2、完整安装 3、自定义组件 4、退出
echo.
choice /n /c 1234 /m 请选择：
if errorlevel 4 exit
if errorlevel 3 goto zj2
if errorlevel 2 goto cd3
if errorlevel 1 set all=0
:cd3
cls
if exist D:\Office\Data echo 检测到D:\Office有离线安装包，可进行离线安装！&echo.
echo 请选择安装方式：
echo.
echo 1、在线安装 2、离线安装 3、退出
echo.
choice /n /c 123 /m 请选择：
if errorlevel 3 exit
if errorlevel 2 goto lx
if errorlevel 1 goto bb
:bb
cls
if %PROCESSOR_ARCHITECTURE%==x86 goto az
echo 当前使用的是64位系统，推荐安装64位的Office！
echo.
echo 请选择安装版本：
echo.
echo 1、64位(推荐) 2、32位 3、退出
echo.
choice /n /c 123 /m 请选择：
if errorlevel 3 exit
if errorlevel 2 goto az
if errorlevel 1 set bit=64
:az
cls
echo 正在执行，请稍候……
call :do
setup.exe /configure configuration.xml
cls
echo 操作完成！
echo.
pause
goto cd
:lx
set dz=1
if exist D:\Office\Data goto bb
cls
echo 请将离线安装包目录“Office”复制到D盘根目录！
echo.
pause
goto lx
:xzb
set dz=1
set dd=0
cls
echo 请选择下载版本：
echo.
echo 1、32位 2、64位 3、32位和64位 4、退出
echo.
choice /n /c 1234 /m 请选择：
if errorlevel 4 exit
if errorlevel 3 set dd=1&goto xz2
if errorlevel 2 goto xz
if errorlevel 1 goto xz2
:xz
set bit=64
:xz2
cls
echo 正在下载%bit%位版本Office，请稍候……
call :do
setup.exe /download configuration.xml
if %dd%==1 if %bit%==32 goto xz
cls
echo 下载完成，离线安装包已保存在D:\Office
echo.
pause
goto cd
:zj
set doc=0
set xls=0
set ppt=0
set mdb=0
set groove=0
set lync=0
set onedrive=0
set onenote=0
set outlook=0
set publisher=0
set teams=0
set all=1
set i=0
goto :eof
:zj2
cls
echo 请选择安装组件：
echo.
echo 1、Word 2、Excel 3、PowerPoint 4、Access
echo.
echo 5、OneDrive for Business 6、Skype for Business 7、OneDrive
echo.
echo 8、OneNote 9、Outlook Q、Publisher W、Teams
echo.
echo E、全选 R、重新选择 T、确认选择 Y、退出
echo.
echo Tips：二次选择可以逐个取消！
echo.
echo 已选择%i%个组件：
if %doc%==1 echo 1、Word
if %xls%==1 echo 2、Excel
if %ppt%==1 echo 3、PowerPoint
if %mdb%==1 echo 4、Access
if %groove%==1 echo 5、OneDrive for Business
if %lync%==1 echo 6、Skype for Business
if %onedrive%==1 echo 7、OneDrive
if %onenote%==1 echo 8、OneNote
if %outlook%==1 echo 9、Outlook
if %publisher%==1 echo Q、Publisher
if %teams%==1 echo W、Teams
echo.
choice /n /c 123456789qwerty /m 请选择：
if errorlevel 15 exit
if errorlevel 14 goto zj4
if errorlevel 13 call :zj&goto zj2
if errorlevel 12 goto cd3
if errorlevel 11 set j=teams&goto zj3
if errorlevel 10 set j=publisher&goto zj3
if errorlevel 9 set j=outlook&goto zj3
if errorlevel 8 set j=onenote&goto zj3
if errorlevel 7 set j=onedrive&goto zj3
if errorlevel 6 set j=lync&goto zj3
if errorlevel 5 set j=groove&goto zj3
if errorlevel 4 set j=mdb&goto zj3
if errorlevel 3 set j=ppt&goto zj3
if errorlevel 2 set j=xls&goto zj3
if errorlevel 1 set j=doc
:zj3
if !%j%!==0 (
set %j%=1
set /a i+=1) else (
set %j%=0
set /a i-=1)
goto zj2
:zj4
if %i% gtr 0 set all=2&goto cd3
goto zj2
:do
>configuration.xml (
echo ^<Configuration^>^<%ar%
if %dz%==1 echo SourcePath="D:"
if %ar%==Add echo OfficeClientEdition="%bit%" Channel="Current"
echo ^>^<Product ID="O365ProPlusRetail"^>^<Language ID="zh-cn"/^>
if %all%==2 (
if %doc%==0 echo ^<ExcludeApp ID="Word"/^>
if %xls%==0 echo ^<ExcludeApp ID="Excel"/^>
if %ppt%==0 echo ^<ExcludeApp ID="PowerPoint"/^>)
if %all% neq 1 (
if %mdb%==0 echo ^<ExcludeApp ID="Access"/^>
if %groove%==0 echo ^<ExcludeApp ID="Groove"/^>
if %lync%==0 echo ^<ExcludeApp ID="Lync"/^>
if %onedrive%==0 echo ^<ExcludeApp ID="OneDrive"/^>
if %onenote%==0 echo ^<ExcludeApp ID="OneNote"/^>
if %outlook%==0 echo ^<ExcludeApp ID="Outlook"/^>
if %publisher%==0 echo ^<ExcludeApp ID="Publisher"/^>
if %teams%==0 echo ^<ExcludeApp ID="Teams"/^>)
echo ^</Product^>^</%ar%^>^</Configuration^>)

复制代码

1152 · 发表于 2021-4-25 19:40:16

本帖最后由 1152 于 2021-4-25 19:45 编辑

C:\ _

C:\Windows\system32\cmd.exe

- □ ×

不好用
你可以试试需要第三方的，比如：
变颜色
字体加粗
下划线
~~删除线~~
改变字体样子

Batcher · 发表于 2021-4-25 22:57:57

回复 1# li495388759

196~208建议改成这个格式：

if %all%==2 (
if %doc%==0 echo ^<ExcludeApp ID="Word"/^>
if %xls%==0 echo ^<ExcludeApp ID="Excel"/^>
if %ppt%==0 echo ^<ExcludeApp ID="PowerPoint"/^>
) else if %all% neq 1 (
if %mdb%==0 echo ^<ExcludeApp ID="Access"/^>
if %groove%==0 echo ^<ExcludeApp ID="Groove"/^>
if %lync%==0 echo ^<ExcludeApp ID="Lync"/^>
if %onedrive%==0 echo ^<ExcludeApp ID="OneDrive"/^>
if %onenote%==0 echo ^<ExcludeApp ID="OneNote"/^>
if %outlook%==0 echo ^<ExcludeApp ID="Outlook"/^>
if %publisher%==0 echo ^<ExcludeApp ID="Publisher"/^>
if %teams%==0 echo ^<ExcludeApp ID="Teams"/^>
)

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[系统相关] 原创批处理office 365下载安装向导