[已解决]批处理if命令的用法（条件同时存在）

woxinfeixian93

我写一个同时存在的条件：
我不知道if如何写
就比如时间

1. @echo off
   
2. color 0a
   
3. setlocal enabledelayedexpansion
   
4. set time1=%time:~0,-3%
   
5. echo %time1%
   
6. for /f "tokens=1-3 delims=: " %%a in ("%time1%") do (
   
7. set b1=%%b
   
8. set c1=%%c
   
9. )
   
10. set /p line3=请在址秒内输完：
    
11. set time2=%time:~0,-3%
    
12. echo %time2%
    
13. for /f "tokens=1-3 delims=: " %%a in ("%time2%") do (
    
14. set b2=%%b
    
15. set c2=%%c
    
16. )
    
17. if %b1% equ %b2% (if %c1%+10 geq %c2% (goto right))
    
18. if %b1% neq %b2% (if %c1%+10 geq %c2%+60 (echo right)) else (echo 你输入有误！)
    
19. pause

复制代码

如果在十秒内输完而且正确，就跳转到指定的一个地方！最后if这要杂样写呀！

stuqx

这个要输入的东西是一个字符还是个字串呀    如果是一个字符 那可以用choice来设定默认等待时间

woxinfeixian93

和输入没有关系，只是不知道这if杂么写，条件要同时成立!
这个想要这输入在10秒内完成！
我是这样想的，两种情况,1。在分相同时，秒加10判断就可以！
                        2。如果在分不同时，比如15:55 那就要比较55+10和新值+60，不知道我讲清楚了吗！
就这个问题！
意思就是，我要这个输入在10秒内完成！这些条件杂么写，如果能有更好的办法，欢迎！！！

Seter

批处理是单线程,单批处理不可能

woxinfeixian93

可能我还没有讲清楚吧！
我要的不是你输入时判断，我可以比较两个时间！你输入前记下时间，输入完在记下时间！如果这个时间 <10秒，才能做下面的事情！
就是最后这个if如何写，简单点说，用户输入在十秒内，才可以跳转到指定的地方！

zljzsmzzx

1. @echo off
   
2. :input
   
3. set time1=%time%
   
4. set/p str=请在十秒内完成输入：&cls
   
5. set time2=%time%
   
6. set/a delay=(%time2:~0,2%-%time1:~0,2%+60)%%60*3600+(1%time2:~3,2%-1%time1:~3,2%+60)%%60*60+1%time2:~-5,2%-1%time1:~-5,2%
   
7. if %delay% gtr 10 (echo,输入超时，请重新输入。&goto input)
   
8. echo,输入时间为：%delay%秒。输入内容为：%str%。
   
9. pause

复制代码

woxinfeixian93

恩，就是我想要的！看来还是我脑子，不好用！算法没有你妙！ 好像(1%time2:~3,2%-1%time1:~3,2%+60)%%60*60+1%time2:~-5,2%-1%time1:~-5,2%这个1%time2:~3,2%前面的一什么意思呀！不用也可以吧！

zljzsmzzx

这个1要的。因为时间的分和秒在小于10的时候是显示00~09的，而在参与set/a计算时以0开头的数字是按八进制数外理的，八进制数的书写方式就是以0开头做为标志的，这个就不用我解释了吧。而08和09是非法的八进制数，因为07上去是010。所以当分或秒为08或09时参与计算就会出错，这时前面的1就起作用了，08就变成108，09变成109，相当于减数和被减数同时加了100，差不变。这样就不存在有八进制数参与计算了。你可以把1去掉算准时间测试一下是否如我所说。

zjw767676

1. @echo off
   
2. :input
   
3. set t=
   
4.   set t=%time%
   
5.    set str=
   
6.     set /p str=请在十秒内完成输入：
   
7.       call :time0 "%t%" "%time%" ok
   
8.          if %ok% gtr 10 (echo,输入超时，请重新输入。&goto input)
   
9.           echo,输入时间为：%ok%秒。输入内容为：%str%。
   
10. pause
    
11. exit
    
12. 
    
13. :time0  计算时间差 （封装）
    
14. @echo off&setlocal&set /a n=0&rem code 随风 @bbs.bathome.net
    
15. for /f "tokens=1-8 delims=.: " %%a in ("%~1:%~2") do (
    
16. set /a n+=10%%a%%100*360000+10%%b%%100*6000+10%%c%%100*100+10%%d%%100
    
17. set /a n-=10%%e%%100*360000+10%%f%%100*6000+10%%g%%100*100+10%%h%%100)
    
18. set /a s=n/360000,n=n%%360000,f=n/6000,n=n%%6000,m=n/100,n=n%%100
    
19. set "ok=%s% 小时 %f% 分钟 %m% 秒 %n% 毫秒"
    
20. set /a "ok=%s%*3600+%f%*60+%m%"
    
21. endlocal&set %~3=%ok:-=%&goto :EOF

复制代码

[ 本帖最后由 zjw767676 于 2009-11-5 22:07 编辑 ]

woxinfeixian93

前几天有事，恩，明白了！谢谢！

CrLf

回复 11# 学习处理


    只要测试无误就能用。
    顺便贴个这方面的链接：http://bbs.bathome.net/viewthread.php?tid=16147