求助批处理如何按文件固定字符前字符命名压缩包名？

jieyuan_1981 · 发表于 2022-6-29 15:31:02

我有一段代码是按照文件前10位数字来命名压缩包名，如果要是这样取 "_" 前几位相同字符来命名怎么改，如:
a_disk1.txt
a_disk2.txt
abc_disk1.txt
abc_disk2.txt
efgh_disk1.txt
efgh_disk2.txt
efgh_disk3.txt
想实现效果 a.zip abc.zip efgh.zip (里面文件要是a_disk1.txt a_disk2.txt ....)

@echo off
cd /d %~dp0
setlocal enabledelayedexpansion
::设置WinRAR的安装目录路径
set WinRarDir=%ProgramFiles%\WinRAR
set Path=%Path%;%WinRarDir%
for %%a in (*.txt) do (
set "Fn=%%~na"
echo ,!Fs!,|findstr ",!Fn:~,10!," >nul || set "Fs=!Fn:~,10!,!Fs!"
)
for %%a in (!Fs!) do RAR a "%%~a" "%%~a*.txt"

复制代码

Batcher · 发表于 2022-6-29 18:15:34

回复 1# jieyuan_1981

@echo off
cd /d %~dp0
setlocal enabledelayedexpansion
REM 设置WinRAR的安装目录路径
set WinRarDir=%ProgramFiles%\WinRAR
set Path=%Path%;%WinRarDir%
for %%a in (*.txt) do (
for /f "delims=_" %%b in ("%%~na") do (
set "Fn=%%b"
echo ,!Fs!,|findstr ",!Fn!," >nul || set "Fs=!Fn!,!Fs!"
)
)
for %%a in (!Fs!) do (
WinRAR a "%%a.zip" "%%a_*.txt"
)

复制代码

jieyuan_1981 · 发表于 2022-6-29 19:56:44

回复 2# Batcher

winrar报错：没有文件被添加

Batcher · 发表于 2022-6-30 11:00:27

回复 3# jieyuan_1981

1. 请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

2. 代码里面加几个echo看看是哪个环节出了问题，例如：

@echo off
cd /d %~dp0
setlocal enabledelayedexpansion
REM 设置WinRAR的安装目录路径
set WinRarDir=%ProgramFiles%\WinRAR
set Path=%Path%;%WinRarDir%
for %%a in (*.txt) do (
echo 正在处理文件 %%a
for /f "delims=_" %%b in ("%%~na") do (
set "Fn=%%b"
echo ---!Fn!
echo ,!Fs!,|findstr ",!Fn!," >nul || set "Fs=!Fn!,!Fs!"
echo +++!Fs!
)
)
echo ===!Fs!
for %%a in (!Fs!) do (
WinRAR a "%%a.zip" "%%a_*.txt"
)

复制代码

jieyuan_1981 · 发表于 2022-6-30 11:53:37

回复 4# Batcher

感谢大神编译已通过。

jieyuan_1981 · 发表于 2022-7-3 12:00:15

回复 5# jieyuan_1981

我找到出错的原因了，可能是空格的问题。导致有的过不去。会把空格前后字符单独处理。请帮改一下。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 求助批处理如何按文件固定字符前字符命名压缩包名？