[已解决]批处理如何使用findstr作为if条件？

meiszp

需要在多个文件中查找error，如果找到了，列出文件名，输出“包含”，如果找不到，输出“不包含”

::/m 输出文件名
findstr  /m "error" 123.txt 456.txt 789.txt

if 【findstr 找到了】   (
        echo "包含"
）else (
       echo "不包含"
)

ShowCode

回复 1# meiszp


1.bat

1. @echo off
   
2. for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
   
3.     findstr "error" "%%i" >nul 2>&1
   
4.     if errorlevel 1 (
   
5.         echo "%%i" 不包含
   
6.     ) else (
   
7.         echo "%%i" 包含
   
8.     )
   
9. )
   
10. pause

复制代码

ShowCode

回复 1# meiszp


2.bat

1. @echo off
   
2. for %%i in (*.txt) do (
   
3.     findstr "error" "%%i" >nul 2>&1
   
4.     if errorlevel 1 (
   
5.         echo "%%i" 不包含
   
6.     ) else (
   
7.         echo "%%i" 包含
   
8.     )
   
9. )
   
10. pause

复制代码

ShowCode

回复 1# meiszp


3.bat

1. @echo off
   
2. findstr /m "error" *.txt
   
3. if errorlevel 1 (
   
4.     echo 不包含
   
5. ) else (
   
6.     echo 包含
   
7. )
   
8. pause

复制代码

aloha20200628

在批处理脚本中用系统变量 errorlevel 判断时，须注意‘预处理’对复合语块（典型如for或if）内的系统变量会预先赋值的影响，errorlevel 也是系统变量，亦在‘法网’之中，如下式中的 errorlevel 会被预先赋值=0，即运行时会无视以前 findstr 的真实执行结果

1. 
   
2. for %%F in (*.txt) do (
   
3.         findstr /i "abc" "%%F">nul
   
4.         if errorlevel 0 (echo,有》%%F) else (echo,无》%%F)
   
5. )
   

复制代码

所以，还是老办法，采用延迟变量解决预处理问题，如下式

1. 
   
2. setlocal enabledelayedexpansion
   
3. for %%F in (*.txt) do (
   
4.         findstr /i "abc" "%%F">nul
   
5.         if !errorlevel! equ 0 (echo,有》%%F) else (echo,无》%%F)
   
6. )
   

复制代码

就是不用延迟变量，也有其道，如下式

1. 
   
2. for %%F in (*.txt) do (findstr /i "abc" "%%F">nul&&echo,有》%%F||echo,无》%%F)
   

复制代码

以上关于 ‘errorlevel 也是系统变量’ 的更严谨说法及其更多用法可详见另帖》http://www.bathome.net/thread-69472-1-1.html 18楼

77七

有关if errorlevel 用法，我记得站长讲过一次，大概意思是这样的

1. @echo off
   
2. for /l %%l in (0,1,5) do (
   
3.         call :1 %%l
   
4.         if errorlevel 3 (
   
5.                 echo [errorlevel=%%l  ^>=3]
   
6.         ) else (
   
7.                 echo [errorlevel=%%l  ^<3]
   
8.         )
   
9. )
   
10. pause
    
11. exit
    
12. 
    
13. :1
    
14. exit /b %1

复制代码

aloha20200628

回复 6# 77七

阁下跑题了

buyiyang

回复 5# aloha20200628


    if errorlevel 0的意思是判断变量errorlevel的值是否大于或等于0，
“预处理”只扩展%var%形式引用的变量，errorlevel的取值和比较是执行时进行的，类似set /a error=errorlevel