***为什么批处理代码只能修改文件夹名称不能修改各种类型文件名称

zsww258

@echo off
chcp 65001 >nul
setlocal enabledelayedexpansion

:: 定义随机字符串长度
set "length=8"

:: 先处理子文件夹
for /d /r %%i in (*) do (
    :: 生成随机字符串
    set "rand="
    for /l %%j in (1,1,!length!) do (
        set "chars=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"
        set /a "randnum=!random!%%62"
        for %%k in (!randnum!) do set "rand=!rand!!chars:~%%k,1!"
    )
    :: 获取文件夹所在路径和原名称
    set "folderpath=%%~dpi"
    set "foldername=%%~nxi"
    :: 避免重命名当前脚本所在目录
    if not "!folderpath!!foldername!"=="%~dp0." (
        :: 重命名文件夹
        ren "%%i" "!rand!" >nul 2>&1
    )
)

:: 处理文件
for /r %%i in (*) do (
    :: 跳过当前批处理文件
    if not "%%~nxi"=="%~nx0" (
        :: 生成随机字符串
        set "rand="
        for /l %%j in (1,1,!length!) do (
            set "chars=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"
            set /a "randnum=!random!%%62"
            for %%k in (!randnum!) do set "rand=!rand!!chars:~%%k,1!"
        )
        :: 保留文件扩展名
        ren "%%i" "!rand!%%~xi" >nul 2>&1
    )
)

endlocal
echo 重命名完成！
pause >nul

aloha20200628

回复 1# zsww258

系统不允许文件更名的常见情况如下：
一。文件被占用
二。文件被权限保护
三。有重名文件存在
针对第三者可试用以下代码解决...
另：遵循批处理脚本编写规范，建议将复合代码块（典型如 for 和 if 语句）中的注释行前缀 :: 改为 rem 为妥...

1. 
   
2. @echo off &setlocal enabledelayedexpansion &set "length=8"
   
3. :: 因文件名不区分大小写，以下字符集可减为36个
   
4. set "chars=0123456789abcdefghijklmnopqrstuvwxyz"
   
5. :: 仅处理文件
   
6. for /r %%i in (*) do (
   
7.     rem 跳过当前批处理文件
   
8.     if not "%%~nxi"=="%~nx0" call :xxx "%%i" )
   
9. pause&exit/b
   
10. :xxx
    
11.    :: 生成随机字符串
    
12.    set "rand="
    
13.    for /l %%j in (1,1,!length!) do (
    
14.       set /a "randnum=!random!%%36"
    
15.       for %%k in (!randnum!) do set "rand=!rand!!chars:~%%k,1!" )
    
16.    :: 保留文件扩展名
    
17.    if exist "%~dp1!rand!%~x1" goto :xxx
    
18.    ren "%~1" "!rand!%~x1" &exit/b
    

复制代码

aloha20200628

回复 1# zsww258

还有一种文件更名时常见的报错情况》是启用延迟变量后，路径文件名中包含了如 !^& 等特殊字符，如是，须改用以下代码解决...

1. 
   
2. @echo off &setlocal &set "length=8"
   
3. :: 因文件名不区分大小写，以下字符集可减为36个
   
4. set "chars=0123456789abcdefghijklmnopqrstuvwxyz"
   
5. :: 仅更名文件
   
6. for /r %%i in (*) do (
   
7.     rem 跳过当前批处理文件
   
8.     if not "%%~nxi"=="%~nx0" (
   
9.        set "F=%%i" &set "pF=%%~dpi" &set "xF=%%~xi"
   
10.        setlocal enabledelayedexpansion
    
11.        call :xxx &endlocal ))
    
12. pause&exit/b
    
13. :xxx
    
14.    :: 生成随机字符串
    
15.    set "rand="
    
16.    for /l %%j in (1,1,!length!) do (
    
17.       set /a "randnum=!random!%%36"
    
18.       for %%k in (!randnum!) do set "rand=!rand!!chars:~%%k,1!" )
    
19.    :: 保留文件扩展名
    
20.    if exist "!pF!!rand!!xF!" goto :xxx
    
21.    ren "!F!" "!rand!!xF!" &exit/b
    

复制代码