[已解决]自动解压缩的批处理中特殊字符的处理问题

thp2008

我有个自动解压的批处理。正常情况使用没有问题。
但是现在很多设置压缩密码的时候，喜欢加入一些特殊字符，这个时候，批处理就会出错。
像这种情况，有没有什么高手可以解决这个问题。

1. @echo off
   
2. echo.
   
3. set /p pass=请输入当前目录下压缩文件的解压密码：
   
4. set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
   
5. for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p%pass% -o- "%%i" "%%~dpi"

复制代码

比如密码中存在：^ ! & 类似这种，批处理，就识别密码不正确了。

感谢！

77七

参考下这个帖子
http://www.bathome.net/redirect. ... 3453&pid=258303

thp2008

回复 2# 77七

谢谢提供消息，我看后，研究了一下。自已写的好像还是不对，应该是怎么个写法。

1. @echo off
   
2. echo.
   
3. set /p pass=请输入当前目录下压缩文件的解压密码：
   
4. echo %pass%>PtempS.txt
   
5. winclip.exe -u -c PtempS.txt
   
6. set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
   
7. winclip.exe -p | for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p -o- "%%i" "%%~dpi"
   
8. del PtempS.txt
   
9. pause

复制代码

我一输入含有特殊字符的密码，就自动退出了。

我已下载了第三方工具winclip.exe在放同一目录。

77七

回复 3# thp2008


   不知道你怎么实际使用，使用set /p 输入密码吗？去掉-p 这样直接在弹框中输入密码可以吗？

1. @echo off
   
2. set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
   
3. for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -o- "%%i" "%%~dpi"
   
4. pause

复制代码

thp2008

回复 4# 77七

哦，可以这样，让他直接弹出密码输入框，我发现输入一个错误的密码或者不输，也会弹出。这样，什么密码就都可以输了。这也是个办法。

解压文件少，是没多大影响。

但是，就是文件解压文件较多的话，就比较麻烦一点，每一个文件，都要输。不能一个密码，应用到所有解压文件，还有对多重解压也是，要多次输入密码

如果用批处理解决的话，又要解决特殊字符，又要解决空格，全角，的问题。的确是比较麻烦。

不知道，还有没有，什么，完美的解决办法，或借助Powershell,VBS,第三方工具也行。

77七

回复 5# thp2008


   如果你需要解压的文件的密码都是相同的，可以用那个帖子的方法
我使用那个作者提供的密码

1. 1"@>::”#<$%"*%@“=?(*::"=*}{3"5*!！?%&|=6$”"4……-^_a=*a`~*()-_=+aa

复制代码

这个密码echo 后 密码中含有的变量会变成空值
所以不妨直接复制密码，然后点击脚本，解压期间不要操作剪贴板

1. @echo off
   
2. for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') (
   
3.         winclip -p|"C:\Program Files\7-Zip\7z.exe" x "%%i" -o"%%~dpi" 1>nul
   
4. )
   
5. pause

复制代码

thp2008

我找到去年，我问过的一个类似的问题，用了flashercs帮我提供的一种方法，我改了一下，发现可以使用。
就是先把密码保存在一个文本文件中。

对于较多的解压文件，就可以用这种方法，因为不需要第三方工具，更方便。如果文件较少，就直接在弹出的对话框中粘贴就好了。

提示：本方法可以处理含有特殊字符的字符串，在批处理中作为变量，前提是把密码存放在tsPass.txt中。密码如果有中文或全角，就要保存了ANSI格式。

1. @echo off
   
2. set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
   
3. echo.
   
4. for /f "delims=" %%a in (tsPass.txt) do (
   
5.     set pass=%%a
   
6.     setlocal EnableDelayedExpansion
   
7.     set pass=!pass:"=""!
   
8. for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p"!pass!" -o- "%%i" "%%~dpi"
   
9.     endlocal
   
10. )
    
11. exit

复制代码

如果可以不手工创建文件就完美了。

thp2008

回复  thp2008


   如果你需要解压的文件的密码都是相同的，可以用那个帖子的方法
我使用那个作者提供 ...
77七 发表于 2023-6-22 13:25

我试了一下，这种办法，好像对WINRAR无效，不知道是不是我写错了。

我先把密码，复制到剪贴板，再运行下面的批处理。不能自动粘贴，还是弹出对话框。

1. @echo off
   
2. set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
   
3. for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do (winclip -p |  "%rar%" x -y -o- "%%i" "%%~dpi")
   
4. pause

复制代码

77七

回复 8# thp2008


   7楼的方法挺好的。winrar可能不支持吧。

buyiyang

就是预处理的问题，直接给%pass%加上双引号就行了。或者开变量延迟setlocal enabledelayedexpansion，把%pass%改成!pass!

1. setlocal enabledelayedexpansion
   
2. for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p"!pass!" -o- "%%i" "%%~dpi"

复制代码

thp2008

能不能在7楼的基础上，加上一个粘贴密码后，自动创建tsPass.txt的文件呀，我试着用批处理创建，不行，只要有全角符号，或者^等特殊字符就不行了。不知道，用VBS或者其它什么方式，可不可以，做个输入框，加在批处理前面，这样就自动创建tsPass.txt。比较方便一点。学习使用脚本，本身就是为了方便。

77七

回复 11# thp2008


  

1. @echo off
   
2. set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
   
3. for /f "delims=" %%a in ('winclip -p') do (
   
4.         set "pass=%%a"
   
5.         setlocal EnableDelayedExpansion
   
6.         set "pass=!pass:"=""!"
   
7.         for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p"!pass!" -o- "%%i" "%%~dpi"
   
8.         endlocal
   
9. )
   
10. exit

复制代码

特殊字符使用set /p ，我试了直接闪退，在7楼的代码上修改，复制后直接点脚本就行了，不用粘贴
“特殊字符使用set /p ，我试了直接闪退”，说法有误！

thp2008

回复  thp2008


    特殊字符使用set /p ，我试了直接闪退，在7楼的代码上修改，复制后直接点脚本就行 ...
77七 发表于 2023-6-22 15:37

   这个方法不错，我测试了，可以。

buyiyang

回复 12# 77七


    哪个特殊字符会让set /p闪退？

77七

回复 14# buyiyang


   大佬，您试试这个

1. 1"@>::”#<$%"*%@“=?(*::"=*}{3"5*!！?%&|=6$”"4……-^_a=*a`~*()-_=+aa

复制代码

这个就是2楼那个帖子作者试验的密码
我又试了一下，开启延迟变量后，再使用set /p 就不会闪退了
多次测试，只有开启延迟变量后，使用叹号才能正确echo 这个字符串，

1. @echo off
   
2. set "rar=%ProgramFiles%\WinRAR\WinRAR.exe"
   
3. for /f "delims=" %%a in ('winclip -p') do (
   
4.         set "pass=%%a"
   
5.         setlocal EnableDelayedExpansion
   
6.         set "pass=!pass:"=""!"
   
7.         for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p"!pass!" -o- "%%i" "%%~dpi"
   
8.         endlocal
   
9. )
   
10. pause
    
11. 
    
12. for /f "delims=" %%a in ("1") do (
    
13.         set /p pass=
    
14.         setlocal EnableDelayedExpansion
    
15.         set "pass=!pass:"=""!"
    
16.         for /f "delims=" %%i in ('dir /b /s *.rar *.001 *.7z *.zip') do "%rar%" x -y -p"!pass!" -o- "%%i" "%%~dpi"
    
17.         endlocal
    
18. )
    
19. pause

复制代码

使用上面的密码压缩的文件，再同一个批处理文件中，使用上面的代码第一段winclip -p 获取密码解压成功，使用第二段 set /p 输入密码，提示密码错误。