77七

回复 14# qixiaobin0715

谢谢大佬指点！
  

@echo off
for /l %%l in (2,1,2000000) do (
	echo 1
	goto :2
)
:2
echo 2
pause
复制代码

像call for /l 用的可能少一点，但像上面的代码，我有时候还是会用到的，以后得谨慎使用过大数字。

adfs945

回复 2# BingjianREMIX

非常感谢指导，接下来我根据自己水平稍微调整一下，因为个主要是针对TXT文件，我是要所有文件。

aloha20200628

如何尽快跳出 for /L 循环》又是一个经典问题。
外网dostips.com就此曾有多次讨论，现简化出三个题型说明一些思路的对比结果，给本坛有兴趣者品味参考...
基本上是毙掉了在循环体内 call :xxx 子过程的方法，因其低效繁复。
个人感觉题型一类似 do-while 循环结构，也许更有实用价值。

::题型一，采用开关变量 + if 语块包裹循环体》耗时约2s
@echo off
set "#break="
for /L %%n in (1,1,320000) do if not defined #break (
   REM ”其他命令“
   set "n=%%n" &set #break=1)
echo,%n%
::exit/b

::题型二，采用 if 语块包裹循环体》约耗时1.5s
@echo off
for /L %%n in (1,1,320000) do if %%n equ 1 (
    REM ”其他命令“
    set "n=%%n" &goto[outLoop])
:[outLoop]
	echo,%n%
	::exit/b

::题型三，不采用 if 语块包裹循环体》耗时约12s
@echo off
for /L %%n in (1,1,3200000) do (
	REM ”其他命令“
	set "n=%%n" &goto[outLoop])
:[outLoop]
	echo,%n%
	::exit/b
复制代码

adfs945

回复 3# 77七

非常感谢指导，测试OK。
另外我又追加了循环10秒运行一回，但是失败了，请继续指导一下。

@echo off

set INTERVAL=10

:Again

rem 批处理保存为ansi编码格式
set "folder1=C:\Users\dmns25163\Desktop\AAA"
set "folder2=C:\Users\dmns25163\Desktop\BBB"
for %%a in ("%folder1%\*.*") do (
	if not exist "%folder2%\%%~nxa" (
		move "%%a" "%folder2%"
	) else (
		call :1
	)
)
pause
exit

	:1
	for /l %%l in (2,1,200) do (
		if not exist "%folder2%\%%~na(%%l)%%~xa" (
			move "%%a" "%folder2%\%%~na(%%l)%%~xa"
			exit /b
		)
	)

    
    del try.txt

    timeout %INTERVAL%
    
    goto Again  
复制代码

adfs945

回复 5# 447219071


    感谢指导，学习了。

adfs945

回复 4# Batcher


    感谢大佬指点，小白努力学习中。

BingjianREMIX

回复 5# 447219071


    怎么有点像GPT的

BingjianREMIX

回复 17# adfs945


    没事把所有后缀改动一下就行,像*.*

Batcher

回复 19# adfs945


timeout %INTERVAL%
goto Again
你把这两行挪到第17行下面试试

Batcher

回复 18# aloha20200628


    是不是复制错了，为何一和二是4个0，三是5个0？

77七

回复 18# aloha20200628


   
谢谢老师指点！经过我粗略测试，发现三种方法，仍然没有避免for /l 产生不必要的迭代，细微的时间差别，可能是脚本自身的效率影响。

77七

回复 19# adfs945


   既然你需要如此频繁使用，将标签部分修改为 set /a +goto 好了，避免 for /l 影响效率，和for /l 数字固定问题。

@echo off

set INTERVAL=10

:Again

rem 批处理保存为ansi编码格式
set "folder1=C:\Users\dmns25163\Desktop\AAA"
set "folder2=C:\Users\dmns25163\Desktop\BBB"
for %%a in ("%folder1%\*.*") do (
	if not exist "%folder2%\%%~nxa" (
		move "%%a" "%folder2%"
	) else (
		set n=1
		call :1 "%%a"
	)
)
timeout %INTERVAL%
goto Again

pause
exit

	:1
	set /a n+=1
	if not exist "%folder2%\%~n1(%n%)%~x1" (
		move "%~1" "%folder2%\%~n1(%n%)%~x1"
		exit /b
	) else (
		goto :1
	)
复制代码

qixiaobin0715

回复 27# 77七
后面代码这样即可：

:1
set /a n+=1
if exist "%folder2%\%~n1(%n%)%~x1" goto :1
move "%~1" "%folder2%\%~n1(%n%)%~x1"
复制代码

77七

回复 28# qixiaobin0715


   

谢谢大佬指点！大佬的代码更加直观易读。

aloha20200628

代码已作如下订正。看那些纯P老玩家已经不深究 for/L 能否立即退出循环的问题了，切磋的只是如何“尽快”退出的“妙计高招”。for/L 的循环量一旦过万，钝感即现，上十万就相当吃力了... 好在批处理脚本勉为其难的企业级(大数量规模)应用，都有更高效的成熟解决方案，仅脚本而言，前有vbs/jscript/mshta/awk/...，后有powershell/python/... 着实省去了以往纯P非要在“螺蛳壳里作道场”的艰难曲折了...

::题型一》采用开关变量+if 语块包裹循环体 不用goto》耗时约2s
set "#break="
for /L %%n in (1,1,320000) do if not defined #break (set "n=%%n" &set #break=1)
echo,%n%
pause &exit/b

::题型二》采用 goto+if 语块包裹循环体》耗时1.6s
for /L %%n in (1,1,320000) do if %%n equ 1 (set "n=%%n" &goto[outLoop])
:[outLoop]
	echo,%n%
pause &exit/b

::题型三》采用 goto，不采用 if 语块包裹循环体》耗时约1s
for /L %%n in (1,1,320000) do (set "n=%%n" &goto[outLoop])
:[outLoop]
	echo,%n%
pause &exit/b
复制代码