[日期时间] 批处理如何调用mshta获取当前系统日期？

Python

希望得到的格式是：
yyyymmdd

apang

这样可以不？

@echo off
%1set "D=Year(Date)^&Right("0"^&Month(Date),2)^&Right("0"^&Day(Date),2)"
%1mshta vbscript:CreateObject("WScript.Shell").Run("%~s0 :: "^&%D%)(Window.Close)&goto :eof

echo,%2
pause 
复制代码

terse

@echo off
%1mshta vbscript:createobject("wscript.shell").run("%~fs0 : "^&year(date)*10000+Month(Date)*100+Day(Date))(close)&exit
echo %2
pause>nul
复制代码

Python

回复 2# apang


    这样会新启动一个cmd进程吧，有没有类似于start /b这样的方法？

Python

回复 3# terse


    有没有不启动新cmd进程的方法？

apang

回复 4# Python


    如果用fso将结果写入一个文本文件，不会有两个cmd进程。但不明白这样做有什么用啊？

@echo off
set "D=Year(Date)^&Right("0"^&Month(Date),2)^&Right("0"^&Day(Date),2)"
mshta vbscript:CreateObject("Scripting.FileSystemObject").CreateTextFile("a.txt",True).Write(%D%)(Window.Close)
复制代码

batman

当前系统日期直接在cmd中获取不行？

CrLf

回复 7# batman


    估计楼主是用来计算日期差什么的吧？

Python

回复 7# batman


    主要是担心不同的系统里面日期格式不一样

Python

回复 6# apang


    多谢。在实际的使用中要进行计算、比较、进一步处理等。肯定不是只显示一下，那没有任何意义嘛

terse

一定要mshta获取吗

@echo off
for /f %%i in ('WMIC OS GET LocalDateTime') do set str=%%i
echo %str:~,8%
pause
复制代码

Python

回复 11# terse


    受限用户（没有管理员权限）是不能运行WMIC的，首次执行的时候它不是要安装吗。所以不太通用。

chok

大神们，有没有在获取系统当前时间的同时与北京时间做比较，将时间不准的信息拉出来。

pcl_test

for /f %%a in ('mshta VBScript:Execute("FmtDate=right(year(now),4)&right(""0""&month(now),2)&right(""0""&day(now),2):CreateObject(""Scripting.FileSystemObject"").GetStandardStream(1).Write FmtDate:close"^)') do echo;%%a
复制代码