[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖
实质是变量延迟的问题, 调试代码:
  1. @echo off&setlocal enabledelayedexpansion
  2. set/p a=起始日期,格式20071221:
  3. set/p b=终止日期,格式20080310:
  4. set m=寒夜312831303130313130313031孤星
  5. if "%a:~4,1%"=="0" (set tm=%a:~5,1%) else set tm=%a:~4,2%
  6. if "%a:~6,1%"=="0" (set td=%a:~7,1%) else set td=%a:~6,2%
  7. set ty=%a:~0,4%&echo.%a%
  8. :hanye
  9. echo n=!n!
  10. set/a n=%tm%*2,y=%ty%%%4,td=%td%+1,e=!m:~%n%,2!
  11. echo n=!n!,e=!e!
  12. pause
  13. if %tm%==2 if %y%==0 set e=29
  14. if %td% gtr %e% set/a tm=%tm%+1,td=1
  15. if %tm%==13 set/a ty=%ty%+1,tm=1
  16. if %tm% lss 10 (set em=0%tm%) else set em=%tm%
  17. if %td% lss 10 (set ed=0%td%) else set ed=%td%
  18. set d=%ty%%em%%ed%
  19. if %d% gtr %b% pause>nul&goto :eof
  20. echo.%d%&goto :hanye
复制代码
测试结果:
起始日期,格式20071221:18991125
终止日期,格式20080310:20000305
18991125
n=
n=22,e=0

我的代码中用的是如下方式来截取的:
  1. (set /a index=m*2-2)& for %%i in (!index!) do set dmax=!days:~%%i,2!
复制代码

TOP

原帖由 neorobin 于 2010-4-8 00:17 发表
实质是变量延迟的问题, 调试代码echo off&setlocal enabledelayedexpansion
set/p a=起始日期,格式20071221:
set/p b=终止日期,格式20080310:
set m=寒夜312831303130313130313031孤星
if "%a:~4,1%"=="0" ...

谢谢,第一次是分两行写的,结果后来贪图美观就给和并到一行了,忘记了延迟的问题。。。
寒夜孤星:在没有说明的情况下,本人所有代码均运行在 XP SP3 下 (有问题请发贴,QQ临时会话已关闭)

TOP

以下代码同样用 100 年的日期测试, 用时与 7 楼 FOR 的代码极为接近
对输入的日期前后无限制, 可自动将在前的日期作为起始日期
其中 如: if "!_y!!_m!%%d" gtr "!ymde!" (goto :break) 这样的判断语句还可省去, 进一步提高效率, 但未有简洁方案, 太显繁长
  1. @echo off&setlocal enabledelayedexpansion
  2. set /p ymds=请输入起始日期(yyyymmdd),要使用系统当前日期,请直接回车:
  3. set /p ymde=请输入截止日期(yyyymmdd),要使用系统当前日期,请直接回车:
  4. (set t=%time%)&(cd.>outFile.txt)
  5. for /l %%m in (1,1,12) do (set days_%%m=31)
  6. for %%m in (4,6,9,11) do (set days_%%m=30)
  7. if not defined ymds (set ymds=%date:~0,4%%date:~5,2%%date:~8,2%)
  8. if not defined ymde (set ymde=%date:~0,4%%date:~5,2%%date:~8,2%)
  9. if "!ymde!" lss "!ymds!" (set tt=!ymde!)&(set ymde=!ymds!)&(set ymds=!tt!)
  10. echo 起始日期为:!ymds!, 截止日期为:!ymde!
  11. (set /a ys=1!ymds:~0,4!-10000, ye=1!ymde:~0,4!-10000)
  12. (set /a ms=1!ymds:~4,2!-100, me=1!ymde:~4,2!-100)
  13. (set /a ds=1!ymds:~6,2!-100, de=1!ymde:~6,2!-100)
  14. set /a "y_1=ys+1,m_1=ms+1,d_1=ds+1"
  15. for /l %%y in (!ys!,1,!ys!) do (
  16.   (set _y=000%%y)&(set _y=!_y:~-4!)
  17.   for /l %%m in (!ms!,1,!ms!) do (
  18.     (set _m=0%%m)&(set _m=!_m:~-2!)
  19.     if %%m==2 set /a "days_2=28+(^!(%%y%%4)&^!^!(%%y%%100))|^!(%%y%%400)"
  20.     for /l %%d in (!ds!,1,9) do (
  21.       if "!_y!!_m!0%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!0%%d
  22.     )
  23.     if !ds! geq 10 (set d_2=!ds!) else set d_2=10
  24.     for /l %%d in (!d_2!,1,!days_%%m!) do (
  25.       if "!_y!!_m!%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!%%d
  26.     )
  27.   )
  28.   for /l %%m in (!m_1!,1,12) do (
  29.     (set _m=0%%m)&(set _m=!_m:~-2!)
  30.     if %%m==2 set /a "days_2=28+(^!(%%y%%4)&^!^!(%%y%%100))|^!(%%y%%400)"
  31.     for /l %%d in (1,1,9) do (
  32.       if "!_y!!_m!0%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!0%%d
  33.     )
  34.     for /l %%d in (10,1,!days_%%m!) do (
  35.       if "!_y!!_m!%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!%%d
  36.     )
  37.   )
  38. )>>outFile.txt
  39. for /l %%y in (!y_1!,1,!ye!) do (
  40.   (set _y=000%%y)&(set _y=!_y:~-4!)
  41.   for /l %%m in (1,1,12) do (
  42.     (set _m=0%%m)&(set _m=!_m:~-2!)
  43.     if %%m==2 set /a "days_2=28+(^!(%%y%%4)&^!^!(%%y%%100))|^!(%%y%%400)"
  44.     for /l %%d in (1,1,9) do (
  45.       if "!_y!!_m!0%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!0%%d
  46.     )  
  47.     for /l %%d in (10,1,!days_%%m!) do (
  48.       if "!_y!!_m!%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!%%d
  49.     )
  50.   )
  51. )>>outFile.txt
  52. :break
  53. echo 用时: !t! ==^> %time%
  54. start outFile.txt
  55. pause
  56. exit /b
复制代码

[ 本帖最后由 neorobin 于 2010-4-8 03:46 编辑 ]

TOP

参照日期算法 应该可行 效率没测试

TOP

提速,100 个日期 只需 1.81 秒
  1. @echo off&setlocal enabledelayedexpansion
  2. set t=%time%
  3. echo 请输入8位数的起始日期和结束日期用空格分开
  4. echo 或只输入结束(开始)日期,默认当前日期为起始(结束)日期
  5. echo 输入格式 20080205 21080529&echo.
  6. set xx=19100201
  7. for /f "tokens=1,2" %%i in ("%xx%") do (
  8.    if not "%%j"=="" (set qs=%%i&set js=%%j) else (
  9.       for /f "tokens=1-3 delims=.\-/ " %%a in ("!date!") do (
  10.          if %%a%%b%%c gtr %%i (set/a qs=xx,js=%%a%%b%%c) else (
  11.             set/a qs=%%a%%b%%c,js=%%i
  12. ))))
  13. for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do set/a n+=1&set/a yue!n!=%%a
  14. set /a qsd=100%qs:~4,2%%%100,qsm=100%qs:~6,2%%%100
  15. set /a yuq=qsd,yuh=12,mq=qsm,mh=yue!qsd!
  16. echo 起始日期 %qs:~0,4%-%qs:~4,2%-%qs:~6,2%
  17. echo 结束日期 %js:~0,4%-%js:~4,2%-%js:~6,2%
  18. for /l %%i in (1 1 31) do set .%%i=0%%i&set ".%%i=!.%%i:~-2!"
  19. (
  20. for /l %%i in (%qs:~0,4% 1 %js:~0,4%) do (
  21.     set /a yue2="^!(%%i%%4)&^!(^!(%%i%%100))|^!(%%i%%400)"+28
  22.     if %%i equ %js:~0,4% set /a yuh=100%js:~4,2%%%100&set flag=a
  23.     for /l %%j in (!yuq! 1 !yuh!) do (
  24.        set /a mh=yue%%j
  25.        if defined flag if %%j equ !yuh! set /a mh=100!js:~-2!%%100
  26.        for /l %%k in (!mq! 1 !mh!) do echo %%i!.%%j!!.%%k!
  27.        set /a mq=1&echo;
  28.      )
  29.      set yuq=1
  30. )
  31. )>c.txt
  32. pause
复制代码

TOP

看楼上各位把for /l用到这境界,羡一个。。。
寒夜孤星:在没有说明的情况下,本人所有代码均运行在 XP SP3 下 (有问题请发贴,QQ临时会话已关闭)

TOP

发现已经迟到一步
  1. @echo off&setlocal enabledelayedexpansion
  2. set "YmdP=19080521"
  3. set "YmdT=20110902"
  4. if "%YmdP%" gtr "%YmdT%" set/a "YmdP=YmdT,YmdT=%YmdP%"
  5. set /a "p1=%YmdP:~,4%,p2=1%YmdP:~4,2%%%100,p3=1%YmdP:~6,2%%%100,T1=%YmdT:~,4%,T2=1%YmdT:~4,2%%%100,T3=1%YmdT:~6,2%%%100"
  6. for /l %%i in (%p1% 1 %t1%) do set /a "i%%i=1,j%%i=12"
  7. set /a "i%p1%=p2,j%t1%=t2"
  8. for %%i in (31 28 31 30 31 30 31 31 30 31 30 31) do set /a n+=1&set "_n!n!=%%i"
  9. for /l %%i in (%p1% 1 %t1%) do (
  10. set /a "_n2=^!(%%i%%4)&^!(^!(%%i%%100))|^!(%%i%%400)+28"
  11.     for /l %%j in (!i%%i! 1 !j%%i!) do (
  12.        set i=1
  13.        if "%%i%%j" equ "!p1!!p2!" set /a "i=p3"
  14.        if "%%i%%j" equ "!t1!!t2!" set /a "_n%%j=t3"
  15.        set "m=0%%j"
  16.        for /l %%k in (!i! 1 !_n%%j!) do (
  17.        set "d=0%%k"
  18.        echo;%%i!m:~-2!!d:~-2!
  19. )))
  20. pause
复制代码

TOP

继续提速,减少for循环内代码运行的次数,效率略有提高,测试100个日期耗时1.66秒左右

  1. @echo off&setlocal enabledelayedexpansion
  2. set t=%time%
  3. echo 请输入8位数的起始日期和结束日期用空格分开
  4. echo 或只输入结束(开始)日期,默认当前日期为起始(结束)日期
  5. echo 输入格式 20080205 21080529&echo.
  6. set xx=19100201
  7. for /f "tokens=1,2" %%i in ("%xx%") do (
  8.    if not "%%j"=="" (set qs=%%i&set js=%%j) else (
  9.       for /f "tokens=1-3 delims=.\-/ " %%a in ("!date!") do (
  10.          if %%a%%b%%c gtr %%i (set/a qs=xx,js=%%a%%b%%c) else (
  11.             set/a qs=%%a%%b%%c,js=%%i
  12. ))))
  13. for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do set/a n+=1&set/a yue!n!=%%a
  14. set /a qsd=100%qs:~4,2%%%100,qsm=100%qs:~6,2%%%100
  15. set /a yuq=qsd,yuh=12,mq=qsm,mh=yue!qsd!
  16. for /l %%i in (1 1 31) do set .%%i=0%%i&set ".%%i=!.%%i:~-2!"
  17. set /a a=100!js:~4,2!%%100,b=100!js:~-2!%%100
  18. set #2010!a!=!js:~0,4!&set yue!js:~0,4!!a!=!b!
  19. set _!js:~0,4!=!a!&set yuh!a!=!a!
  20. echo 起始日期 %qs:~0,4%-%qs:~4,2%-%qs:~6,2%
  21. echo 结束日期 %js:~0,4%-%js:~4,2%-%js:~6,2%
  22. (for /l %%i in (%qs:~0,4% 1 %js:~0,4%) do (
  23.     set /a yue2="^!(%%i%%4)&^!(^!(%%i%%100))|^!(%%i%%400)"+28,yuh=yuh!_%%i!
  24.     for /l %%j in (!yuq! 1 !yuh!) do (
  25.        set /a mh=yue!#%%i%%j!%%j
  26.        for /l %%k in (!mq! 1 !mh!) do echo %%i!.%%j!!.%%k!
  27.        set mq=1
  28.      )
  29.      set yuq=1
  30. ))>c.txt
  31. pause
复制代码

[ 本帖最后由 FOR 于 2010-4-8 15:06 编辑 ]
1

评分人数

TOP

借鉴各位的技巧和思路,特别是 FOR 的, 再发一个:
  1. @echo off&setlocal enabledelayedexpansion
  2. set /p ymds=请输入起始日期(yyyymmdd),要使用系统当前日期,请直接回车:
  3. set /p ymde=请输入截止日期(yyyymmdd),要使用系统当前日期,请直接回车:
  4. if not defined ymds (set ymds=%date:~0,4%%date:~5,2%%date:~8,2%)
  5. if not defined ymde (set ymde=%date:~0,4%%date:~5,2%%date:~8,2%)
  6. if "!ymde!" lss "!ymds!" (set tt=!ymde!&set ymde=!ymds!&set ymds=!tt!)
  7. echo 起始日期为:!ymds!, 截止日期为:!ymde!
  8. set /p=%time% ==^><nul
  9. for /l %%i in (0 1 31) do set _%%i=0%%i&set "_%%i=!_%%i:~-2!"
  10. (for /l %%m in (1,1,12) do set SD_%%m=31)&for %%m in (4,6,9,11) do set SD_%%m=30
  11. set /a ys=1!ymds:~0,4!-10000, ye=1!ymde:~0,4!-10000
  12. set /a ms=1!ymds:~4,2!-100, me=1!ymde:~4,2!-100
  13. set /a ds_diff=1!ymds:~6,2!-101, dEnd=1!ymde:~6,2!-100
  14. (for /l %%y in (%ymds:~0,4% 1 %ymde:~0,4%) do (
  15.   set /a "SD_2=28+(^!(%%y%%4)&^!^!(%%y%%100))|^!(%%y%%400)"
  16.   if %%y gtr !ys! (set ms=1)
  17.   if %%y lss !ye! (
  18.     for /l %%m in (!ms!,1,12) do (
  19.       set /a "ds=1+(^!(%%y^^ys)&^!(%%m^^ms))*ds_diff"
  20.       for /l %%d in (!ds!,1,!SD_%%m!) do echo %%y!_%%m!!_%%d!
  21.     )
  22.   ) else for /l %%m in (!ms!,1,!me!) do (
  23.       set /a "ds=1+(^!(%%y^^ys)&^!(%%m^^ms))*ds_diff"
  24.       if %%m geq !me! (set de=!dEnd!) else (set de=!SD_%%m!)
  25.       for /l %%d in (!ds!,1,!de!) do echo %%y!_%%m!!_%%d!
  26.   )
  27. ))>out.txt
  28. echo %time%&start out.txt&pause
复制代码

TOP

返回列表