[ 新手练习题 5 ] 文件与目录相互替换

wxcute

[ 新手练习题 5 ] 文件与目录相互替换
检测批处理所在目录是否存在 LOGFILE 文件/目录。
如果 LOGFILE 是文件，则用同名目录替换它；反之则用同名文件替换名为 LOGFILE 的目录。
如果都不存在则构造一个 0 字节的名为 LOGFILE 的文件。
　　注意：名字没有扩展名！

目的：了解文件/目录的存在特性，学会生成文件与创建目录。

要求：文件目录名称可自行修改。多次运行都要有效。
　　　方法不限。

评分：代码可读性 1 分；
　　　首个新方法 5 分，第二个 4 分，依次类推，最少 2 分；
　　　一人可多种方法，新方法追加 2 分，已经出现过的方法追加 1 分。

keen

1. @echo off
   
2. set name=logfile
   
3. if exist %name% (
   
4.    cd %name% 2>nul&&(cd..&rd %name%&cd.>%name%)||(del %name%&md %name%)
   
5. ) else (cd.>%name%)

复制代码

wangshuping42

1. 
   
2. @echo off
   
3. if not exist logfile (cd.>logfile&pause&exit)
   
4. 
   
5. :again
   
6. cd logfile 2>nul
   
7. if errorlevel 1 (goto 1)
   
8. if errorlevel 0 (goto 0)
   
9. 
   
10. :1
    
11. del logfile
    
12. md logfile
    
13. pause>nul&goto again
    
14. 
    
15. :0
    
16. cd ..\
    
17. rd /s /q logfile
    
18. cd.>logfile
    
19. pause>nul&goto again
    
20. 
    

复制代码

tireless

1. @echo off
   
2. set name="logfile"
   
3. if not exist %name% exit/b>%name%
   
4. if exist %name%\ rd/s/q %name% & exit/b>%name%
   
5. del/a/f %name% & md %name%

复制代码

1. @echo off
   
2. set name="logfile"
   
3. dir/a-d/b %name%>nul 2>nul&&del/a/f %name%&&md %name%||(rd/s/q %name% 2>nul&cd.>%name%)

复制代码

inittab

1. @echo off
   
2. set name="logfile"
   
3. if exist %name% (rd /s/q %name% 2>nul&&cd.>%name%||del /a/f %name% 2>nul&&md %name%) else cd.>%name%

复制代码

lovelymorning

(type LOGFILE&&(del /q LOGFILE&md LOGFILE)||(rd /s /q LOGFILE&cd>LOGFILE))>nul 2>nul

if exist LOGFILE\ (rd /s /q LOGFILE&cd>LOGFILE) else (if exist LOGFILE (del /q LOGFILE&md LOGFILE) else (cd>LOGFILE))

keen

请学会使用code将代码括起来，这样既让你的代码美观，更易他人复制你的代码，谢谢！
Q：如何用code将代码括起来？
A：http://www.bathome.net/viewthread.php?tid=404&highlight=code

lovelymorning

为何不成功呢？

怎么我测试的，却是可以？

1. (type LOGFILE&&(del /q LOGFILE&md LOGFILE)||(rd /s /q LOGFILE&cd>LOGFILE))>nul 2>nul

复制代码

1. if exist LOGFILE\ (rd /s /q LOGFILE&cd>LOGFILE) else (if exist LOGFILE (del /q LOGFILE&md LOGFILE) else (cd>LOGFILE))

复制代码

keen

楼主的题目要求生成0字节的文件。
你的代码只要把cd>LOGFILE
改成cd.>LOGFILE

liuks001

不晓得还有管理员在看这个帖子不！我是这几天才知道这个网站的！ 也是新手 有些地方不太理解
比如：2>nul   是什么意思哦   我在几个批处理里面都看到 有 1>nul 2>nul 能解释一哈不！

Batcher

批处理中的重定向符号以及句柄的使用方法和讲解
http://bbs.bathome.net/thread-3296-1-1.html

liuks001

if exist %name% (
   cd %name% 2>nul&&(cd..&rd %name%&cd.>%name%)||(del %name%&md %name%)
) else (cd.>%name%)
   管理员能帮我解释一下这句话的意思吗？

风行者

1. @echo off
   
2. if exist logfile (if exist logfile\nul (
   
3. rd /s /q logfile & cd. >logfile) else (
   
4. del logfile & md logfile)) else cd. >logfile

复制代码

wxcute

请不要在回复中提不相关的问题，有什么问题请到相应版块发表新主题。谢谢合作。

pumahxh

@echo off&setlocal EnableDelayedExpansion
dir /a-d logfile >nul 2>nul
if %errorlevel%==0 (
   del logfile
   md logfile
   ) else (
          dir /ad logfile >nul 2>nul
          if !errorlevel!==0 (
             rd/q logfile
             cd.>logfile
             ) else (
                    cd.>logfile
                    )
           )
pause
利用了dir里attrib的目录属性

找到另一种方法：
(md logfile || del /q logfile&md logfile || rd /q logfile & cd.>logfile)>nul 2>nul

[ 本帖最后由 pumahxh 于 2009-11-11 11:12 编辑 ]