[文件操作] 【已解决】求助批处理文件名互换位置

gzjhong

原格式：
111 222 3333 4444_555555_66666666
现在想改成：
66666666555555_11122233334444
请问能通过批处理实现吗？

flashercs

for %%a in (*) do (
  for /f "tokens=1-5* delims=_ " %%A in ("%%a") do (
    ren "%%a" "%%F%%E_%%A%%B%%C%%D"
  )
)
复制代码

gzjhong

flashercs 发表于 2020-11-27 08:01

    谢谢，用您提供的批处理，现在变成了66666666.txt_11122233334444555555，还是没达到效果，哪位大神能帮忙再改一下吗？

flashercs

回复 3# gzjhong

for %%a in (*) do (
  for /f "tokens=1-5* delims=_ " %%A in ("%%~na") do (
    ren "%%a" "%%F%%E_%%A%%B%%C%%D%%~xa"
  )
)
复制代码

gzjhong

回复  gzjhong
flashercs 发表于 2020-11-29 20:59

    现在变成了66666666_11122233334444555555.txt，我想要的效果是66666666555555_11122233334444.txt，能再改一下吗？谢谢！

flashercs

@echo off
cd /d "%~dp0"
for /f "delims=" %%a in ('dir /a /b *.txt') do (
  for /f "tokens=1-5* delims=_ " %%A in ("%%~na") do (
    echo ren "%%a" "%%F%%E_%%A%%B%%C%%D%%~xa"
    ren "%%a" "%%F%%E_%%A%%B%%C%%D%%~xa"
  )
)
pause
exit /b
复制代码

gzjhong

回复 6# flashercs


    现在提示找不到文件了

Batcher

回复 1# gzjhong

@echo off
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
    for /f "tokens=1-6 delims=_ " %%a in ("%%~ni") do (
        ren "%%i" "%%f%%e_%%a%%b%%c%%d%%~xi"
    )
)
复制代码

gzjhong

回复 8# Batcher


    还是不行 ，555555还是没到前面来，和之前一样

gzjhong

应该是我的问题，我认真测试一下，谢谢你

Batcher

回复 9# gzjhong


    请把你测试用的bat和txt文件打包压缩传上来我试试

gzjhong

回复 10# gzjhong


这个是样本文件，能帮忙测试一下吗？文件名前面的位数有可能会少一点，但后面的年月日和时间是固定位数的，134331是时间，20190722是年月日

gzjhong

回复 11# Batcher


    是我的问题，我没有注意到我文件的细节，文件前面的位数不一样，所以导致结果也不一样，真抱歉！！！

Batcher

回复 12# gzjhong

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
    for /f "tokens=1-3 delims=_" %%a in ("%%~ni") do (
        set "c1=%%a"
        ren "%%i" "%%c%%b_!c1: =!%%~xi"
    )
)
复制代码

liyu963926475

哈哈哈不愧是大佬佩服