[文件操作] 求助批处理移动遇相同向上递增计数

娜美

@echo off
setlocal enabledelayedexpansion
set path1=C:\2
set path2=D:\3
for /r %path1% %%a in (*.txt) do (
if not exist "%path2%\%%~nxa" (move "%%a" "%path2%\") else (
if not exist "%path2%\%%~na(2)%%~xa" (move "%%a" "%path2%\%%~na(2)%%~xa") else (
set n=2
for /f "delims=" %%b in ('dir /b /a-d %path2%\*^|findstr /r /be /c:"%%~na ([0-9][0-9]*)%%~xa"') do (
set "str=%%~nb"
set "m=!str:%%~na (=!"
set "m=!m:)=!"
if !m! gtr !n! set /a n=m
)
set /a n+=1
move "%%a" "%path2%\%%~na(!n!)%%~xa"
)
)
)
endlocal
pause
移动文件时遇相同向上计数递增, 现在是感觉不太科学
新建文本文档(2).txt
新建文本文档(2)(2).txt
新建文本文档(2)(2)(2).txt
新建文本文档(2)(2)(2)(2).txtCOPY

希望写成像windows那样向上计数递增
新建文本文档.txt
新建文本文档 (2).txt
新建文本文档 (3).txt
新建文本文档 (4).txt
新建文本文档 (5).txt

smss

@echo off&setlocal enabledelayedexpansion&set "a=c:\2"&set "b=d:\3"
for /r "%a%" %%i in (*)do set n=0&set "f=%%~ni"&set "e=%%~xi"set "M=%%i"&set "W=!b!\!f!!e!"&call :loop
pause
:loop
if not exist "!W!" (move "!M!" "!W!")else set /a n+=1&set "W=!b!\!f!(!n!)!e!"&goto :loop
goto :eofCOPY

77七

论坛内很多此类问题帖子

http://www.bathome.net/thread-36991-1-1.html

qixiaobin0715

类似的，4楼代码：
http://bbs.bathome.net/thread-57444-1-1.html

aloha20200628

回复 1# 娜美

以下代码可处理源文件名与目标文件名的重复情况-举例如下：
        源文件夹中要移至目标文件夹的文件是》abc.txt，abc (2).txt
        目标文件夹已存在的文件是》abc.txt，abc (2).txt，abc (3).txt
        处理结果是目标文件夹新增两个文件》abc (4).txt，abc (5).txt
代码第12行数字 -5 管控文件名序号长度（2-999），绝对值增加则长度增加

@echo off &setlocal enabledelayedexpansion
set "path1=C:\2" &set "path2=D:\3" &pushd "!path1!"
for /f "delims=" %%F in ('dir /b/a-d *.txt *.rar *.zip *.jpg *.mp4') do (
	if not exist "!path2!\%%~nxF" (move "%%F" "!path2!\") else (
		(call :get#nF "%%~nF" nFn n) & (call :check#2F nFn "%%~xF" !n! qF)
		move "%%F" "!path2!\!nFn!(!qF!)%%~xF"
	)
)
popd&endlocal&exit/b
:get#nF //REM 获取源文件名序号锚点
	set "_nF=%~1" &if "!_nF:~-1!" neq ")" (set "%~2=%~1 " &set "%~3=2" &exit/b)
	set "_k=" &for /L %%k in (-2,-1,-5) do (
		set "c=!_nF:~%%k,1!"
		if "!c!"=="(" (set "%~2=!_nF:~0,%%k!" &set "%~3=!_k!" &exit/b) else (
			if "!c!" geq "0" if "!c!" leq "9" set "_k=!c!!_k!"
		)
	)
	exit/b
:check#2F //REM 验证目标文件名不重复序号
	set "_qF=%~3"
	:[Loop]
	if exist "!path2!\!%~1!(!_qF!)%~2" (set/a "_qF+=1" &goto[Loop])
	set "%~4=!_qF!" &exit/bCOPY

娜美

各位大哥哥
以上都不符合哦

所有命令或连接都试了,  仅只能执行移动文件1次,  如果再次执行移动命令 或 不断重复执行命令就失效了, 说明移动文件遇到相同名称都不具有向上递增计数命名功能
还需考虑多扩展文件类型txt jpg rar zip 等
for /r %path1% %%a in (*.txt *.rar) do (....)

aloha20200628

回复 6# 娜美

楼主的实际情况与5楼代码的测试举例有何区别？

娜美

回复 7# aloha20200628


   5楼还没测, 我回复时还没看到有代码上来, 我马上试试哈

娜美

回复 5# aloha20200628


   大哥哥这个写得很好,  计数递增命名格式正确,  虽然我看不太懂.  看上去很科学,   但扩展名只能一种*.txt吗 ?   考虑一下增加支持多扩展名就好了 *.txt rar zip jpg mp4 等等

请再修改一下我试试看 thanks
移动当前目录及子目录文件
for /r %path1% %%a in (*.txt *.rar *.zip *.jpg) do (....)

aloha20200628

回复 9# 娜美

订正了5楼代码，增加了多种文件类型匹配...

77七

回复 2# smss


   参考：不要在批处理for命令内部定义标签

77七

回复 6# 娜美


   我不信请提供 path1、path2下的文件名，我试试。

娜美

回复 12# 77七



1-4楼的连接及所有子连接都试过  用的最简单文件名称测试的, 没有任何特殊符号的,   

D:\A
D:\BCOPY

D:\A\新建文本文档.txt
D:\A\1.txtCOPY

D:\B\新建文本文档.txt
D:\B\1.txtCOPY

娜美

回复 5# aloha20200628


   谢谢,  好了

77七

回复 13# 娜美


   我测试了http://www.bathome.net/redirect.php?goto=findpost&;ptid=36991&pid=173326，是对的，其余未测试。使用代码需要一些基础知识，比如 更改工作路径（cd）、copy改move等。

@echo off
rem "http://www.bathome.net/redirect.php?goto=findpost&ptid=36991&pid=173326"
cd /d "d:\A"
for /r %%i in (*) do (
    set "strName=%%~nxi" & set "n="
    call :CP "%%i"
)
pause & exit
 
:CP
if not exist "d:\B\%strName%" move "%~1" "d:\B\%strName%" & goto :EOF
if exist "d:\B\%strName%" set /a n+=1
set "strName=%~n1(%n%)%~x1"
goto :CPCOPY