[文件操作] 如何用批处理搜索文件夹，并显示出该文件夹路径？

zcy85611

比如说我的I386文件夹是在c:\aaa\bbb\i386下，请问一下如果才能用批处理搜索出这个文件夹，并显示出路径呢？


比如I386是在c:\aaa\bbb下，或者是在d:\ccc下，都可以用这个批处理文件找到I386文件夹，并把路径显示出来。


我目前只会用这种方法来搜索I386文件夹，但是这个方法必须要指定多级目录的位置才行，不太方便。麻烦大家帮忙把这个批处理改成我想要的那种，谢谢！

@echo off
set TargetPath=\aaa\bbb\I386
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist "%%a:%TargetPath%" (set NeededPath=%%a:%TargetPath%)
)
echo !NeededPath!
pause
复制代码

[ 本帖最后由 zcy85611 于 2009-11-29 10:54 编辑 ]

Seter

@echo off
for %%j in (q w e r t y u i o p a s d f g h j k l z x c v b n m) do (
if exist %%j:\nul (
for /f "delims=" %%i in ('dir %%j:\i386 /a-d /b /s /a 2^>nul') do echo %%i
)
)
pause
复制代码

是这个意思吗

bluewing009

这种网吧里的路径都不一样 ，所以我写了这个，更广泛一点。
可以针对普通要求的搜索。嘿嘿  直接把例子发上来了，  有必要的话就改改。

@echo off
setlocal enabledelayedexpansion
for /f "delims=\" %%i in ('fsutil fsinfo drives^|find /v ""') do (
    call set a=%%i
    for /f "delims=" %%j in ('dir /a /b /s !a:~-2!\War3.exe') do (
           echo %%j
           copy "%~dp0\冰峰王座\真三国无双3.9d_AI.w3x" "%%~dpj\maps\"
           copy "%~dp0\冰峰王座\DotA Allstars AI CN.w3x" "%%~dpj\maps\"
                     
)
)
echo 完成
pause
复制代码

zcy85611

原帖由 Seter 于 2009-11-29 10:29 发表
@echo off
for %%j in (q w e r t y u i o p a s d f g h j k l z x c v b n m) do (
if exist %%j:\nul (
for /f "delims=" %%i in ('dir %%j:\i386 /a-d /b /s /a 2^>nul') do echo %%i
)
)
pause是这个意思 ...

这位朋友，不好意思，是我没有描述清楚，是这样的

我是意思是说无论i386在哪个盘的哪一级目录下，都可以用批处理搜索出I386文件夹，并显示出它的路径
比如I386是在c:\aaa\bbb下，或者是在d:\ccc下，都可以用这个批处理文件找到I386文件夹，并把路径显示出来。

batman

@echo off
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do (
     if not defined str for /f "delims=" %%b in ('dir /ad /b /s %%a:\i386') do set "str=%%b"
)
echo %str%&pause>nul
复制代码

[ 本帖最后由 batman 于 2009-11-29 11:04 编辑 ]

Seter

昏迷,我就是这个意思啊
我这里运行结果是

e:\khm\I386
d:\Program Files\Macromedia\Flash CS4\JVM\lib\i386
复制代码

请先运行一下试试看...不行的话把结果发上来..唉...WIN98的我就无语了

vsbat

@echo off
for %%i in (c d e f j h i g k) do (if exist %%i: (
for /f "delims=" %%j in ('dir /b /s /ad %%i:\i386  2^>nul') do echo %%j ))
pause 
复制代码

batman 版主的好像是 只要找到一个就结束了

[ 本帖最后由 vsbat 于 2009-12-3 10:07 编辑 ]

cryfordog

@echo off
for %%i in (c: d: e: f: g:) do (
for /f "delims=" %%a in ('dir /b /s /ad %%i\i386') do echo %%a
)
pause
复制代码

错信息不知掉怎么屏蔽掉？？

bluewing009

郁闷....干嘛无视我的帖子....55555

请教  这个方法不行么？

zcy85611

原帖由 Seter 于 2009-11-29 10:29 发表
@echo off
for %%j in (q w e r t y u i o p a s d f g h j k l z x c v b n m) do (
if exist %%j:\nul (
for /f "delims=" %%i in ('dir %%j:\i386 /a-d /b /s /a 2^>nul') do echo %%i
)
)
pause是这个意思 ...

Seter，你好，你的这个程序我试过了，非常好，但是我有一些代码不太理解，想请教一下你

dir %%j:\i386 /a-d /b /s /a 这一段里面，我试着去掉了/a-d,/s,/a中的任意一个，结果都会导致这个程序找不到我要的文件夹，/s /a我能理解，但是/a-d是什么意思呢？

再就是 dir c:\i386  为什么这样写，就可以找到c盘下所有包含i386文件夹的文件夹呢？

麻烦Seter解答一下，谢谢！

zcy85611

原帖由 bluewing009 于 2009-11-29 10:48 发表
这种网吧里的路径都不一样 ，所以我写了这个，更广泛一点。
可以针对普通要求的搜索。嘿嘿  直接把例子发上来了，  有必要的话就改改。@echo off
setlocal enabledelayedexpansion
for /f "delims=\" %%i in ('fs ...

这位朋友的代码我试过了，也是可以的，还学到了一个新的用法 fsutil fsinfo drives^|find /v "" ，感谢你的回答

Batcher

/a-d的意思是排除文件夹，参考帮助文档：

/A          Displays files with specified attributes.   attributes   D  Directories                R  Read-only files                H  Hidden files               A  Files ready for archiving                S  System files               I  Not content indexed files                L  Reparse Points             -  Prefix meaning not

zcy85611

原帖由 Batcher 于 2009-12-12 00:33 发表
/a-d的意思是排除文件夹，参考帮助文档：

  /A          Displays files with specified attributes.
  attributes   D  Directories                R  Read-only files
               H  Hidden files       ...

Batcher你好，这个文档我看过了，但是我还是不太理解为什么

dir %%j:\i386 /a-d /b /s /a

这样一段代码就能达到我想要的效果

前面有一段/a-d 排除掉目录，后面又有一个/a把所有的类型都包含进去，不是有一点前后矛盾的感觉吗？麻烦大家帮我解答一下，谢谢

zqz0012005

这个代码本来就是错的。
1、/a-d 是排除文件夹，而你的目的是搜索文件夹
2、后面的/a选项覆盖了前面的，即前面不起作用。
总之就是dir %%j:\i386 /a-d /b /s /a这一句很失败！

zqz0012005

@echo off
set TargetFolder=I386
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do if exist %%a:\ (
    pushd %%a:\
    for /d /r %%i in (.) do if /i "%%~ni"=="%TargetFolder%" echo %%~fi
    popd
)
pause
复制代码