隐藏盘符.BAT（注册表障眼法）....WIN10可用版！

jiavip

如题：隐藏盘符.BAT（注册表障眼法）....WIN10可用版！
逛无忧，，看到一帖 ，，隐藏盘符.BAT（注册表障眼法），，，http://wuyou.net/forum.php?mod=viewthread&tid=449148&extra=page%3D1
后来试用了一下，发现WIN10 系统下并不能正藏隐藏，，也不知道那楼主用的是什么系统，，，

后来鄙人无聊就顺着他那思路修改了他的代码，并重构了计算方式，，，，
这个帖子发出来的是全新修改 WIN10 可用版的，，，，扔代码。

1. @Echo off
   
2. Set 字母列表=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
   
3. For %%a in (%字母列表%) do ( dir %%a: >nul 2>nul &&Call Set "盘符列表=%%盘符列表%% %%a")
   
4. If "%盘符列表:~0,1%"==" " Set 盘符列表=%盘符列表:~1%
   
5. :隐藏盘符输入
   
6. Set 盘符输入=
   
7. Set/p 盘符输入=输入【%盘符列表%】，输入【DEL】清除所有隐藏:
   
8. Cls
   
9. If /i "%盘符输入%"=="del" Reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoDrives"  /f & cls &Echo.已清除所有隐藏盘符，按任意键重启Explorer进程！& Pause > Nul & Tskill Explorer & Start Explorer ::{20D04FE0-3AEA-1069-A2D8-08002B30309D} & Exit
   
10. Set 盘符输入=%盘符输入: =%
    
11. Set 输入检测=%盘符输入%
    
12. :隐藏盘符检测
    
13. Echo.%输入检测:~0,1%|findstr /i "%盘符列表%" >nul 2>nul ||Echo.【%输入检测:~0,1%】不在磁盘列表中，请重新输入 ！&& Goto,隐藏盘符输入
    
14. Set 输入检测=%输入检测:~1%
    
15. If Not "%输入检测%"=="" Goto,隐藏盘符检测
    
16. For %%b in (%字母列表%) do ( Call Set "_%%b=")
    
17. :拆分盘符
    
18. If Not Defined _%盘符输入:~,1% Set "_%盘符输入:~,1%=1"
    
19. Set "盘符输入=%盘符输入:~1%"
    
20. If Defined 盘符输入 Goto,拆分盘符
    
21. For %%c in (%字母列表%) do (
    
22. If Not Defined Nums (Set Nums=1) else (Call Set/a Nums*=2)
    
23. If Defined _%%c (Set/a 输入个数+=1
    
24. Call Set "盘符输入=%%盘符输入%%%%c,"
    
25. Call Set/a Num=Num+Nums))
    
26. :十六进制换算
    
27. Set /a Hex=Num %% 16
    
28. Set /a Num=Num / 16
    
29. If %Hex% equ 10 Set Hex=A
    
30. If %Hex% equ 11 Set Hex=B
    
31. If %Hex% equ 12 Set Hex=C
    
32. If %Hex% equ 13 Set Hex=D
    
33. If %Hex% equ 14 Set Hex=E
    
34. If %Hex% equ 15 Set Hex=F
    
35. Call Set Hexs=%%Hex%%%%Hexs%%
    
36. If %Num% Gtr 0 Goto,:十六进制换算
    
37. If "%盘符输入:~-1,1%"=="," Set 盘符输入=%盘符输入:~0,-1%
    
38. Echo.
    
39. Echo 要隐藏的磁盘有【%盘符输入%】共[%输入个数%]个盘!
    
40. Echo.&Echo.注册表代码：&Echo.Reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoDrives" /t REG_DWORD /d "0x%Hexs%" /f
    
41. Echo.&Echo.按任意键，隐藏磁盘【%盘符输入%】，并重启Explorer进程。
    
42. Pause > Nul
    
43. Reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoDrives" /t REG_DWORD /d "0x%Hexs%" /f
    
44. Tskill Explorer & Start Explorer ::{20D04FE0-3AEA-1069-A2D8-08002B30309D}
    
45. Pause > Nul & Exit
    

复制代码

代码存 ANSI 编码，隐藏盘符.BAT
------------------------------
我这个写的版本，针对现有盘符才可选择，，，否则不可取。
而且把很多没必要多余的标签取消了，，，
代码变量&标签 尽可能写中文，取代注释，方便新手学习借鉴。
也取消了 延迟开关，，（不知道为什么我写代码很不喜欢开启延迟变量，尽量Call 调用（个人怪癖）），，，

欢迎大家对比测试各个系统下的运行结果，回来讨论，，，古董本，没装虚拟机，，，
也欢迎各路大神 对比一下我与无忧论坛发布的那代码的区别与不同。

---------清除隐藏盘符---保命代码。牢记

1. Reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoDrives"  /f

复制代码

--------送一条：无责隐藏所有盘符 A-Z-注册表（只在WIN10测试通过）--

1. Reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoDrives" /t REG_DWORD /d "0x3FFFFFF" /f

复制代码

77七

https://bbs.bathome.net/viewthread.php?tid=1863



以前我写的
http://www.bathome.net/redirect. ... 9544&pid=283057