数据库备份文件ftp异地备份的批处理如何设置日期变量？

zs415156995 · 发表于 2019-1-16 14:46:44

用任务计划运行批处理实现数据库备份文件的ftp异地备份，上图set可以实现因为变量在最后面
但是另外一台服务器的数据库备份文件名变量在中间，如何设置set来实现
求大神帮忙

Batcher · 发表于 2019-1-16 21:08:39

把你的代码第4行改成这样：

for /f %%i in ('powershell -c "Get-Date -uformat '%%Y_%%m_%%d'"') do (
set "Today=%%i"
)
set fn=EN_PRJ_backup_%Today%

复制代码

zs415156995 · 发表于 2019-1-17 09:31:09

回复 2# Batcher
管理，你弄错了，我是想把下面那个图片每天使用FTP上传

dbhpn-bkhpn-101469-201901161200
dbhpn-bkhpn-101470-201901162100
这两个文件用FTP上传中间和最后4位是变量

Batcher · 发表于 2019-1-17 10:28:37

回复 3# zs415156995

你把代码发出来，不要截图。

zs415156995 · 发表于 2019-1-17 10:58:58

本帖最后由 zs415156995 于 2019-1-17 11:00 编辑

回复 4# Batcher

@echo on
e:
cd \thamsDatabaseBackup
set fn=dbhpn-bkhpn-%date:~5,2%%date:~8,2%
if exist "%fn%" goto rar
echo No File
go end
:rar
del e:\data.rar
"C:\Program Files\WinRAR\WinRAR.exe" a -ep1 -y e:\data"%fn%".rar "%fn%"*
echo open 10.46.3.210>q
echo dabackup>>q
echo 1234567890qwert>>q
echo lcd e:\>>q
echo put data"%fn%".rar>>q
echo bye>>q
ftp -s:q
del q /q
del e:\data"%fn%".rar
:end
cd\
rem exit

复制代码

第四行那个set 我是设置成dbhpn-bkhpn-今天日期，但是实际是dbhpn-bkhpn-xxxxxx(中间变量)-今天日期（xxxx） x是变量
我不知道怎么表示那个变量

就是怎么表示下面红色部分
dbhpn-bkhpn-101469-201901161200
dbhpn-bkhpn-101470-201901162100

Batcher · 发表于 2019-1-17 12:43:20

这个脚本放在bak文件的那个目录下面执行：

@echo off
for /f %%i in ('powershell -c "Get-Date -uformat '%%Y%%m%%d'"') do (
set "Today=%%i"
)
for %%i in ("dbhpn-bkhpn-*-%Today%*.bak") do (
call :rar %%i
)
goto :eof
:rar
"C:\Program Files\WinRAR\WinRAR.exe" a -ep1 -ibck -y "%~n1".rar "%1"
echo open 10.46.3.210>q
echo dabackup>>q
echo 1234567890qwert>>q
echo lcd %~dp0 >>q
echo put "%~n1".rar>>q
echo bye>>q
ftp -s:q
del /f /q "%~n1".rar q

复制代码

zs415156995 · 发表于 2019-1-17 13:30:16

回复 6# Batcher
非常感谢管理 15行和16行目录和命名改完就好用了谢谢

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[日期时间] 数据库备份文件ftp异地备份的批处理如何设置日期变量？