[已解决]批处理如何批量赋予IIS程序池独立用户?

692568516

请教下以下两个脚本如何拼成一个，需要吧生成密码的脚本放到for 循环里，随机生成密码并赋予用户和程序池

@echo off & setlocal enabledelayedexpansion

set ws=14
set str=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ
for /l %%a in (1,1,%ws%) do (
    set /a num=!random!%%62
    call set zf=%%str:~!num!,1%%
    set pw=!pw!!zf!
)


set targe=''
for /f   %%i in (user.txt)  do (
set target=%%i
net user !target! !pw! /add
net user !target! /FULLNAME:!target!  /COMMENT:"由bat创建"
net localgroup users !target! admintemp /delete
C:\Windows\System32\inetsrv\appcmd.exe add apppool /apppool.name:!target!
C:\Windows\System32\inetsrv\appcmd.exe set config /section:applicationPools /[name='!target!'].processModel.identityType:SpecificUser /[name='!target!'].processModel.userName:!target! /[name='!target!'].processModel.password:!pw!
)
pause

flashercs

1. @echo off & setlocal enabledelayedexpansion
   
2. 
   
3. set targe=''
   
4. for /f   %%i in (user.txt)  do (
   
5. set target=%%i
   
6. call :getpw
   
7. net user !target! !pw! /add
   
8. net user !target! /FULLNAME:!target!  /COMMENT:"由bat创建"
   
9. net localgroup users !target! admintemp /delete
   
10. C:\Windows\System32\inetsrv\appcmd.exe add apppool /apppool.name:!target!
    
11. C:\Windows\System32\inetsrv\appcmd.exe set config /section:applicationPools /[name='!target!'].processModel.identityType:SpecificUser /[name='!target!'].processModel.userName:!target! /[name='!target!'].processModel.password:!pw!
    
12. )
    
13. pause
    
14. exit /b
    
15. 
    
16. :getpw
    
17. set pw=
    
18. set ws=14
    
19. set str=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ
    
20. for /l %%a in (1,1,%ws%) do (
    
21.     set /a num=!random!%%62
    
22.     call set zf=%%str:~!num!,1%%
    
23.     set pw=!pw!!zf!
    
24. )
    
25. exit /b

复制代码

692568516

谢谢谢谢大佬