提取加密的7z压缩文件中指定扩展名的文件到指定目录

小白龙

我有一个加密的7z压缩文件, 例如下面的文件路径, 密码是文件名的前6位,
我想把压缩文件中:
1.扩展名为txt的文件(该类型的文件只有一个)提取到桌面, 文件名改为a.txt
2.扩展名为doc的文件(该类型的文件只有一个)提取到桌面, 文件名改为b.doc

C:\Users\Administrator\Desktop\ab.cdefg_25.05.03.7z

小白龙

这个问题让ai解答, 完全不知道在干什么

aloha20200628

回复 1# 小白龙

1. 
   
2. @echo off &set "_7zF=C:\Users\Administrator\Desktop\ab.cdefg_25.05.03.7z"
   
3. md "#$" &pushd "#$" 2>nul &for %%F in ("%_7zF%") do set "nF=%%~nF"
   
4. 7za e "%_7zF%" *.txt *.doc -p"%nF:~0,6%" -r -y
   
5. for %%F in (*.txt *.doc) do if /i "%%~xF"==".txt" (move /y "%%F" "%userprofile%\desktop\a.txt") else (move /y "%%F" "%userprofile%\desktop\b.doc")
   
6. popd &rd /s/q "#$" &pause&exit/b
   

复制代码

小白龙

回复 3# aloha20200628

如果不解压到临时文件夹, 直接不能定位所需的文件并提取吗?

aloha20200628

回复 4# 小白龙

用临时目录以便隔离当前目录中已有的同名文件，不用亦可但可能会覆盖当前目录中的同名文件...
假设当前目录中没有同名文件可用以下代码

1. 
   
2. @echo off &set "_7zF=C:\Users\Administrator\Desktop\ab.cdefg_25.05.03.7z"
   
3. for %%F in ("%_7zF%") do set "nF=%%~nF"
   
4. 7za e "%_7zF%" *.txt *.doc -p"%nF:~0,6%" -r -y
   
5. for /f "tokens=6 delims= " %%F in ('7za l "%_7zF%"^|findstr /ir "\.txt$ \.doc$" ') do if /i "%%~xF"==".txt" (move /y "%%F" "%userprofile%\desktop\a.txt") else (move /y "%%F" "%userprofile%\desktop\b.doc")
   
6. pause&exit/b
   

复制代码

小白龙

回复 5# aloha20200628


    多谢大佬, 我的意思是下面这个命令在提取时, 直接用相同的文件名提取到桌面上, 这可能吗?
例如包内各有一个txt文件和doc文件, 把这两个文件用相同的文件名, 例如xx,提取到桌面上, 这样桌面上就有了xx.txt和xx.doc

7za e "%_7zF%" *.txt *.doc -p"%nF:~0,6%" -r -y

aloha20200628

回复 6# 小白龙

1. 
   
2. @echo off &set "_7zF=C:\Users\Administrator\Desktop\ab.cdefg_25.05.03.7z"
   
3. for %%F in ("%_7zF%") do set "nF=%%~nF"
   
4. 7za e "%_7zF%" *.txt *.doc -p"%nF:~0,6%" -r -y -o"%userprofile%\desktop"
   
5. pause&exit/b
   

复制代码

小白龙

回复 7# aloha20200628


    解压到的文件名要是xx

aloha20200628

回复 8# 小白龙

这一版总算到家了吧 ...

1. 
   
2. @echo off &set "_7zF=C:\Users\Administrator\Desktop\ab.cdefg_25.05.03.7z"
   
3. for %%F in ("%_7zF%") do set "nF=%%~nF"
   
4. 7za e "%_7zF%" *.txt *.doc -p"%nF:~0,6%" -r -y -o"%userprofile%\desktop">nul
   
5. for /f "tokens=6 delims= " %%F in (
   
6.   '7za l "%_7zF%"^|findstr /ir "\.txt$ \.doc$" ') do (ren "%userprofile%\desktop\%%~nxF" "xx%%~xF")
   
7. pause&exit/b
   

复制代码

aloha20200628

回复 8# 小白龙

用 7za 的参数 -so （解压数据流直给标准管道）可助楼主的最终要求 ‘直线’ 解压更名到桌面，不必追加外部更名的操作了...

1. 
   
2. @echo off &set "_7zF=C:\Users\Administrator\Desktop\ab.cdefg_25.05.03.7z"
   
3. for %%F in ("%_7zF%") do set "nF=%%~nF"
   
4. for /f "tokens=6 delims= " %%F in (
   
5.   '7za l "%_7zF%"^|findstr /ir "\.txt$ \.doc$" '
   
6. ) do 7za e "%_7zF%" "%%F" -p"%nF:~0,6%" -y -so>"%userprofile%\desktop\xx%%~xF"
   
7. pause&exit/b
   

复制代码