[文件操作] 批处理如何批量替换文件名？

aabout2008

比如当前文件夹下有无数张照片：

a1.1.jpg
a1.2.jpg
a1.3.jpg
a1.4.jpg
a1.5.jpg
a1.6.jpg
……
a1.999.jpg

我要将文件名中的a替换成b ：
b1.1.jpg
b1.2.jpg
b1.3.jpg
b1.4.jpg
b1.5.jpg
b1.6.jpg
……
b1.999.jpg

要实现的效果是:在当前文件夹下，点击后就将原来所有的文件改名，且不论文件夹下是什么格式的文件，不局限于当前示例的jpg。
思路就是在bat，可以设置一个字符  替换成另一个字符，后期可以按需修改。
批处理获取路径就是当前文件夹目录，不要使用绝对路径。

批处理改名要排除批处理本身，如果目录下这个执行的批处理是a1.1.bat  不会修改成b1.1.bat

aabout2008

@echo off
set folder_path=%~dp0
set output_file=%~dp0\Output.txt
dir /b "%folder_path%\*" > "%output_file%"
pause
复制代码

我在网上找到的只能实现这种功能。
这个获取当前目录下的文件名，如何排除Output.txt  和批处理本身呢？

77七

@echo off
rem 保存为ansi编码
cd /d "%~dp0"
set "oldstr=a"
set "newstr=b"
for /f "delims=" %%i in ('dir /b /a-d') do (
	if "%%i" neq "%~nx0" (
		set n=%%~ni
		if defined n (
			call ren "%%i" "%%n:%oldstr%=%newstr%%%%%~xi"
		)
	)
)
pause
复制代码

aabout2008

77七 发表于 2024-11-21 12:50

效果不错，但是不能改成中文，改中文就乱码。如果连中文都能改就更好了。

aabout2008

回复 3# 77七

谢谢您，不能改成中文，改中文会乱码。如果连中文都能改就更好了。

77七

回复 5# aabout2008


   参考 链接

qixiaobin0715

ren a*.jpg b*.jpg

aloha20200628

回复 5# aabout2008

以下两版批处代码均可替换文件名中的中文字符（任何位置），只要确保第一版批处存为简中（936）编码（如记事本的ANSI编码），第二版批处存为utf-8编码即可，总之，保存脚本的编码要与脚本行头采用的码页保持一致。实际上用第一版就可以了...

第一版

@echo off &chcp 936>nul
set "s1=自行车" &set "s2=坦克车"
for /f "delims=" %%F in ('dir /b/a-d *%s1%*') do (
	set "F=%%~nF" &setlocal enabledelayedexpansion
	(ren "%%F" "!F:%s1%=%s2%!%%~xF") &endlocal)
pause&exit/b
复制代码

第二版

@echo off &chcp 65001>nul
set "s1=自行车" &set "s2=坦克车"
for /f "delims=" %%F in ('dir /b/a-d *%s1%*') do (
	set "F=%%~nF" &setlocal enabledelayedexpansion
	(ren "%%F" "!F:%s1%=%s2%!%%~xF") &endlocal)
pause&exit/b
复制代码

备注》代码中对文件名的字符串替换是整体替换，即出现在任何位置的目标字符串均被替换；对英文字符替换的匹配模式为不区分大小写

aabout2008

回复 8# aloha20200628

效果堪称完美，只有一点没有排除批处理本身。
如我上面的示例，a.bat 运行后，会变成b.bat。