BAT如何批量复制当前目录(包括子目录)下的特定类型文件到一个文件夹里？

86223125 · 发表于 2013-11-20 14:59:45

求代码：批量复制当前目录(包括子目录)下的特定类型文件到一个文件夹里，重名自动修改，并生成导出清单txt

【复制出来的重名文件】自动在后面添加数字，如：“文件名”、“文件名1”、“文件名2”等等。

如果可以，希望复制的重名文件自动改名的同时源文件也同时修改，如：

【源文件】                      【复制出时改名】                         【同时修改源文件名】

F:\上报制卡\1\文件名          F:\上报制卡\备份\文件名                F:\上报制卡\1\文件名

F:\上报制卡\2\文件名          F:\上报制卡\备份\文件名1             F:\上报制卡\2\文件名1

F:\上报制卡\3\文件名          F:\上报制卡\备份\文件名2             F:\上报制卡\3\文件名2

最后生成复制出的文件路径、改名清单txt

foxJL · 发表于 2013-11-20 15:19:03

特定类型是什么类型？

86223125 · 发表于 2013-11-20 17:22:12

回复 1# 86223125

比如jpg txt

changedirectory · 发表于 2013-11-22 10:45:04

本帖最后由 changedirectory 于 2013-11-22 21:51 编辑

本人是新手，请高手指点，谢谢！

@echo off&setlocal enabledelayedexpansion
attrib +s %~f0"
for /r %%a in (*) do (
set str=%%~dpa&& set str=!str:~-2,1!
set /a num=!str!-1
if !str!==r (
echo off
) else (
if !num!==0 (
ren "%%a" "%%~nxa"
) else (
ren "%%a" "%%~na!num!%%~xa"
)
)
)
for /r %%b in (*) do (
md backup&xcopy "%%b" backup >nul 2>nul
)
pause

复制代码

terse · 发表于 2013-11-22 12:52:06

@echo off
set "fph=f:\test\备份"
set "ext=*.txt *.bat"
setlocal enabledelayedexpansion
if not exist "%fph%" md "%fph%"
(for /f "delims=" %%i in ('dir /b/s/a-d %ext%') do (
if not exist "%fph%\%%~nxi" (
copy "%%i" "%fph%\%%~nxi" >nul 2>nul
echo "%%i" ==^> "%fph%\%%~nxi"
) else (
set n=0
call:lp "%%~ni" "%%~xi" "%%~dpi"
copy "%%i" "%fph%\%%~ni!n!%%~xi" >nul 2>nul
ren "%%i" "%%~ni!n!%%~xi"
echo "%%~dpi%%~ni!n!%%~xi" ==^> "%fph%\%%~ni!n!%%~xi
)
))>清单.txt
pause&exit
:lp
set /a n+=1
if exist "%fph%\%~1%n%%~2" goto lp
if exist "%~3\%~1%n%%~2" goto lp
goto:eof

复制代码

apang · 发表于 2013-11-22 13:33:24

假设相同文件名的重复个数不超过20

@echo off
set "SrcDir=F:\上报制卡"
set "DstDir=D:\备份"
for /r "%SrcDir%" %%a in (*.jpg *.txt) do (
if exist "%DstDir%\%%~nxa" (
set flag=1
for /l %%b in (1 1 20) do (
if defined flag (
if not exist "%DstDir%\%%~na%%b%%~xa" (
copy "%%a" "%DstDir%\%%~na%%b%%~xa"
set "flag="
echo,%%a %DstDir%\%%~na%%b%%~xa>>List.txt
)
)
)
) else (
copy "%%a" "%DstDir%"
echo,%%a %DstDir%\%%~nxa>>List.txt
)
)
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] BAT如何批量复制当前目录(包括子目录)下的特定类型文件到一个文件夹里？