[已解决]批处理如何将两个txt文本内容的每一行合并在一起

IGOfilm · 发表于 2022-1-15 14:36:45

本帖最后由 IGOfilm 于 2022-1-15 22:08 编辑

比如我有a文本
aaaaa
bbbbb
ccccc
现在我想把b文本
11111
22222
33333
的每行追加到a文本后面去，变成
aaaaa11111
bbbbb22222
ccccc33333

求大佬指教

went · 发表于 2022-1-15 15:34:14

@echo off & cd /d "%~dp0"
set "f1=a.txt"
set "f2=b.txt"
(
for /f "usebackq delims=" %%i in ("%f1%") do (
set /p "s="
call echo %%i%%s%%
)
)<"%f2%">"%f1%_new"
move /y "%f1%_new" "%f1%"
pause&exit

复制代码

aloha20200628 · 发表于 2022-1-15 15:53:18

@echo off & setlocal EnableDelayedExpansion
findstr /n .* a.txt > a.b
findstr /n .* b.txt >> a.b
set/a n=0
(for /f "delims=" %%s in ('sort a.b') do (
set "z=%%s" & set "z=!z:*:=!"
if !n! equ 1 (set/a n=0 & echo,!ls!!z!) else (set/a n+=1 & set ls=!z!)
))>ab.txt
del/q a.b

aloha20200628 · 发表于 2022-1-15 16:13:54

再精简一步：
@echo off & setlocal EnableDelayedExpansion
findstr /n .* a.txt > a.b
findstr /n .* b.txt >> a.b
set/a n=0
(for /f "tokens=1* delims=:" %%1 in ('sort a.b') do (
if !n! equ 1 (set/a n=0 & echo,!ls!%%2) else (set/a n+=1 & set ls=%%2)
))>ab.txt
del/q a.b

IGOfilm · 发表于 2022-1-15 22:07:42

回复 2# went

感谢

IGOfilm · 发表于 2022-1-15 22:10:42

回复 4# aloha20200628

感谢

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理如何将两个txt文本内容的每一行合并在一起

评分