【出题】批处理按特定条件查找文本内容

随风

a.txt

sdfgsdfgsdfg
上dfhgjs正确
abcddfja;正确
sdfg下正确
sdfgsdgs
sdfgsdgsdg
55555555555
sg上fg正确
abcd正确
sdfg下gf正确
fgfdgsdfg
77777777777
上fdg正确dsfg
abcddkfja
dfsg下dfsg正确
tuytutyuy
gfhgfh
sdghj上dfg正确
abcd正确
sdg下sdg正确
复制代码

要求一：显示a.txt中以 abcd 开头的行和它的上一行。
要求二：显示a.txt中以 abcd 开头的行和它的上一行及下一行。

[ 本帖最后由 随风 于 2008-5-24 01:35 编辑 ]

springcm

我的答案：
要求一

@echo off
setlocal enabledelayedexpansion
set n=0
set count=0
goto :loop
:up
set /a count=!n!-2
for /f "skip=%count% tokens=*" %%j in (a.txt) do (
    echo %%j>>b.txt
    goto :eof
    )
:loop
for /f "tokens=*" %%i in (a.txt) do (
    set /a n+=1
    set temp=%%i
    if "!temp:~0,4!"=="abcd" (
    echo %%i>>b.txt
    call :up
    )
    )
start b.txt
复制代码

要求二

@echo off
setlocal enabledelayedexpansion
set n=0
set count=0
goto :loop
:up
set /a count=!n!-2
for /f "skip=%count% tokens=*" %%j in (a.txt) do (
    echo %%j>>b.txt
    goto :eof
    )
:low
set /a count=!n!
for /f "skip=%count% tokens=*" %%j in (a.txt) do (
    echo %%j>>b.txt
    goto :eof
    )
:loop
for /f "tokens=*" %%i in (a.txt) do (
    set /a n+=1
    set temp=%%i
    if "!temp:~0,4!"=="abcd" (
    echo %%i>>b.txt
    call :up
    call :low
    )
    )
start b.txt
复制代码

如果原文件以abcd开头行出现的位置<2的话就要加判断语句,否则会报错.
不过按照楼主的a.txt文件,我测试是通过的.

[ 本帖最后由 springcm 于 2008-6-2 07:59 编辑 ]

tangfu

set /a count=!n!-2
for /f "skip=%count% tokens=*" %%j in (a.txt) do (.....
其中的conut在loop循环时一直为零，直到call   ：up时值才改变，楼主可否解释一下这个count，我有点搞不懂......

springcm

:: 在标签:loop处,我用了
set /a n+=1 
:: 相当于FOR 语句每处理一行N值递增1.
set /a count=!n!-2
:: 然后把n-2赋值给变量count
复制代码

tangfu

哦，终于弄明白了，我没有看到n在变化.....
谢谢！！！

随风

呵呵，不错，加分鼓励！
但可以更简洁，支持一题多解。
争取在一个ｆｏｒ里循环一次就完成。

more

要求一：显示a.txt中以 abcd 开头的行和它的上一行。

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('type a.txt') do (
   set /a n+=1,m=n-1
   set _!n!=%%a
   set str=%%a
   if "!str:~,4!"=="abcd" call echo %%_!m!%%&call echo %%_!n!%%
)
pause
复制代码

要求二：显示a.txt中以 abcd 开头的行和它的上一行及下一行。

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('type a.txt') do (
   set /a a+=1
   set _!a!=%%a
)
for /f "delims=" %%a in ('type a.txt') do (
   set /a n+=1,o=n+1,m=n-1
   set _!n!=%%a
   set str=%%a
   if "!str:~,4!"=="abcd" call echo %%_!m!%%&call echo %%_!n!%%&call echo %%_!o!%%
)
pause
复制代码

batman

呵呵，又是这道题啊。

dishuo

只用一个for完成要求2

cls&@echo off&setlocal enabledelayedexpansion
set a1=不存在&set a2=不存在
for /f "tokens=*" %%i in (a.txt) do (
    set a0=!a1!&set a1=!a2!&set a2=%%i
    if "!a1:~0,4!" equ "abcd" echo 上一行:  !a0!&echo abcd开头:!a1!&echo 下一行:  !a2!&echo.
)
if "%a2:~0,4%" equ "abcd" echo 上一行:  !a1&echo abcd开头:!a2!&echo 下一行:  不存在&echo.
pause&goto:eof

运行结果

上一行:  上dfhgjs正确
abcd开头:abcddfja;正确
下一行:  sdfg下正确

上一行:  sg上fg正确
abcd开头:abcd正确
下一行:  sdfg下gf正确

上一行:  上fdg正确dsfg
abcd开头:abcddkfja
下一行:  dfsg下dfsg正确

上一行:  sdghj上dfg正确
abcd开头:abcd正确
下一行:  sdg下sdg正确

请按任意键继续. . .

z_berry

哇，这个好难

z_berry

@echo off
setlocal enabledelayedexpansion
set n=0
set before=不存在
set beforebefore=不存在
for /f "delims=" %%i in (a.txt) do (
    set cur=%%i
    if "!before:~0,4!"=="abcd" (
        echo ------------
        echo 上一行：!beforebefore!
        echo 当前行：!before!
        echo 下一行：%%i
        echo _____________
    )
    set beforebefore=!before!
    set before=!cur!
)

这是第二道题目，第一个更简单哦

jellyhk

不会！

学习中！！！！！！！

wxcute

@echo off
for /f "tokens=1* delims=:" %%c in ('findstr /n /b "abcd" a.txt') do call :zd n %%c %%d
pause
goto :eof
:zd
　set %1=%2
　set/a m=%n%-1
　for /f "tokens=1* delims=:" %%i in ('findstr /n . a.txt') do call :s2 f %%i %%j
　goto :eof
:s2
　set %1=%2
　if %f%==%m% echo %3
　if %f%==%n% echo %3&echo.
复制代码

上为两行，下为三行的。上下思路没改

@echo off
for /f "tokens=1* delims=:" %%c in ('findstr /n /b "abcd" a.txt') do call :zd n %%c %%d
pause
goto :eof
:zd
　set %1=%2
　set/a m=%n%-1
　set/a k=%n%+1
　for /f "tokens=1* delims=:" %%i in ('findstr /n . a.txt') do call :s2 f %%i %%j
　goto :eof
:s2
　set %1=%2
　if %f%==%m% echo %3
　if %f%==%n% echo %3
　if %f%==%k% echo %3&echo.
复制代码

顺便问下，我怎么给别人评分阿？

[ 本帖最后由 wxcute 于 2008-9-15 19:00 编辑 ]

keen

答案一：

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=:" %%i in ('findstr /n "abcd" a.txt') do (
    set a=%%i
    set /a a-=1
    for /f "tokens=1,2 delims=:" %%m in ('findstr /n .* a.txt') do if %%m==!a! echo %%n
    echo %%j
)
pause
复制代码

答案二：

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=:" %%i in ('findstr /n "abcd" a.txt') do (
    set a=%%i
    set /a a-=1
    for /f "tokens=1,2 delims=:" %%m in ('findstr /n .* a.txt') do if %%m==!a! echo %%n
    echo %%j
    set b=%%i
    set /a b+=1
    for /f "tokens=1,2 delims=:" %%x in ('findstr /n .* a.txt') do if %%x==!b! echo %%y
)
pause
复制代码

cainiao736

要求一

@echo off&setlocal enabledelayedexpansion
for /f %%i in (a.txt) do (
echo %%i|findstr "abcd">nul&&echo %%i &&echo !m!
set m=%%i )
pause
复制代码

考虑到a文本中只要有abcd，都是位于开头部分，所以没有进行判断。只要存在abcd字符串即符合条件。
要求二

@echo off&setlocal enabledelayedexpansion
set n=0
for /f %%i in (test.txt) do (
if !n!==1 ( echo %%i&set n=0 )
echo %%i|findstr "abcd">nul&&echo %%i&&echo !m!&&set n=1
set m=%%i )
pause
复制代码