[已解决]BAT脚本达到微信多开的问题

love303929545

请问大佬们，想弄个微信多开，目前是这种用的其他大佬的（我本人是小白一枚0.0）：

1. @echo off
   
2. 
   
3. cd /d "%SrcDir%"
   
4. color 0f
   
5. 
   
6. :start
   
7. echo 请输入要打开微信的个数：
   
8. set /p answer=
   
9. 
   
10. for /l %%i in (1,1,%answer%) do start WeChat.exe

复制代码

但是这种不适合所有人使用，因为每个人微信安装位置不一样，这个必须要放在微信安装目录下才能正确运行。请问要怎么写，才能够不管微信安装在哪儿，bat不管放哪儿都可以直接多开呢？请大佬指教。

yhcfsr

办法当然有,第一次运行的话肯定要全盘扫描的,扫描到WeChat.exe可以将路径记录到流文件.以后运行就不需要再扫描了.
不过将微信的路径设置到BAT里更快不是吗?

love303929545

回复 2# yhcfsr


    快是快，但是每个人安装电脑路径不一样啊，别人找我要这个我直接就发给别人了，很多同事压根儿都不知道什么路径啥的。。。

love303929545

回复 2# yhcfsr


    请问你说的那个怎么写代码呢？

Batcher

参考：
http://bbs.bathome.net/thread-3465-1-1.html

yhcfsr

回复 5# Batcher


参考老大提供的帖子,写了个,题主做下参考.

1. @echo off
   
2. rem 此脚本实现微信多开功能
   
3. 
   
4. set "FileName=wechat.exe"
   
5. set "script_path=%~f0"
   
6. (set/p wechat=<"%script_path%:WX") 2>nul
   
7. if "%wechat%" equ "" (echo 首次运行,正在扫描微信...) else goto :start_wechat
   
8. 
   
9. (for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
   
10.     if exist %%a:\ (
    
11.         pushd %%a:\
    
12.         for /r %%b in (*%FileName%) do (
    
13.             if /i "%%~nxb" equ "%FileName%" (
    
14.                                
    
15.                 echo,%%b|findstr /v "%tmp%"&&(
    
16.                                         echo %%b>"%script_path%:WX"
    
17.                                         goto :start_wechat
    
18.                                 )
    
19.             )
    
20.         )
    
21.         popd
    
22.     )
    
23. ))>nul 2>nul
    
24. echo;对不起,没有找到微信
    
25. pause&exit
    
26. 
    
27. :start_wechat
    
28. set/p wechat=<"%script_path%:WX"
    
29. set /p "num=亲要开几个微信:"
    
30. for /l %%a in (1,1,%num%) do start "" "%wechat%"

复制代码

hnfeng

扫硬盘？ 运行一下就扫一遍？扫到什么时候啊

直接读注册表里面 微信 的位置

whiter

直接修改电脑的环境变量啊,电脑属性--高级--环境变量设置
或者 reg add命令添加注册表 位置应该是:[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment]
应该可以,具体实现我没试

yhcfsr

回复 7# hnfeng


  亲测,装在C盘扫描2秒.E盘约6秒.
只会在首次运行时扫描一次.

读注册表的方法很好,我试试完善下.非常感谢指点^V^ .

1. @echo off
   
2. rem 此脚本实现微信多开功能.
   
3. 
   
4. for /f "tokens=2*" %%a in ('reg query "HKEY_CURRENT_USER\Software\Tencent\WeChat" /v InstallPath 2^>nul') do set "wechat=%%b"
   
5. if not defined wechat echo;没有找到微信&pause&exit
   
6. set /p "num=亲要开几个微信:"
   
7. for /l %%a in (1,1,%num%) do start "" "%wechat%\WeChat.exe"

复制代码

love303929545

回复 6# yhcfsr


    大佬，这个出现丢失ssleay32.dll和wechatwin.dll文件缺失怎么解决呢？直接打开微信有没有出现这个

hnfeng

1. C:\Windows\System32>for /f "tokens=1,2*" %a in ('reg query HKCU\Software\Tencent\WeChat /v InstallPath ^| find /i "REG_SZ" ') do set WeChatPath=%c
   
2. 
   
3. C:\Windows\System32>set WeChatPath=C:\Program Files (x86)\Tencent\WeChat

复制代码

yhcfsr

回复 10# love303929545

先试试9楼的代码吧.
至于6楼代码出问题,需要看调试信息.可能是获取路径出了问题.
我测试时也发现临时目录也会出现WECHAT.exe,所以我排除了临时目录(可能系统不一样,临时目录的环境变量不太一样,我应该用Temp不应该用tmp)

Batcher

参考：自动获取QQ路径的几种方法：读注册表、全盘搜索、获取进程信息等
http://bbs.bathome.net/thread-4193-1-1.html

love303929545

回复 12# yhcfsr


    多谢大佬。9楼完美解决了。

刚刚刚刚好

start D:\微信\WeChat\WeChat.exe
start D:\微信\WeChat\WeChat.exe
对于能查看路径的直接改后面路径
再说了 右键微信的快捷方式 属性 就能看到微信路径 直接复制 多省事