批处理如何删除文件名中某字符前的内容？

cabat

有比较多文件要进行重命名：
例如:
原文件：
1235_1.jpg
165_2.jpg
1 4.44_3.jpg（删除部分可能含有"空格"或"."）
12_665_4.jpg（要求删除第一个_前内容即可，因为可以通过多次处理得到4.jpg，但如果能一步到位更好）
......
经过一次处理后要求修改为：（包括子文件夹内文件）
1.jpg
2.jpg
3.jpg
665_4.jpg/4.jpg
.....
之前找了一些代码，有用但效果不好，例如有些对文件名含空格文件无效，有些对子文件无效，所以求助各位大神有没有啥好的解决办法。

bat或cmd /K命令均可。

77七

1. @echo off
   
2. rem 最多支持文件名含10个"_"
   
3. for /f "delims=" %%i in ('dir /b /s /a-d *.jpg') do (
   
4.         set "newName=%%~nxi"
   
5.         set "oldName=%%~fi"
   
6.         setlocal enabledelayedexpansion
   
7.         for /l %%l in (1,1,10) do (
   
8.                 set "newName=!newName:*_=!"
   
9.         )
   
10.         echo ren "!oldName!" "!newName!"
    
11.         ren "!oldName!" "!newName!"
    
12.         endlocal
    
13. )
    
14. pause
    

复制代码

jyswjjgdwtdtj

set shell=createobject("shell.application")
set folder=shell. namespace(replace(wscript.scriptfullname,wscript.scriptname,""))
set filecollection=folder. items(). filter(&h40)
for each file in filecollection
n=file. name
file. name=mid(n,instrrev(n,"_"))
next

terse

文件名格式不是很特殊的话 也可以这样简单点处理

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. for /f "delims=" %%i in ('dir /b /s /a-d *_*.jpg') do (
   
4.         set "FileName=%%~nxi"
   
5.         for %%j in ("!FileName:_=\!") do echo ren "%%i"   "%%~nxj"
   
6. )
   
7. pause

复制代码

77七

1. @echo off
   
2. rem 预期保留的文件名部分不含空格键、逗号、分号、等号、叹号
   
3. for /f "delims=" %%i in ('dir /b /s /a-d *.jpg') do (
   
4.         set "newName=%%~nxi"
   
5.         set "oldName=%%~fi"
   
6.         setlocal enabledelayedexpansion
   
7.         set "newName=!newName:_==!"
   
8.         for %%a in (!newName!) do (
   
9.                 set "newName=%%a"
   
10.         )
    
11.         echo ren "!oldName!" "!newName!"
    
12.         ren "!oldName!" "!newName!"
    
13.         endlocal
    
14. )
    
15. pause

复制代码