[文本处理] 批处理如何删除每行最后一个指定字符之前的内容/提取每行最后一个指定字符之后的内容

lyfwcn

http://www.bathome.net/post.php?action=newthread&fid=5                              (这有三个/)
http://www.bathome.net/c/3553908420                                                               (这有四个/)

删除/前的
变成
post.php?action=newthread&fid=5
3553908420

谢谢

yiwuyun

sed "s/.*\///" 1.txt
复制代码

apang

@echo off
for /f "delims=" %%a in (a.txt) do echo %%~nxa
pause
复制代码

lyfwcn

回复 3# apang

谢谢，可行.但换了个符号就不行了

lyfwcn

yiwuyun 发表于 2015-1-28 21:06

我下了个sed,文本改成1.txt,结果没变化。

yiwuyun

sed -i.txt "s/.*\///" 1.txt
复制代码

@echo off
for /f "delims=" %%a in ('type 1.txt') do (
  set line=%%a
  setlocal EnableDelayedExpansion
  set "line=!line:/= !"
  call :Dispose "^!line^!"
  endlocal
)
exit /b 0

:Dispose
set "line=%~1"
:start
for /f "tokens=1* delims= " %%c in ('echo "!line!"') do (
    set content=%%~c
    set line=%%~d
)
if "!line!"=="" goto end
set line=!line:~0,-1!
if not "!line!"=="" goto start
:end
echo !content!
exit /b 0
复制代码

digitbear

用sed 应该可以

amwfjhh

@echo off
setlocal enabledelayedexpansion

for /f "tokens=1 delims=:" %%i in ('findstr /n /r "^:样本" %~s0') do set /a "nTag=%%i"

if defined nTag (
	for /f "delims=" %%i in ('more +%nTag% %~s0') do (
		set "strLine=%%i"
		echo,原地址     : !strLine!
		call :_ShowAction "strLine"
		echo,处理后地址 : !strLine!
	)	
)

pause & goto :EOF

:_ShowAction
(
	echo,"!%~1!" | findstr /c:"/" >nul && (
		set "%~1=!%~1:*/=!"
		call :_ShowAction "%~1"
	)
	
	goto :EOF
)


:样本
http://www.bathome.net/post.php?action=newthread&fid=5
http://www.bathome.net/c/3553908420
复制代码

apang

@echo off & setlocal enabledelayedexpansion
set Lf=^


for /f %%a in ('copy /z "%~0" nul') do for %%b in ("!Lf!") do (
        endlocal
        (for /f "delims=" %%c in (a.txt) do (
                set "s=%%c"
                setlocal enabledelayedexpansion
                set "s=!s:/=/%%a%%~b!"
                echo,!s!
                endlocal
        ))>$
)
findstr "[^/]$" $ > b.txt
del $
pause
复制代码

慕夜蓝化

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
    set "str=%%i"&call :split 
)
pause
:split
echo,"!str!"|find "/" >nul 2>nul ||echo,!str!&&goto :eof
set "str=!str:*/=!"&goto :split
复制代码

你应该测试一下，我想了好几条思路，这样一来，字符串的任意提取，几乎没有了难度，所要做的就是接触更多的方法。

amwfjhh

回复 9# apang

 copy /z "%~0" nul
复制代码

请问apang,这句是作什么用的？去掉这层循环，单纯将/后加个回车也能得到正确的结果。

CrLf

回复 11# amwfjhh


    用于取回车符（由 plp626 发明），这样才能被 findstr 的 $ 匹配到（findstr 里判定 $ 的就是回车符）
    apang 的方案非常妙，意外惊喜，赞

CrLf

基于 apang 思路，来俩变化：

@echo off
set NLM=^


set NL=^^^%NLM%%NLM%^%NLM%%NLM%
for /f "delims=" %%a in (c.txt) do (
	set "str=%%a$"
	setlocal enabledelayedexpansion
	for /f "delims=" %%b in (^"!str:/^=%NL%!^") do (
		endlocal
		set "str=%%b"
		setlocal enabledelayedexpansion
	)
	echo !str:~,-1!
	endlocal
)
pause
复制代码

@echo off
for /f "delims=" %%a in (c.txt) do (
	set str=%%a
	setlocal enabledelayedexpansion
	set str=set "str=!str:/="^&set "str=!"
	call :getstr
	echo !str!
	endlocal
)
pause

:getstr
%str%
exit /b
复制代码

CrLf

不过要说哪个方案比较通用，呃，如果不方便用第三方，那还是用 Bat+JS 吧

1>1/* : www.bathome.net
@echo off
cscript -nologo -e:jscript "%~0"<c.txt
pause & exit /b
*/
with(WSH){
Echo(StdIn.ReadAll().replace(/.*\//gm,''))
}
复制代码

amwfjhh

回复 12# CrLf


    回车替换是后面这句做到的嘛。

for %%b in ("!Lf!") do
复制代码

!Lf!在前面已经赋值，但前面那句

copy /z "%~0" nul
复制代码

还是不清楚是来干嘛的，有它没它，单凭后面那层循环也可以直接将回车(准确说是换行符)加到"/"字符之后。