[分享]批处理给照片(包括子文件夹)添加随机图片水印

Batcher

【问题描述】

https://mp.weixin.qq.com/s/mSfzh4YhBYGjiRpuOn6L7A
使用这篇文章里面的代码，在照片目录下的多张图片可以直接添加上。
但有很多文件夹，不同的文件夹里的图片都要改，怎么写？

Batcher

【解决方案】

RandomPictureWatermark-2.bat

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. REM 1、下载并安装 ImageMagick 这个命令行工具
   
4. REM https://imagemagick.org/script/download.php#windows
   
5. REM 2、根据自己电脑实际安装路径设置以下临时环境变量
   
6. set "path=C:\Program Files\ImageMagick;%path%"
   
7. 
   
8. REM 设置待处理的照片所在的目录
   
9. set "FolderOld=C:\Test\照片"
   
10. REM 设置水印图片所在的目录
    
11. set "FolderWM=C:\Test\水印"
    
12. REM 设置添加水印之后的照片所在的目录
    
13. set "FolderNew=C:\Test\合成"
    
14. 
    
15. set "IndexWM=0"
    
16. for /f "delims=" %%i in ('dir /a-d /b /s "%FolderWM%\*.png"') do (
    
17.     set /a IndexWM+=1
    
18.     set "File!IndexWM!=%%i"
    
19. )
    
20. 
    
21. set "IndexGD=0"
    
22. set "ListDirect=NorthWest North NorthEast West Center East SouthWest South SouthEast"
    
23. for %%i in (%ListDirect%) do (
    
24.     set /a IndexGD+=1
    
25.     set "Position!IndexGD!=%%i"
    
26. )
    
27. 
    
28. REM 假设待处理的照片有jpg、png两种格式，如有需要可以继续添加
    
29. set "ListExt=jpg png"
    
30. set "PictureType="
    
31. for %%i in (%ListExt%) do (
    
32.     set "PictureType=!PictureType! *.%%i"
    
33. )
    
34. 
    
35. cd /d "%FolderOld%"
    
36. for /f "delims=" %%i in ('dir /b /a-d !PictureType!') do (
    
37.     echo %%i
    
38.     set /a SelectWM=!random!%%!IndexWM!+1
    
39.     ping -n 2 127.0.0.1 >nul
    
40.     set /a SelectGD=!random!%%!IndexGD!+1
    
41.     call magick.exe composite -gravity %%Position!SelectGD!%% "%%File!SelectWM!%%" "%%i" "%FolderNew%\%%i"
    
42. )
    
43. for /f "delims=" %%a in ('dir /b /ad') do (
    
44.     echo --- %%a
    
45.     if not exist "%FolderNew%\%%a" (
    
46.         md "%FolderNew%\%%a"
    
47.     )
    
48.     pushd "%%a"
    
49.     for /f "delims=" %%i in ('dir /b /a-d !PictureType!') do (
    
50.         echo %%i
    
51.         set /a SelectWM=!random!%%!IndexWM!+1
    
52.         ping -n 2 127.0.0.1 >nul
    
53.         set /a SelectGD=!random!%%!IndexGD!+1
    
54.         call magick.exe composite -gravity %%Position!SelectGD!%% "%%File!SelectWM!%%" "%%i" "%FolderNew%\%%a\%%i"
    
55.     )
    
56.     popd
    
57. )
    
58. endlocal
    

复制代码