[分享]批处理给不同类型文件分别添加序号

Batcher

【问题描述】

我只想给这些文件后面添加log001—log999的排序但又不打乱文件的位置
不会超过1000个文件，因为里面有三种文件，一种文件数量都是几百个

Batcher

【解决方案】

test_1.bat 请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

1. @echo off
   
2. cd /d "%~dp0"
   
3. setlocal enabledelayedexpansion
   
4. for %%a in (avi blf mf4) do (
   
5.     call :ChangeName %%a
   
6. )
   
7. pause
   
8. goto :eof
   
9. 
   
10. :ChangeName
    
11. for /f "delims=" %%i in ('dir /b /a-d *.%1 ^| find /v /c ""') do (
    
12.     set "FileCount=%%i"
    
13. )
    
14. set "NumLast=1000!FileCount!"
    
15. for /f "delims=" %%i in ('dir /b /a-d /o-n *.%1') do (
    
16.     set "NewName=%%~ni_log!NumLast:~-3!%%~xi"
    
17.     ren "%%i" "!NewName!"
    
18.     set /a "NumLast-=1"
    
19. )

复制代码

Batcher

【问题描述】

百分之九十的文件数量都是配套的三个
其余的有一个或者俩个
数量不确定



【解决方案】test_2.bat 请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

1. @echo off
   
2. cd /d "%~dp0"
   
3. setlocal enabledelayedexpansion
   
4. set "SeqNum=10001"
   
5. for /f "delims=" %%i in ('dir /b /a-d *.avi *.blf *.mf4') do (
   
6.     set "_%%~ni=%%~ni"
   
7. )
   
8. for /f "tokens=1* delims==" %%i in ('set _') do (
   
9.     set "NewName=%%j_log!SeqNum:~-3!"
   
10.     if exist "%%j.avi" (
    
11.         ren "%%j.avi" "!NewName!.avi"
    
12.     )
    
13.     if exist "%%j.blf" (
    
14.         ren "%%j.blf" "!NewName!.blf"
    
15.     )
    
16.     if exist "%%j.mf4" (
    
17.         ren "%%j.mf4" "!NewName!.mf4"
    
18.     )
    
19.     set /a "SeqNum+=1"
    
20. )
    
21. endlocal
    

复制代码

Batcher

【问题描述】

部分文件名结尾有个多余的下划线



【解决方案】

1. @echo off
   
2. cd /d "%~dp0"
   
3. setlocal enabledelayedexpansion
   
4. set "SeqNum=10001"
   
5. for /f "delims=" %%i in ('dir /b /a-d *.avi *.blf *.mf4') do (
   
6.     set "OldName=%%~ni"
   
7.     if "!OldName:~-1!" equ "_" (
   
8.         set "_!OldName:~0,-1!=!OldName:~0,-1!"
   
9.     ) else (
   
10.         set "_!OldName!=!OldName!"
    
11.     )
    
12. )
    
13. for /f "tokens=1* delims==" %%i in ('set _') do (
    
14.     set "NewName=%%j_log!SeqNum:~-3!"
    
15.     if exist "%%j.avi" (
    
16.         ren "%%j.avi" "!NewName!.avi"
    
17.     ) else if exist "%%j_.avi" (
    
18.         ren "%%j_.avi" "!NewName!.avi"
    
19.     )
    
20.     if exist "%%j.blf" (
    
21.         ren "%%j.blf" "!NewName!.blf"
    
22.     ) else if exist "%%j_.blf" (
    
23.         ren "%%j_.blf" "!NewName!.blf"
    
24.     )
    
25.     if exist "%%j.mf4" (
    
26.         ren "%%j.mf4" "!NewName!.mf4"
    
27.     ) else if exist "%%j_.mf4" (
    
28.         ren "%%j_.mf4" "!NewName!.mf4"
    
29.     )
    
30.     set /a "SeqNum+=1"
    
31. )
    
32. endlocal
    

复制代码

yyz219

【问题描述】

部分文件名结尾有个多余的下划线



【解决方案】
Batcher 发表于 2022-12-13 15:52

    感谢分享