把文本第一行移动到&字符前面的批处理怎么写？

s091200

把文本第一行移动到&字符前面的批处理怎么写谢谢

Batcher

回复 1# s091200


请给一个真实的例子说明一下你的需求吧，比如操作之前是怎样的，操作之后变成啥样？
如果需要上传文件，请用使用网盘。

如果需要上传截图，可以找个图床，例如：
http://bbs.bathome.net/thread-60985-1-1.html

s091200

回复 2# Batcher


    处理前的样子
L14010
M: Q420B
LP: 4935
SA140 SB140 TA10 TB10
DA25.5 X40 TR45
DA25.5 X4895 TR45
MKFF-AC-JCK29201C & X420
M30
END
处理后的样子
M: Q420B
LP: 4935
SA140 SB140 TA10 TB10
DA25.5 X40 TR45
DA25.5 X4895 TR45
MKFF-AC-JCK29201C L14010& X420
M30
END
把第一行 L14010 移动到 & 字符前

77七

回复 3# s091200


  

1. @echo off
   
2. cd /d "%~dp0"
   
3. set /p str=<"1.txt"
   
4. (for /f "useback skip=1 delims=" %%i in ("1.txt") do (
   
5.         set _str=%%i
   
6.         setlocal enabledelayedexpansion
   
7.         echo !_str:^&=%str%^&!
   
8.         endlocal
   
9. )) > "2.txt"
   
10. pause

复制代码

aloha20200628

回复 3# s091200

给一个用 sed.exe 简化的批处版本
可从本坛第三方直接下载 sed.exe 落地即用（http://bcn.bathome.net/s/tool/index.html?key=sed），与批处脚本和 1.txt 同目录

1. 
   
2. @echo off &setlocal &set/p v=<1.txt
   
3. more +1 1.txt|sed "s/&/%v%&/g">2.txt
   
4. type "2.txt"&pause&exit/b
   

复制代码

s091200

回复 4# 77七


    非常感谢！还是无法进行多个文件同时修改。

Batcher

回复 6# s091200


    请更新顶楼的需求，写清楚：多个文件同时修改。

77七

回复 6# s091200

1. @echo off
   
2. cd /d "%~dp0"
   
3. for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
   
4.         call :1 "%%i"
   
5. )
   
6. pause
   
7. exit
   
8. 
   
9.         :1
   
10.         set /p str=<"%~1"
    
11.         (for /f "useback skip=1 delims=" %%i in ("%~1") do (
    
12.                 set _str=%%i
    
13.                 setlocal enabledelayedexpansion
    
14.                 echo !_str:^&=%str%^&!
    
15.                 endlocal
    
16.         )) > "%~n1_2%~x1"
    
17.         rem move "%~n1_2%~x1" "%~1"
    
18.         exit /b

复制代码

aloha20200628

回复 1# s091200

5楼代码订正如下，存为 test.bat 运行，结果会将当前目录下凡是包含 ‘&’ 字符的 *.txt 文件逐一处理 》第一行被删除，其中有 '&' 字符的位置被置换为 ‘第一行字符串+&’，新文件名被更名为 *.new.txt

1. 
   
2. @echo off &setlocal
   
3. for /f "delims=" %%F in ('dir /b/a-d *.txt') do find "&" "%%F">nul&&(
   
4.    set/p "v="<"%%F" &setlocal enabledelayedexpansion
   
5.    more +1 "%%F"|sed.exe "s/&/!v!&/">"%%~nF.new%%~xF"
   
6.    endlocal)
   
7. pause&exit/b
   

复制代码

s091200

谢谢大家！问题以解决

s091200

回复 8# 77七


    大神帮帮忙子文件夹里的处理不了，能不能帮我写一个把子文件夹里的文件一块修改的批处理 谢谢！

77七

回复 11# s091200


  

1. @echo off
   
2. cd /d "%~dp0"
   
3. for /f "delims=" %%i in ('dir /b /s /a-d *.txt') do (
   
4.         call :1 "%%i"
   
5. )
   
6. pause
   
7. exit
   
8. 
   
9.         :1
   
10.         set /p str=<"%~1"
    
11.         (for /f "useback skip=1 delims=" %%i in ("%~1") do (
    
12.                 set _str=%%i
    
13.                 setlocal enabledelayedexpansion
    
14.                 echo !_str:^&=%str%^&!
    
15.                 endlocal
    
16.         )) > "%~dpn1_2%~x1"
    
17.         rem move "%~dpn1_2%~x1" "%~1"
    
18.         exit /b

复制代码