【已解决】统计每个TXT文件中【<img】出现的次数，将其加入到每个文件名中。

qixiaobin0715

由于UTF-8编码的影响，部分双引号也会出现乱码，为保险起见，在15楼代码7、8行之间插入一行   set "str=!str:"=!"    最好。

qixiaobin0715

修改和简化后的完整代码：

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. for /r %%i in ("*.txt") do (
   
4.     set n=0
   
5.     for /f "delims=" %%a in ('type "%%i"') do (
   
6.         set "str=%%a"
   
7.         set "str=!str:img alt= <img alt!"
   
8.         set "str=!str:"=!"
   
9.         for %%k in (!str!) do (
   
10.             if "%%k"=="<img" set /a n+=1
    
11.         )
    
12.     )
    
13.     ren "%%i" "%%~ni（共!n!张图片）%%~xi"
    
14. )
    
15. pause&exit
    

复制代码

WHY

回复 14# 三十年前


    是 sed.exe 不是 set，脚本上面一行有下载链接。

WHY

纯批的话，改一下代码页可以避免乱码问题。

1. @echo off & setlocal enabledelayedexpansion
   
2. chcp 65001
   
3. for /f "delims=" %%i in ('dir /b /a-d /s *.txt') do (
   
4.     set n=0
   
5.     for /f "delims=" %%j in ('type "%%i"') do (
   
6.         set "s=%%j"
   
7.         set "s=!s:"=!"
   
8.         for %%k in ("!s:<img=" "!") do set /a n+=1
   
9.         set /a n-=1
   
10.     )
    
11.     echo ren "%%i" "%%~ni（!n!）%%~xi"
    
12. )
    
13. pause

复制代码

保存为 test.bat，编码格式选 utf-8 without BOM。

Active code page: 65001
ren "E:\Test\需求.txt" "需求（2）.txt"
ren "E:\Test\测试文件\怀素《自叙帖》草书书法图片.txt" "怀素《自叙帖》草书书法图片（45）.txt"
ren "E:\Test\测试文件\蔡京《大观御笔记》行书欣赏.txt" "蔡京《大观御笔记》行书欣赏（4）.txt"
Press any key to continue . . .

qixiaobin0715

回复 19# WHY

乱码问题原来可以这样解决，以前不知道，学到了。谢谢！！！

qixiaobin0715

第5行加上findstr过滤一下效率应当能够得到提升：
'type "%%i"^|findstr /c:"img alt"'

qixiaobin0715

练练手，去掉一层for循环，复习一下call的用法，效率差点。

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. for /r %%i in ("*.txt") do (
   
4.     set n=0
   
5.     for /f "delims=" %%a in ('type "%%i"^|findstr /c:"img alt"') do (
   
6.         set "str=%%a"
   
7. :a
   
8.         echo "!str!"|findstr /c:"img alt">nul&&set str=!str:*img alt=!&&set /a n+=1&&call :a
   
9.     )
   
10.     ren "%%i" "%%~ni（共!n!张图片）%%~xi" 2>nul
    
11. )
    
12. goto :eof
    

复制代码

WHY

回复 22# qixiaobin0715


    for 循环内部（语句块内部）应该不能放置标签的吧？可以把 :a 标签放到 for 循环体外面。

qixiaobin0715

回复 23# WHY

通常是不行。这里是特例，call循环完成后会继续完成它下面的代码，中间ren会报错，增加 2>nul消除。内层for循环结束一次（每个文件读取完成）后，会正常执行一次ren。这里是非常规的用法。只是博得一笑而已。
报错原因是无法识别%%i。