BAT脚本如何批量重命名子文件下的文件名？

wodekao

例如:
A/123/1.jpg
A/123/c.jpg
A/123/v.jpg  

A/zzz/e.jpg
A/zzz/r.jpg
A/zzz/t.jpg  

B/acv/x.jpg
B/acv/c.jpg
B/acv/b.jpg

B/eee/e.jpg
B/eee/r.jpg
B/eee/t.jpg  

其中A文件夹和B文件夹在同一个目录下
需求bat，执行后的结果:

A/A-123/A-123-001.jpg
A/A-123/A-123-002.jpg
A/A-123/A-123-003.jpg  

A/A-zzz/A-zzz-001.jpg
A/A-zzz/A-zzz-002.jpg
A/A-zzz/A-zzz-003.jpg  

B/B-acv/B-acv-001.jpg
B/B-acv/B-acv-002.jpg
B/B-acv/B-acv-003.jpg

B/B-eee/B-eee-001.jpg
B/B-eee/B-eee-002.jpg
B/B-eee/B-eee-003.jpg

smss

以下脚本保存为ANSI编码放在你描述的A B文件夹所在目录执行

1. @echo off&setlocal enabledelayedexpansion
   
2. for /d %%a in (*) do for /d %%b in (%%a\*) do (ren "%%~fb" "%%~na-%%~nb"&cd "%%a\%%~na-%%~nb"&set n=0
   
3. for /f "delims=" %%i in ('dir /b/s "*.jpg"') do (set "p=%%~dpi"&cd/d "!p!..\.."&call set "pf=%%p:!cd!\=%%"&set /a n+=1
   
4. if !n! lss 10 (ren "%%i" "!pf:\=-!00!n!%%~xi")else if !n! lss 100 (ren "%%i" "!pf:\=-!!0n!%%~xi")else ren "%%i" "!pf:\=-!!0n!%%~xi"))
   
5. pause

复制代码

或者

1. @echo off&setlocal enabledelayedexpansion
   
2. for /d %%a in (*) do for /d %%b in (%%a\*) do (ren "%%~fb" "%%~na-%%~nb"&cd "%%a\%%~na-%%~nb"&set n=1000
   
3. for /f "delims=" %%i in ('dir /b/s "*.jpg"') do (set "p=%%~dpi"&cd/d "!p!..\.."&call set "pf=%%p:!cd!\=%%"&set /a n+=1&set m=!n:~1!
   
4. ren "%%i" "!pf:\=-!!m!%%~xi"))
   
5. pause

复制代码

Batcher

回复 1# wodekao

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. for /d %%a in (*) do (
   
4.     for /d %%b in (%%a\*) do (
   
5.         ren "%%~fb" "%%~na-%%~nb"
   
6.         pushd "%%a\%%~na-%%~nb"
   
7.         set n=1000
   
8.         for /f "delims=" %%i in ('dir /b /s "*.jpg"') do (
   
9.             set /a n+=1
   
10.             ren "%%i" "%%~na-%%~nb-!n:~-3!%%~xi"
    
11.         )
    
12.         popd
    
13.     )
    
14. )

复制代码

Batcher

回复 2# smss


    n的初始值设置为1000，可以省去那几个判断。

smss

回复 4# Batcher
嗯