[文件操作] 批处理如何实现文件版本更替，并保留最新文件？

星空独子

假如#+数字（比如#78）为同名文件的版本号，那么如何实现保留最新的版本，如果不存在#+数字，则默认为该版本为同名文件的最新文件，然后，通过确认删除#+数字后删除#+数字

flashercs

del /p *#*.pdf
复制代码

星空独子

回复 2# flashercs
大神，你的代码无法对同名文件就行版本比较并保留最新版本的文件，其次不能删除文件名中#+数字，你的代码直接把我文件给删除了，最后我的确认只需要一次，就实现#+数字的删除，而非每个文件都确认

Batcher

回复 1# 星空独子


以顶楼这几个文件为例，需要实现的目标是不是这样：

删除文件[目视检查.pdf]、[目视检查#12.pdf]
[目视检查#78.pdf]重命名为[目视检查.pdf]

删除文件[设备检查.pdf]
[设备检查#7.pdf]重命名为[设备检查.pdf]

星空独子

回复 4# Batcher
是的，理解的很到位

WHY

dir 'E:\Test\*.pdf' | sort{1*($_.BaseName -split '#(\d+)$')[1]} -Desc | group{($_.BaseName -split '#\d+$')[0]} | ?{$_.Count-1} | %{del $_.Group[1..($_.Count-1)] -WhatIf; ren $_.Group[0] -NewName ($_.Group[0].Name -replace '#\d+(\.pdf)$','$1') -WhatIf }
复制代码

效果：

WhatIf: 对目标“E:\Test\目视检查#12.pdf”执行操作“删除文件”。
WhatIf: 对目标“E:\Test\目视检查.pdf”执行操作“删除文件”。
WhatIf: 对目标“项: E:\Test\目视检查#78.pdf 目标: E:\Test\目视检查.pdf”执行操作“重命名文件”。
WhatIf: 对目标“E:\Test\设备检查.pdf”执行操作“删除文件”。
WhatIf: 对目标“项: E:\Test\设备检查#7.pdf 目标: E:\Test\设备检查.pdf”执行操作“重命名文件”。

星空独子

回复 6# WHY
如果文件名是这样的   F402-1#6，路径也包含中文名，这个程序需要做什么样的调整

WHY

回复  WHY
如果文件名是这样的   F402-1#6，路径也包含中文名，这个程序需要做什么样的调整
星空独子 发表于 2019-12-4 09:21

扩展名是 pdf 就行，这个程序没必要做调整。

WHY

好吧，保存为 Test.BAT，修改 E:\Test 为实际目录名称，双击运行。
如果显示无误，删除脚本中的 -WhatIf

@echo off
PowerShell -exec ByPass -c "dir -Literal 'E:\Test' -filter *.pdf | sort{1*($_.BaseName -split '#(\d+)$')[1]} -Desc | group{$_.BaseName -replace '#\d+$'} | ?{$_.Count-1} | %%{ $f = $_.Group | select -Exp fullName; del -Literal $f[1..($_.Count-1)] -WhatIf; mv -Literal $f[0] -Dest ($f[0] -replace '#\d+(\.pdf)$','$1') -WhatIf}"
pause
复制代码

went

@echo off
setlocal enabledelayedexpansion
REM 循环所有pdf文件
for /f "delims=" %%i in ('dir /b *.pdf ^| sort') do (
	for /f "tokens=1,2 delims=#." %%a in ("%%i") do (
		set "curFileName=%%a"
		set "curVer=%%b"
		if "!curVer!"=="pdf" set "curVer=0"
	)
	if "!lastFileName!"=="" set "lastFile=%%i"&set "lastFileName=!curFileName!"&set "lastVer=!curVer!"
	if "!curFileName!"=="!lastFileName!" (
		REM 删掉ECHO
		if !curVer! lss !lastVer!  ECHO del "%%i"&set "curVer=!lastVer!"
		REM 删掉ECHO
		if !curVer! gtr !lastVer! ECHO del "!lastFile!"&set "lastFile=%%i"
		set "lastFileName=!curFileName!"&set "lastVer=!curVer!"
	) else ( 
		echo ---^> !lastFileName!最新版本:!lastVer!
		REM 删掉ECHO
		ECHO rename "!lastFileName!#!lastVer!.pdf" "!lastFileName!.pdf"
		set "lastFile=%%i"&set "lastFileName=!curFileName!"&set "lastVer=!curVer!"
		echo --------------------------------------------------
	)
)
echo ---^> !lastFileName!最新版本:!lastVer!
REM 删掉ECHO
ECHO rename "!lastFileName!#!lastVer!.pdf" "!lastFileName!.pdf"
echo --------------------------------------------------
pause
复制代码

确认无误删掉大写的ECHO