[文件操作] 【已解决】批处理怎样两两配对，找出落单的文件？

tpnybaby

各位朋友，大家好，最近在收集文件，同一个文件夹下，有形如
a.jpg   a.xml   b.jpeg    b.xml
c.png   c.xml    d.fir     d.jpg

这些文件之间会两两配对（前缀名是一样的，只是扩展名不一样）
但是可能就是存在只有单独一个的，比如只存在e.xml
想咨询一下大家，如何在cmd窗口中，用命令，实现遍历整个文件夹，找出单个的文件，然后放在待勘误的文件夹里？
目前没有较好的思路

terse

回复 1# tpnybaby
这个不难实现，但也要看文件名结构，看有没有特殊情况

terse

看结果正确不
修正一下

@echo off
for /f "tokens=*" %%i in ('dir /b /a-d') do if defined :.%%~ni (set ":.%%~ni=")else set ":.%%~ni=%%i"
set :.
pause
复制代码

@echo off&@echo off&setlocal enabledelayedexpansion
for /f "tokens=*" %%i in ('dir /b /a-d') do set /a "_%%~ni+=1"
for /f "tokens=*" %%i in ('dir /b /a-d') do if !_%%~ni! equ 1 if %%~ni neq %~n0 echo %%i
pause
复制代码

77七

如果不存在文件名中含有两个点号
试试

for /f "delims=" %i in ('dir /b /a-d') do ((md "待勘误" 2>nul) & (dir /b /a-d |find "%~ni." |find /v "%i" 1>nul 2>nul || move "%i" "待勘误"))
复制代码

命令有很多问题，命令错误。

tpnybaby

回复 2# terse


    嗯，之前已经通过一些管理和技术手段保证文件名中只有一个点号

tpnybaby

回复 4# 77七


    谢谢，真的可以，顺便问问，这句背后的逻辑是怎么样的？

tpnybaby

回复 3# terse


    好的，谢谢，我试试

aloha20200628

先用 dir/b/a-d/o:n 生成按文件名排序的简报，其中同名组数量为一者即lz所求...
如目录文件量较多，可将 dir/b/a-d/o:n 移出 for...()

setlocal enabledelayedexpansion
set "n=0" & set "lastF= "
for /f "delims=" %%F in ('dir/b/a-d/o:n') do (
    if "!lastF!" neq "%%~nF" (
	if !n! equ 1 (echo,!Flast!)
	set "n=0"
    )
    set/a "n+=1" &set "lastF=%%~nF" &set "Flast=%%F"
)
if !n! equ 1 (echo,!Flast!)
endlocal&pause&exit/b
复制代码

tpnybaby

回复 8# aloha20200628


    谢谢

77七

回复 6# tpnybaby

命令错误，我又写了一个，和3楼terse大佬的雷同。批处理

@echo off
md "待勘误" 2>nul
for /f "delims=" %%i in ('dir /b /a-d ^|findstr /xvc:"%~nx0"') do (
	if not defined _"%%~ni" (
		set _"%%~ni"=1
	) else (
		set _"%%~ni"=2
	)
)
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d ^|findstr /xvc:"%~nx0"') do (
	if "!_"%%~ni"!" equ "1" (
		move /y "%%i" "待勘误"
	)
)
endlocal
pause
复制代码