求助: 批处理如何获取文件的路径信息？

swallowcn · 发表于 2014-11-18 11:32:20

比如:
STR1=C:\1.txt 或STR1=\\server1\share\2.txt

如何得到STR1值中的目录信息，比如说上边两个例子的目录分别应该是 C:\ 或 \\server1\share

求指教，谢谢。

cjiabing · 发表于 2014-11-18 12:16:16

set STR1=C:\1.txt
echo %STR1%

DAIC · 发表于 2014-11-18 12:46:37

回复 2# cjiabing

你看错需求了吧

@echo off
set "STR1=C:\1.txt"
for %%i in ("%STR1%") do echo %%~dpi
set "STR1=\\server1\share\2.txt"
for %%i in ("%STR1%") do echo %%~dpi
pause

复制代码

apang · 发表于 2014-11-18 12:57:37

本帖最后由 apang 于 2014-11-19 11:11 编辑

@echo off
set "str1=\\server1\share\2.txt"
for /f "delims=" %%a in ("%str1:\\=?:\%\..") do set "str2=%%~fa"
set "str2=%str2:?:\=\\%"
echo,%str2%
pause

复制代码

apang · 发表于 2014-11-18 13:01:04

本帖最后由 apang 于 2014-11-19 11:46 编辑

来个奇葩解：

@set @n=0;/* & echo off
set "str1=\\server1\share\2.txt"
for /f "delims=" %%a in ('cscript -nologo -e:jscript "%~0" "%str1%"') do (
set "str2=%%a"
)
echo,%str2%
pause & exit/b */
s = WScript.Arguments(0).replace(/([a-z]:\\|.*?)(\\)?[^\\]*$/i, "$1");
WScript.Echo(s)

复制代码

swallowcn · 发表于 2014-11-18 19:45:47

谢谢楼上几楼前辈的回复。

我测试了一下，
STR1=C:\1.txt时，处理后取到的结果是我想要的C:\
但如果STR1=\\server1\share\1.txt时，处理后得到的结果成了\\share\share\，我想其结果是\\server1\share就是用网络路径时，不要最后哪个\符号。

DAIC · 发表于 2014-11-18 20:11:15

回复 6# swallowcn

@echo off
set "STR1=C:\1.txt"
for %%i in ("%STR1%") do echo %%~dpi
set "STR2=\\server1\share\2.txt"
for %%i in ("%STR2%") do set "STR2_NEW=%%~dpi"
echo %STR2_NEW:~0,-1%
pause

复制代码

swallowcn · 发表于 2014-11-18 20:29:12

谢谢“DAIC”老大的及时回复，完美解决。结贴。

ads350668398 · 发表于 2014-11-18 20:45:22

以后都统一点用小写字母写晕啊大写直接晕了

swallowcn · 发表于 2014-11-19 09:49:57

回复 9# ads350668398

好的，下次我一定遵守纪律，一律改用小写字母！

amwfjhh · 发表于 2014-11-19 11:11:33

回复 5# apang

PJ混排，其乐无穷。

CrLf · 发表于 2014-11-19 20:37:57

回复 11# amwfjhh

同感，简直就是小霸王学习机

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 求助: 批处理如何获取文件的路径信息？