terse

batman兄：
输入数有限制不？位数

BBCC

题目已经写好是两位小数啦...

youxi01

个人支持将含小数的分成两部分计算

以小数点为分割点，分别计算

batman

看来此题确是有难度，我只要公布自己的代码了（自己看着都晕得很。。。）：

@echo off&setlocal enabledelayedexpansion
set /p str=输入的两数为：
set /a num_1=0,num_2=0,num=1,v=0
for %%a in (%str%) do (
    set /a n+=1
    for /f "tokens=1,2 delims=." %%b in ("%%a") do (
        set "_!n!=%%b"
        if "%%c" equ "" (
           set ".!n!=00"&set /a m+=1
           if !m! equ 2 set "flag=a"
           ) else (
           set "a=%%c00"&set "a=!a:~,2!"
           set ".!n!=!a!"
        ) 
     )
)
for %%a in (+#h -#c) do (
    for /f "tokens=1,2 delims=#" %%b in ("%%a") do (
        if "%_1:~,1%" equ "-" set "k1=-"
        if "%_2:~,1%" equ "-" set "k2=-"
        set /a %%c1=_1%%b_2,%%c2=!k1!1%.1%%%100%%b!k2!1%.2%%%100
        if !%%c1! lss 0 (
           if !%%c2! leq -100 set /a %%c2+=100,%%c1-=1
           ) else (
           if !%%c1! equ 0 (
              if !%%c2! lss 0 set "%%c1=-0"&set "a=!%%c2!"&set "%%c2=!a:-=!"
              ) else (
              if !%%c2! lss 0 set /a %%c2+=100,%%c1-=1
           )
         )
         if !%%c2! geq 100 set /a %%c2-=100,%%c1+=1 
    )
)
for %%a in (h2 c2) do (
    set "a=!%%a!"&set "a=!a:-=!"&set %%a=!a!
    if !a! lss 10 set "%%a=0!a!"
)
echo 其和为：%h1%.%h2%&echo 其差为：%c1%.%c2%&set /a n=0
if defined flag set ".1="&set ".2="
for %%a in (1 2) do (
    if "!_%%a!" equ "0" (
       set "_%%a="&set /a .%%a=1!.%%a!%%100
       ) else (
       if "!_%%a!" equ "-0" (
          set "_%%a=-"
          ) else (
          set "a=!_%%a!"&set "a=!a:-=!"
          set /a n+=1&call :lp
       )
    )
    if "!.%%a!" neq "" set "a=!.%%a!"&call :loop&set ".%%a=!a!"
)
set /a num1=3-num_1+num_2,m=4-v
if defined flag set /a m=0
if %num1% leq 0 set /a num1=2
for /l %%a in (1,1,%num1%) do set /a num*=10
set /a s=%_1%%.1%*num/%_2%%.2%,j=%_1%%.1%*%_2%%.2%
if %j% lss 0 set "j=%j:-=%"&set "jk=-"
if %s% lss 0 set "s=%s:-=%"&set "sk=-" 
if %m% neq 0 if "!j:~%m%!" equ "" set "j=0000%j%"&set "j=!j:~-%m%!"
if %s% lss %num% set "s=%num:~1%%s%"&set "s=!s:~-%num1%!"
if %m% neq 0 set "j=!j:~,-%m%!.!j:~-%m%,2!"
set "s=!s:~,-%num1%!.!s:~-%num1%,2!
for %%a in (s j) do (
    set "a=!%%a!"
    if "!a:.=!" equ "!a!" (
       set "%%a=!%%a!.00"
       ) else (
       if "!a:~-2,1!" equ "." set "%%a=!%%a!0"
    )  
    if "!a:~,1!" equ "." set "%%a=0!%%a!"
)
echo 其积为：%jk%%j%&echo 其商为：%sk%%s%
pause>nul&goto :eof
:lp
set /a num_%n%+=1&set "a=%a:~1%"
if defined a goto lp
goto :eof
:loop
if "%a:~-1%" equ "0" set "a=%a:~,-1%"&set /a v+=1&goto loopCOPY

[ 本帖最后由 batman 于 2009-2-15 19:16 编辑 ]

batman

&&本人19楼的代码相当复杂，估计大家肯定会看得云里雾里，所以思来想去还
是补充代码编写思路如下，以便理解，同时期待高人出手，给出完美代码：

   一、总体计算思路
   大家知道本题最关键是在对小数点前后两部分数值的处理上，在楼上大家也有
过相关讨论。本人认为在加减法的处理上，应该是要将前后数值分开分别进行计
算然后再做处理（如后面小数位和满百位的处理），最后再在中间补上小数点。
而对乘法，则应是去掉小数点后前后位一起运算，最后从后向前移位补上小数点
。至于除法则是最复杂的，如结果要保留两位小数，你必须要保证除数的数位比
被除数多三位（两数均先去掉小数点），当这一条件没有得到满足时，就要给除
数后面补上足够的0，最后在结果中从后向前移位补上小数点。

   二、对数值的处理
   大家可以看到本人在代码中使用了海量的if语句来做判断，主要是为了处理各
种情况下的数值，大致将情况归纳如下面的12点：
   1 处理原始数值无小数位的情况--从后面补上.00
   2 处理原始数值小数位不满两位的情况--给小数位补上00并提取前面的两位
   3 处理加减计算时小数位大于100的情况--小数位减去100，整数位加1
   4 处理加减计算整数位为负小数位小于-100的情况--小数位加上100，整数位
减1
   5 处理加减计算整数位为0小数位小于0的情况--整数位变为-0，小数位去掉负
号
   6 处理加减计算整数位为正小数位小于0的情况--小数位加上100，整数位减1
   7 处理加减计算小数位小于10的情况--在小数位前面加上0
   8 处理乘除计算时两数小数位均为00的情况--将小数位置空
   9 处理乘除计算时整数位为0的情况--对小数位进行取余运算
  10 处理乘除计算时结果数位不够小数位的情况--在结果值前面补上足够的0并
从后向前提取小数位（如结果为负数还要先取掉负号最后再补上）
  11 处理乘除计算时结果无小数位的情况--在结果后补上.00
  12 处理乘除计算时结果小数位不足两位的情况--在结果后补上0

   三、感言
   在这次编写代码的过程中，本人深深感受到批处理在处理数值上的不足和缺陷
，这也是本人在出题时始料不及的。没想到其中要考虑的问题是方方面面错综复
杂，本人也曾几次在困难面前想要退缩，但为了给大家一个较满意的答案，还是
硬着头皮写了下来。看来批处理只适合做它适合做的事，想人为强加给它其他的
功能的确是费力不计好。

[ 本帖最后由 batman 于 2009-2-15 19:38 编辑 ]

inittab

练练手。基本思路是化小数为整数运算，得到结果后再恢复成小数。
不支持大数字运算。特别是乘法部分有待完善，需要考虑的成分的确太多了。可能有批漏之处

@echo off&setlocal enabledelayedexpansion
:begin
set /p m=输入(q退出):
if "!m!"=="q" goto :eof
set /p n=输入:
for /f "tokens=1,2 delims=." %%i in ("%m%") do set m1=%%j00&if not "%%j"=="" (set mm=%%i!m1:~0,2!) else set mm=%%i00
for /f "tokens=1,2 delims=." %%i in ("%n%") do set n1=%%j00&if not "%%j"=="" (set nn=%%i!n1:~0,2!) else set nn=%%i00
 
if "!mm:~0,1!"=="-" (set mm=!mm:~1!&set /a num=2!mm!-1!mm!,mm=1!mm!-num&set mm=-!mm!) else set /a num=2!mm!-1!mm!,mm=1!mm!-num
if "!nn:~0,1!"=="-" (set nn=!nn:~1!&set /a num=2!nn!-1!nn!,nn=1!nn!-num&set nn=-!nn!) else set /a num=2!nn!-1!nn!,nn=1!nn!-num
 
set /a add=mm+nn
call :check !add! num1
echo 两值之和是: !num1!
 
set /a sub=mm-nn
call :check !sub! num2 
echo 两值之差是: !num2!
 
 
set /a mul=mm*nn
if !mul! lss 100 (set num3=0.00) else (
set mul=!mul:~0,-2!
call :check !mul! num3
)
echo 其积为:!num3!
 
set /a div=100*mm/nn
call :check !div! num4
echo 其商为:%num4%
 
goto begin
 
:check
set var=%1&set "_="
if !var! lss 0 (set /a var=-1*var&set _=-)
if !var! lss 10 (set var=00!var!) else if !var! lss 100 set var=0!var!
if "!var:~-2!"=="00" (set var=!var:~0,-2!) else if "!var:~-1!"=="0" (set var=!var:~0,-2!.!var:~-2,1!) else set var=!var:~0,-2!.!var:~-2!
set %2=!_!!var!&goto :eofCOPY

qq506657335

商的取值不怎么准确。。
如23/36 你写的批处理的结果是0.63
但实际上是0.638888循环。。。
所以取值应该是0.64

Hello123World

回复 5# BBCC
for /f "delims=" %%a in ('%0') do (echo %%a)
是你搞错了('%0'因为"%0")，还是有什么其他的意思——我运行后批处理就不动了。

zhengdalu

这...我新手，请问不是批处理不支持浮点吗

Batcher

回复 25# zhengdalu


你自己试试就知道啦

guaiwu

@echo off
setlocal enabledelayedexpansion
set /p q=请输入两个小数：
for %%i in (%q%) do (
set /a a+=1
set a!a!=%%i
)
set /a a=%a1%+%a2%
set /a b=%a1%-%a2%
set /a c=%a1%*%a2%
set /a d=%a1%/%a2%
echo 两个小数的和为%a%
echo 两个小数的差为%b%
echo 两个小数相乘为%c%
echo 两个小数相除为%d%
pauseCOPY

zhengdalu

回复 26# Batcher


    我试过，窗口只给显示整数位，小数没有啊。

Batcher

回复 28# zhengdalu


嗯，根据你试的结果，你觉得支持吗？

zhengdalu

我觉得不支持，可是楼主...怎么这么问啊

Batcher

回复 30# zhengdalu


如果你觉得不支持，为何还有25楼的疑问呢？