CMD脚本中，不启用延迟扩展，怎样取得IF复合语句内正确的ErrorLevel值？谢谢！

Shuye

不启用延迟扩展

Set "Tar=3"
IF Defined Tar (
   del Abc.abc
   Echo ErrorLevel===%ErrorLevel%
)

Abc.abc是不存在的，这时的ErrorLevel值应该是1，输出却是0。
怎样才能得到ErrorLevel===1？
谢谢啦！

77七

逃脱预处理Call echo %%errorlevel%%
判断if errorlevel 1 echo error

Shuye

逃脱预处理Call echo %%errorlevel%%
判断if errorlevel 1 echo error
77七 发表于 2025-7-11 19:47

谢谢 77七 兄！

Set "Tar=3"
IF Defined Tar (
   del Abc.abc
   Call echo %%errorlevel%%
)

输出还是0。

77七

回复 3# Shuye
应该是del 命令的设定问题。初步试了下，只有非法文件名，errorlevel=123，其余都是0。

Shuye

回复  Shuye
应该是del 命令的设定问题。初步试了下，只有非法文件名，errorlevel=123，其余都是0。
77七 发表于 2025-7-11 20:25

谢谢 77七 兄！

输出的这个0，估计是IF体外， Set "Tar=3" 的返回值。

aloha20200628

回复 1# Shuye

可参考英文老帖（https://stackoverflow.com/questi ... s/34987886#34987886）一共挂了5张列表说明 CMD 常用命令的错误代码值（errorlevel），其中 del 只有两种结果，一是无参数（归于 '语法错误'）或参数错误（归于 '无效开关'）时会将 errorlevel 设为非零值，其余（无论目标文件存在与否）皆为零 ...

77七

回复 5# Shuye


   简单测试

1. @echo off
   
2. rem del失败 改变返回值
   
3. md "|"
   
4. echo %errorlevel%
   
5. del "abc.abc"
   
6. echo %errorlevel%
   
7. 
   
8. rem del成功 改变返回值
   
9. echo=
   
10. cd.>abc.abc
    
11. md "|"
    
12. echo %errorlevel%
    
13. del "abc.abc"
    
14. echo %errorlevel%
    
15. pause

复制代码

Shuye

这个估计与 del 无关，应该是 IF 惹的祸。
我们换个命令，copy，其中的 Abc.abc 是不存在的。

Set "Tar=3"
copy Abc.abc Abc22.abc
Echo ErrorLevel22===%ErrorLevel%

输出：ErrorLevel22===1，这个是正确的，应该是 copy 的返回值。


再将 copy 放入 IF 体内：

Set "Tar=3"
IF Defined Tar (
   copy Abc.abc Abc22.abc
   Echo ErrorLevel33===%ErrorLevel%
)

输出：ErrorLevel33===0，这个是错的，它不是 copy 的返回值，应该是 Set "Tar=3" 的返回值。

也就是说，IF 体内的 %ErrorLevel%，不是 IF 体内命令的返回值，而是 IF 体之前最后一条命令的返回值。

IF 体内，怎样取得正确的 %ErrorLevel% ？
前提是不启用延迟扩展。如果启用延迟扩展，!ErrorLevel!值都是正确的。

aloha20200628

回复 8# Shuye

  首先这是由于 '预处理' 的结果》即复合语块（被圆括号包裹的一组代码或被 & 链接的一组代码）被解释执行前会对其内的所有 %var% 变量预先赋值。因此，8楼代码 if 体内的 %errorlevel% 总是 if 之前的取值。
  其次再来谈 if 体内有效采用错误返回值的方法》
  一。为直接规避预处理拦截，采用 !errorlevel! 肯定是有效的。
  二。采用保留关键词 errorlevel 而非 !errorlevel! 变量，示例代码如下。
  三。采用 &&和 || 运算符，示例如下。
  但如一些老帖中所述，被多年的实用结果验证是第一种方法的灵活性和可靠性更好，因而被优先推荐...

  备注》从6楼英文老帖挂表中查有 copy 命令返回值类型，当目标文件不存在或参数错误其返回值=1，其余均返回零。
方法二

1. 
   
2. @echo off & set "tar=3"
   
3. if defined tar (
   
4.    copy /y 1.txt 2.txt>nul 2>nul
   
5.    if errorlevel 1 (echo,复制失败) else echo,复制成功
   
6. )
   
7. pause&exit/b
   

复制代码

方法三

1. 
   
2. @echo off & set "tar=3"
   
3. if defined tar (
   
4.    copy /y 1.txt 2.txt>nul&&echo,复制成功||echo,复制失败
   
5. )
   
6. pause&exit/b
   

复制代码

77七

1楼的方法获取的的确是if 外的errorlevel，这个值应该是脚本的初始值，echo、set 成功均不会改变errorlevel值。
2楼已经说明了方法。3楼代码正确，获取的是del 命令的errorlevel值，但是由于del本身设定问题导致errorlevel仍为0，4楼已经说明。

删除前必须有文件，删除后文件消失，可以试试以下代码

1. @echo off
   
2. chcp 936 >nul
   
3. del "#" 2>&1 | find /v "删除文件 -"
   
4. if errorlevel 1 (
   
5.         echo 删除成功
   
6. ) else (
   
7.         echo 存在删除失败的文件(或属性问题 或文件被占用^) 或文件不存在(或非法文件名^) 或参数错误
   
8. )
   
9. pause

复制代码

Shuye

谢谢 aloha20200628 兄、77七 兄！

类似于 del、copy 的内部、外部命令很多，
有没有一种通用的方法？
就像 !ErrorLevel! 那样的。

aloha20200628

回复 11# Shuye

其实都写在9楼了。再问就说要楼主回答了 - 为何不想采用 !errorlevel! 呢？

77七

看来盖了好几楼都是无效沟通。
至少在我的实际使用中，if errorlevel 1和 if !errorlevel! geq 1 是没区别的。
这种用法从2楼就开始提及，楼主却还在反复追问...

Batcher

回复 8# Shuye

输出：ErrorLevel33===0，这个是错的，它不是 copy 的返回值，应该是 Set "Tar=3" 的返回值。

你的猜测是错误的。
并非每个命令执行完毕之后都会改变errorlevel的值，具体信息可以仔细阅读6楼链接。

Batcher

批处理各命令错误返回值errorlevel一览
http://bbs.bathome.net/thread-3603-1-1.html

errorlevel的范围是[-2147483648,2147483647]
https://stackoverflow.com/questi ... egative-error-codes

不同的命令设置errorlevel值是不一样的
https://stackoverflow.com/questi ... s/34987886#34987886

批处理中errorlevel的几点猜测
http://bbs.bathome.net/thread-14277-1-1.html